SCOI2009 迷路

有向图有 N 个节点，从节点 0 出发，必须恰好在 T 时刻到达节点 N-1。 现在给出该有向图，总共有多少种不同的路径

注意：不能在某个节点逗留，且通过某有向边的时间严格为给定的时间。

用矩阵乘法把n个01邻接矩阵（连通性矩阵，a[i,j]=1表示 i 到 j 有一条有向边相连），则a[i,j]就表示走n步后从i到j的不同的路的条数。由于题目中边有权，而权值只是1..9，所以可以把每个点拆成9个点，即第i个点变成第9*(i-1)+1到第9*(i-1)+9个点，把这n个点各自拆出来的9个点串连

即a[9*(i-1)+j,9*(i-1)+j+1]:=1（1<=j<=8），读入邻接矩阵时i到j权值是k，就从9*(i-1)+k往9*(j-1)+1上连一条边，用矩阵乘法快速幂在logN的时间内求出a^N，则a[1,9*(n-1)+1]为解。

这个程序写的有些烂，数据在1.0x s出解，自己看着优化下常数，写递归快速幂还爆栈。。

改改改。。。。。。

终于发现问题了，数组开成integer就0.1出解了，没想到int64那么慢。

{$inline on}
program road(input,output);
type
   numbertype=array[0..91,0..91] of integer;//就这里,写成int64过不了
var 
   map        : array[0..11,0..11] of integer;
   power    : array[0..30] of numbertype;
   v        : array[0..30] of boolean;
   f,answer,tmp    : numbertype;
   n,t        : longint;
procedure init; inline;
var
   i,j : longint;
   ch  : char;
begin
   readln(n,t);
   for i:=1 to n do
   begin
      for j:=1 to n do
      begin
     read(ch);
     map[i,j]:=ord(ch)-48;
      end;
      readln;
   end;
   fillchar(f,sizeof(f),0);
   for i:=1 to n do
      for j:=1 to 8 do
     f[9*(i-1)+j,9*(i-1)+j+1]:=1;
   for i:=1 to n do
      for j:=1 to n do
     if map[i,j]>0 then
        f[9*(i-1)+map[i,j],9*(j-1)+1]:=1;
end; { init }
procedure main(y:longint ); inline;
var
   i,tt,j,k,l,s    : longint;
begin
   for i:=1 to 9*n do
      for j:=1 to 9*n do
     power[1][i,j]:=f[i,j];
   s:=y;
   tt:=trunc(ln(y)/ln(2))+1;
   fillchar(v,sizeof(v),false);
   dec(s);
   answer:=f;
   for i:=1 to tt do
      if (s>>(i-1))and 1=1 then
     v[i]:=true;
   for i:=2 to tt do
   begin
      fillchar(power[i],sizeof(power[i]),0);
      for j:=1 to 9*n do
     for k:=1 to 9*n do
        for l:=1 to 9*n do
           power[i][j,l]:=(power[i][j,l]+power[i-1][j,k]*power[i-1][k,l])mod 

2009;
   end;
   for i:=1 to tt do
      if v[i] then
      begin
     fillchar(tmp,sizeof(tmp),0);
     for j:=1 to 9*n do
        for k:=1 to 9*n do
           for l:=1 to 9*n do
          tmp[j,l]:=(tmp[j,l]+answer[j,k]*power[i][k,l])mod 2009;
     for j:=1 to 9*n do
        for k:=1 to 9*n do
           answer[j,k]:=tmp[j,k];
      end;
end; { main }
begin
   assign(input,'road.in');reset(input);
   assign(output,'road.out');rewrite(output);
   init;
   main(t);
   writeln(answer[1,9*(n-1)+1]);
   close(input);
   close(output);
end.