• PL/SQL尚硅谷

    第一章 PL/SQL 程序设计简介

    • PL/SQL是一种高级数据库程序设计语言，该语言专门用于在各种环境下对ORACLE数据库进行访问。由于该语言集成于数据库服务器中，所以PL/SQL代码可以对数据进行快速高效的处理。除此之外，可以在ORACLE数据库的某些客户端工具中，使用PL/SQL语言也是该语言的一个特点。本章的主要内容是讨论引入PL/SQL语言的必要性和该语言的主要特点，以及了解PL/SQL语言的重要性和数据库版本问题。还要介绍一些贯穿全书的更详细的高级概念，并在本章的最后就我们在本书案例中使用的数据库表的若干约定做一说明。

    本章主要重点：

    • PL/SQL概述
    • PL/SQL块结构
    • PL/SQL流程
    • 运算符和表达式
    • 游标
    • 异常处理
    • 数据库存储过程和函数
    • 包
    • 触发器

    1.2 SQL与PL/SQL

    a. 什么是PL/SQL?

    • PL/SQL是 Procedure Language & Structured Query Language 的缩写。ORACLE的SQL是支持ANSI(American national Standards Institute)和ISO92 (International Standards Organization)标准的产品。PL/SQL是对SQL语言存储过程语言的扩展。从ORACLE6以后，ORACLE的RDBMS附带了PL/SQL。它现在已经成为一种过程处理语言，简称PL/SQL。目前的PL/SQL包括两部分，一部分是数据库引擎部分；另一部分是可嵌入到许多产品（如C语言，JAVA语言等）工具中的独立引擎。可以将这两部分称为：数据库PL/SQL和工具PL/SQL。两者的编程非常相似。都具有编程结构、语法和逻辑机制。工具PL/SQL另外还增加了用于支持工具（如ORACLE Forms）的句法，如：在窗体上设置按钮等。本章主要介绍数据库PL/SQL内容。

    b. PL/SQL的好处

    (1) 有利于客户/服务器环境应用的运行
    • 对于客户/服务器环境来说，真正的瓶颈是网络上。无论网络多快，只要客户端与服务器进行大量的数据交换。应用运行的效率自然就回受到影响。如果使用PL/SQL进行编程，将这种具有大量数据处理的应用放在服务器端来执行。自然就省去了数据在网上的传输时间。
    (2) 适合于客户环境
    • PL/SQL由于分为数据库PL/SQL部分和工具PL/SQL。对于客户端来说，PL/SQL可以嵌套到相应的工具中，客户端程序可以执行本地包含PL/SQL部分，也可以向服务发SQL命令或激活服务器端的PL/SQL程序运行。

    c. PL/SQL 可用的SQL语句

    • PL/SQL是ORACLE系统的核心语言，现在ORACLE的许多部件都是由PL/SQL写成。
      在PL/SQL中可以使用的SQL语句有：
      INSERT，UPDATE，DELETE，SELECT … INTO，COMMIT，ROLLBACK，SAVEPOINT。

    tips
    提示：在 PL/SQL中只能用 SQL语句中的 DML 部分，不能用 DDL 部分，如果要在PL/SQL中使用DDL(如CREATE table 等)的话，只能以动态的方式来使用。

    • ORACLE 的 PL/SQL 组件在对 PL/SQL 程序进行解释时，同时对在其所使用的表名、列名及数据类型进行检查。
    • PL/SQL 可以在SQL*PLUS 中使用。
    • PL/SQL 可以在高级语言中使用。
    • PL/SQL可以 在ORACLE的 开发工具中使用。
    • 其它开发工具也可以调用PL/SQL编写的过程和函数，如Power Builder 等都可以调用服务器端的PL/SQL过程。

    1.3 运行PL/SQL程序

    • PL/SQL程序的运行是通过ORACLE中的一个引擎来进行的。这个引擎可能在ORACLE的服务器端，也可能在 ORACLE 应用开发的客户端。引擎执行PL/SQL中的过程性语句，然后将SQL语句发送给数据库服务器来执行。再将结果返回给执行端。

    第二章 PL/SQL块结构和组成元素

    2.1 PL/SQL块

    • PL/SQL程序由三个块组成，即声明部分、执行部分、异常处理部分
      PL/SQL块的结构如下：
    DECLARE   
/* 声明部分: 在此声明PL/SQL用到的变量,类型及游标，以及局部的存储过程和函数 */ 
BEGIN 
    /*  执行部分:  过程及SQL 语句  , 即程序的主要部分  */ 
EXCEPTION 
   /* 执行异常部分: 错误处理  */ 
END;

    tips
    其中 执行部分是必须的。

    PL/SQL块可以分为三类：

    1. 无名块：动态构造，只能执行一次。
    2. 子程序：存储在数据库中的存储过程、函数及包等。当在数据库上建立好后可以在其它程序中调用它们。
    3. 触发器：当数据库发生操作时，会触发一些事件，从而自动执行相应的程序。

    2.2 PL/SQL结构

    • PL/SQL块中可以包含子块；
    • 子块可以位于 PL/SQL中的任何部分；
    • 子块也即PL/SQL中的一条命令；

    2.3 标识符

    PL/SQL程序设计中的标识符定义与SQL 的标识符定义的要求相同。要求和限制有：

    • 标识符名不能超过30字符；
    • 第一个字符必须为字母；
    • 不分大小写；
    • 不能用’-‘(减号);
    • 不能是SQL保留字。

    tips
    提示: 一般不要把变量名声明与表中字段名完全一样,如果这样可能得到不正确的结果.

    例如：下面的例子将会删除所有的纪录，而不是KING 的记录；

    DECLARE 
   Ename varchar2(20) := ’KING’; -- Ename 进行赋值 【:= 赋值】
BEGIN 
 DELETE FROM emp WHERE ename=ename; 
END;
    • 变量命名在PL/SQL中有特别的讲究，建议在系统的设计阶段就要求所有编程人员共同遵守一定的要求，使得整个系统的文档在规范上达到要求。下面是建议的命名方法：
    标识符 命名规则 例子
    程序变量 V_name V_name
    程序常量 C_Name C_company_name
    游标变量 Name_cursor Emp_cursor
    异常标识 E_name E_too_many
    表类型 Name_table_type Emp_record_type
    表 Name_table Emp
    记录类型 Name_record Emp_record
    SQL\* Plus 替代变量 P_name P_sal
    绑定变量 G_name G_year_sal

    2.4 PL/SQL 变量类型

    • 在前面的介绍中，有系统的数据类型，也可以自定义数据类型。下表是ORACLE类型和PL/SQL中的变量类型的合法使用列表：

    a. 变量类型

    在ORACLE8i中可以使用的变量类型有：

    类型 子类 说 明 范 围 ORACLE限制
    CHAR Character,String,Rowid,Nchar 定长字符串,民族语言字符集 0到32767，可选,确省=1 2000
    VARCHAR2 Varchar,String,NVARCHAR2 可变字符串,民族语言字符集 0到32767，4000 4000
    BINARY_INTEGER 带符号整数,为整数计算优化性能
    NUMBER(p,s) Dec,Double,precision,Integer,Int,Numeric,Real,Small int 小数, NUMBER的子类型，高精度实数，整数, NUMBER 的子类型整数, NUMBER 的子类型;与NUMBER等价,与NUMBER等价整数, 比 integer 小
    LONG 变长字符串 0到2147483647 32,767字节
    DATE 日期型 公元前4712年1月1日至公元后4712年12月31日
    BOOLEAN 布尔型 TRUE, FALSE,NULL 不使用
    ROWID 存放数据库行号
    UROWID 通用行标识符，字符类型

    b. 复合类型

    • ORACLE 在 PL/SQL 中除了提供象前面介绍的各种类型外,还提供一种称为复合类型的类型---记录和表.
    (1) 记录类型
    • 记录类型是把逻辑相关的数据作为一个单元存储起来，称作PL/SQL RECORD 的域(FIELD)，其作用是存放互不相同但逻辑相关的信息。
    • 定义记录类型语法如下
      TYPE record_type IS RECORD( 
--把它当作一个对象，需要声明变量，变量多个用逗号隔开,最后一个分号
   Field1 type1  [NOT NULL]  [:= exp1 ], 
   Field2 type2  [NOT NULL]  [:= exp2 ], 
   . . .   . . . 
   Fieldn typen  [NOT NULL]  [:= expn ] ) ;
      image
      或
      image

    tips
    提示:

    1. DBMS_OUTPUT.PUT_LINE 过程的功能类似于 Java 中的 System.out.println() 直接将输出结果送到标准输出中.
    2. 在使用上述过程之前必须将 SQL * PLUS 的环境参数 SERVEROUTPUT 设置为 ON, 否则将看不到输出结果:
      set serveroutput on

    可以用 SELECT语句对记录变量进行赋值,只要保证记录字段与查询结果列表中的字段相配即可。

    (2) 使用%TYPE
    • 定义一个变量，其数据类型与已经定义的某个数据变量的类型相同，或者与数据库表的某个列的数据类型相同，这时可以使用%TYPE。
    • 使用%TYPE特性的优点在于：
      • 所引用的数据库列的数据类型可以不必知道；
      • 所引用的数据库列的数据类型可以实时改变。
        image

    c. 使用%ROWTYPE

    • PL/SQL 提供%ROWTYPE操作符, 返回一个记录类型, 其数据类型和数据库表的数据结构相一致。
    • 使用%ROWTYPE特性的优点在于：
      • 所引用的数据库中列的个数和数据类型可以不必知道；
      • 所引用的数据库中列的个数和数据类型可以实时改变。
        image

    d. PL/SQL 表(嵌套表)

    PL/SQL 程序可使用嵌套表类型创建具有一个或多个列和无限行的变量, 这很像数据库中的表. 声明嵌套表类型的一般语法如下:

    TYPE type_name IS TABLE OF 
 {datatype | {variable | table.column} % type | table%rowtype};
    方法 描述
    EXISTS(n) Return TRUE if the nth element in a PL/SQL table exists;
    COUNT Returns the number of elements that a PL/SQL table currently contains;
    FIRST LAST Return the first and last (smallest and lastest) index numbers in a PL/SQL table. Returns NULL if the PL/SQL table is empty.
    PRIOR(n) Returns the index number that precedes index n in a PL/SQL table;
    NEXT(N) Returns the index number that succeeds index n in a PL/SQL table;
    TRIM TRIM removes one element from the end of a PL/SQL table.
    TRIM(n) removes n element from the end of a pl/sql table.
    DELETE DELETE removes all elements from a PL/SQL table.
    DELETE(n) removes the nth elements from a PL/SQL table.
    DELETE(m, n) removes all elements in the range m to n from a PL/SQL table.

    image

    tips
    说明:

    1. 在使用嵌套表之前必须先使用该集合的构造器初始化它. PL/SQL 自动提供一个带有相同名字的构造器作为集合类型.
    2. 嵌套表可以有任意数量的行. 表的大小在必要时可动态地增加或减少: extend(x) 方法添加 x 个空元素到集合末尾; trim(x) 方法为去掉集合末尾的 x 个元素.

    2.5 运算符和表达式(数据定义)

    a. 关系运算符

    运算符 意义
    = 等于
    <> , != , ~= , ^= 不等于
    < 小于
    > 大于
    <= 小于或等于
    >= 大于或等于

    b. 一般运算符

    运算符 意义
    + 加号
    - 减号
    * 乘号
    / 除号
    := 赋值号
    => 关系号
    .. 范围运算符
    || 字符连接符

    c. 逻辑运算符

    运算符 意义
    IS NULL 是空值
    BETWEEN AND 介于两者之间
    IN 在一列值中间
    AND 逻辑与
    OR 逻辑或
    NOT 取返,如IS NOT NULL, NOT IN

    2.6 变量赋值

    • 在PL/SQL编程中，变量赋值是一个值得注意的地方，它的语法如下：
      variable  := expression ; 
-- variable 是一个PL/SQL变量, expression 是一个PL/SQL 表达式

    a. 字符及数字运算特点

    • 空值加数字仍是空值：NULL + < 数字> = NULL
    • 空值加（连接）字符，结果为字符：NULL || <字符串> = < 字符串>

    b. BOOLEAN 赋值

    • 布尔值只有TRUE, FALSE及 NULL 三个值。

    c. 数据库赋值

    • 数据库赋值是通过 SELECT语句来完成的，每次执行 SELECT语句就赋值一次，一般要求被赋值的变量与SELECT中的列名要一一对应。如：
      DECLARE 
emp_id    emp.empno%TYPE :=7788; -- 使用数据库列的类型
emp_name emp.ename%TYPE; 
wages     emp.sal%TYPE; 
BEGIN
-- 使用 select 查询的字段 into 定义的变量 from 表 [where 标间]
SELECT ename, NVL(sal,0) + NVL(comm,0) INTO emp_name, wages  
FROM emp WHERE empno = emp_id;
-- 打印输出
DBMS_OUTPUT.PUT_LINE(emp_name||’----‘||to_char(wages)); 
END;

    tips
    提示：不能将SELECT语句中的列赋值给布尔变量。

    d. 可转换的类型赋值

    • CHAR 转换为 NUMBER：
      使用 TO_NUMBER 函数来完成字符到数字的转换，如：
      v_total := TO_NUMBER(‘100.0’) + sal;
    • NUMBER 转换为CHAR：
      使用 TO_CHAR函数可以实现数字到字符的转换，如：
      v_comm := TO_CHAR(‘123.45’) || ’元’ ;
    • 字符转换为日期：
      使用 TO_DATE函数可以实现 字符到日期的转换，如：
      v_date := TO_DATE('2001.07.03','yyyy.mm.dd');
    • 日期转换为字符
      使用 TO_CHAR函数可以实现日期到字符的转换，如：
      v_to_day := TO_CHAR(SYSDATE, 'yyyy.mm.dd hh24:mi:ss') ;

    2.7 变量作用范围及可见性

    在PL/SQL编程中，如果在变量的定义上没有做到统一的话，可能会隐藏一些危险的错误，这样的原因主要是变量的作用范围所致。与其它高级语言类似，PL/SQL的变量作用范围特点是：

    • 变量的作用范围是在你所引用的程序单元（块、子程序、包）内。即从声明变量开始到该块的结束。
    • 一个变量（标识）只能在你所引用的块内是可见的。
    • 当一个变量超出了作用范围，PL/SQL引擎就释放用来存放该变量的空间（因为它可能不用了）。
    • 在子块中重新定义该变量后，它的作用仅在该块内。

    2.8 注释

    • 在PL/SQL里，可以使用两种符号来写注释，即：
      1. 使用双 ‘-‘ ( 减号) 加注释
        PL/SQL允许用 – 来写注释，它的作用范围是只能在一行有效。如：
      V_Sal  NUMBER(12,2); -- 工资变量。
      1. 使用 /* */ 来加一行或多行注释，如： 
      /***********************************************/ 
/* 文件名： department_salary.sql      */ 
/***********************************************/

    tips
    提示：被解释存放在数据库中的 PL/SQL 程序，一般系统自动将程序头部的注释去掉。只有在 PROCEDURE 之后的注释才被保留；另外程序中的空行也自动被去掉。

    2.9 简单例子

    a. 简单数据插入例子

    /* 本例子仅是一个简单的插入，不是实际应用。  */ 
DECLARE 
v_ename   VARCHAR2(20) := ‘Bill’; --声明变量
v_sal       NUMBER(7,2) :=1234.56; 
v_deptno   NUMBER(2) := 10; 
v_empno   NUMBER(4) := 8888; 
BEGIN 
INSERT INTO emp ( empno, ename, JOB, sal, deptno , hiredate )   
VALUES ( v_empno, v_ename, ‘Manager’, v_sal, v_deptno,  
TO_DATE(’1954.06.09’,’yyyy.mm.dd’) ); 
COMMIT; 
END;

    b. 简单数据删除例子

    /* 本例子仅是一个简单的删除例子，不是实际应用。  */ 
 DECLARE 
v_empno   number(4) := 8888; 
BEGIN 
DELETE FROM emp WHERE empno=v_empno; 
COMMIT; 
END;

    第三章 PL/SQL流程控制语句

    介绍PL/SQL的流程控制语句, 包括如下三类:

    • 控制语句: IF 语句
    • 循环语句: LOOP语句, EXIT语句
    • 顺序语句: GOTO语句, NULL语句

    3.1 条件语句

    IF <布尔表达式> THEN 
	PL/SQL 和 SQL语句; 
END IF; 

    IF <布尔表达式> THEN 
	PL/SQL 和 SQL语句; 
ELSE 
	其它语句; 
END IF; 

    IF <布尔表达式> THEN 
	PL/SQL 和 SQL语句; 
ELSIF < 其它布尔表达式> THEN 
	其它语句; 
ELSIF < 其它布尔表达式> THEN 
	其它语句; 
ELSE 
	其它语句; 
END IF;

    tips
    提示: ELSIF 不能写成 ELSEIF ！！！

    代码示例

    `DECLARE 
    v_empno emp.empno%TYPE; --使用数据库列的类型
    V_salary emp.sal%TYPE; 
    V_comment VARCHAR2(35); 
BEGIN 
	-- 赋值
   SELECT sal INTO v_salary FROM emp WHERE empno=v_empno; 
   IF v_salary<1500 THEN 
       V_comment:= ‘Fairly less’; 
   ELSIF v_salary <3000 THEN 
      V_comment:= ‘A little more’; 
   ELSE 
      V_comment:= ‘Lots of salary’; 
   END IF; 
   DBMS_OUTPUT.PUT_LINE(V_comment); 
END; `

    3.2 CASE 表达式

    CASE selector 
 WHEN expression1 THEN result1 
 WHEN expression2 THEN result2 
 WHEN expressionN THEN resultN 
 [ ELSE resultN+1] 
END;

    示例

    DECLARE 
 V_grade char(1) ;-- 声明变量
 V_appraisal VARCHAR2(20); 
BEGIN 
 V_appraisal := -- 赋值 空值
 CASE v_grade 
  WHEN 'A' THEN 'Excellent' 
  WHEN 'B' THEN 'Very Good' 
  WHEN 'C' THEN 'Good' 
  ELSE 'No such grade' 
 END; 
 -- Grade:Appraisal:No such grade 【v_grade 没有赋值所以空】
 DBMS_OUTPUT.PUT_LINE('Grade:'||v_grade||'Appraisal:'|| v_appraisal); 
END;

    3.3 循环

    a. 无条件循环

    LOOP 
      要执行的语句; -- 注意分号
      EXIT WHEN <条件语句> ;      /*条件满足，退出循环语句【分号】*/ 
	  -- 或者直接使用 exit退出循环
END LOOP; --注意分号

    示例

    DECLARE 
    int NUMBER(2) :=0;-- 赋值
BEGIN 
   LOOP 
      int := int + 1; 
      DBMS_OUTPUT.PUT_LINE('int 的当前值为:'||int); 
      EXIT WHEN int =10;-- 退出
   END LOOP; 
END; 

-- 打印从1到10
declare
    i int;
begin
   i:=1;
   loop 
       if i >10 then
            exit;   /*结束循环*/
       end if;
       dbms_output.put_line(i); 
       i:=i+1;/*i++*/   
   end loop;
end; 

-- 打印99乘法表
declare
    i int:=1;
    j int:=1;
begin
    loop
        j:=1;
        loop
            if j >i then
                exit;   /*结束循环*/
            end if;
            if i*j >=10 then
                 dbms_output.put(i||'*'||j||'='||i*j||' ');
            else
                 dbms_output.put(i||'*'||j||'='||i*j||'  ');
            end if;
            
            j:=j+1; 
        end loop;
        if i >9 then
                exit;   /*结束循环*/
        end if;
        i:=i+1;
        dbms_output.put_line('');
    end loop;
end;

    b. 条件循环 循环(相较1，推荐使用2)

    WHILE <布尔表达式> LOOP 
    要执行的语句; 
END LOOP;

    示例

    DECLARE  
x NUMBER :=1; 
BEGIN 
   WHILE x<=10 LOOP 
      DBMS_OUTPUT.PUT_LINE('X的当前值为:'||x); 
      x:= x+1; 
   END LOOP; 
END;

-- 获取1到100内的数的和
declare
    sumn int:=0;
    n int:=1;
begin
    while n <=100 loop
        sumn:=sumn+n;
        n:=n+1;
    end loop;
    dbms_output.put_line('1到100内的数的和='||sumn);    
end;

-- 获取1到100内质数的和
declare
    sumn int:=0;
    n int:=1;
    m int;
    b boolean;
begin
    /*定义一个变量让其从1跑到100*/
    while n <=100 loop
        /*判断当前数n是不是质数*/
        m:=2;
        b:=true;
        while m<=sqrt(n) loop
             if mod(n,m)=0 then
                 b:=false;
                 exit;
             end if;
             m:=m+1;
        end loop;
        if b  and n!=1 then
            dbms_output.put_line(n||'是质数！'); 
            sumn:=sumn+1;
        end if;
        n:=n+1;
    end loop;
    dbms_output.put_line('1到100内的质数的和='||sumn);    
end;

    c. for 循环

    FOR 循环计数器 IN [ REVERSE ] 下限(起始值) .. 上限(终止值) 
LOOP 
  要执行的语句; 
END LOOP;
    • 每循环一次，循环变量自动加1；使用关键字REVERSE，循环变量自动减1。跟在IN REVERSE 后面的数字必须是从小到大的顺序，而且必须是整数，不能是变量或表达式。可以使用EXIT退出循环。
      示例
    BEGIN 
   FOR int  in 1..10 LOOP 
       DBMS_OUTPUT.PUT_LINE('int 的当前值为: '||int); 
   END LOOP; 
END; 

    CREATE TABLE temp_table(num_col NUMBER); 
 
DECLARE 
	V_counter NUMBER := 10; 
BEGIN 
   INSERT INTO temp_table(num_col) VALUES (v_counter ); 
   FOR v_counter IN 20 .. 25 LOOP 
      INSERT INTO temp_table (num_col ) VALUES ( v_counter ); 
   END LOOP; 
   INSERT INTO temp_table(num_col) VALUES (v_counter ); 
   FOR v_counter IN REVERSE 20 .. 25 LOOP 
      INSERT INTO temp_table (num_col ) VALUES ( v_counter ); 
   END LOOP; 
END ; 
 
DROP TABLE temp_table;

    --- 99乘法表
begin
    for i in 1..9 loop
         for j in 1..i loop
              if i*j >=10 then
                   dbms_output.put(i||'*'||j||'='||i*j||' ');
              else
                   dbms_output.put(i||'*'||j||'='||i*j||'  ');
              end if;
         end loop;
    end loop;
end;

begin
    for i in 1..9 loop
         for j in 1..i loop
              if i*j >=10 then
                   dbms_output.put(i||'*'||j||'='||i*j||' ');
              else
                   dbms_output.put(i||'*'||j||'='||i*j||'  ');
              end if;
         end loop;
         dbms_output.put_line('');
    end loop;
end;

    3.3 标号和GOTO

    • PL/SQL中GOTO语句是无条件跳转到指定的标号去的意思。语法如下：
      GOTO   label; 
 . . .  . . . 
<<label>> /*标号是用<< >>括起来的标识符 */

    示例

    DECLARE 
   V_counter NUMBER := 1; 
BEGIN 
   LOOP  
     DBMS_OUTPUT.PUT_LINE('V_counter的当前值为:'||V_counter); 
 V_counter := v_counter + 1; 
 IF v_counter > 10 THEN 
     GOTO l_ENDofLOOP; -- 走到这里的时候去定义这个标签的地方
 END IF; 
   END LOOP; 
 <<l_ENDofLOOP>> 
     DBMS_OUTPUT.PUT_LINE('V_counter的当前值为:'||V_counter); 
END ;

    3.4 NULL 语句

    • 在PL/SQL 程序中，可以用 null 语句来说明“不用做任何事情”的意思，相当于一个占位符，可以使某些语句变得有意义，提高程序的可读性。如：
    DECLARE 
	. . . 
BEGIN 
	… 
	IF v_num IS NULL THEN 
		GOTO print1; 
	END IF; 
	… 
	<<print1>> 
	NULL;  -- 不需要处理任何数据。 
END;

    第四章 游标的使用

    在 PL/SQL 程序中，对于处理多行记录的事务经常使用游标来实现。

    4.1 游标概念

    • 为了处理 SQL 语句，ORACLE 必须分配一片叫上下文( context area )的区域来处理所必需的信息，其中包括要处理的行的数目，一个指向语句被分析以后的表示形式的指针以及查询的活动集(active set)。
    • 游标是一个指向上下文的句柄( handle)或指针。通过游标，PL/SQL可以控制上下文区和处理语句时上下文区会发生些什么事情。
    • 对于不同的SQL语句，游标的使用情况不同：
    SQL语句 游标
    非查询语句 隐式的
    结果是单行的查询语句 隐式的或显示的
    结果是多行的查询语句 显示的

    a. 处理显式游标

    (1) 显式游标处理

    显式游标处理需四个 PL/SQL步骤:

    1. 定义游标：就是定义一个游标名，以及与其相对应的SELECT 语句。
      格式：
      -- cursor ... is ..
CURSOR cursor_name[(parameter[, parameter]…)] IS select_statement; 
游标参数只能为输入参数，其格式为： 
parameter_name [IN] datatype [{:= | DEFAULT} expression]
      在指定数据类型时，不能使用长度约束。如NUMBER(4)、CHAR(10) 等都是错误的。
    2. 打开游标：就是执行游标所对应的SELECT 语句，将其查询结果放入工作区，并且指针指向工作区的首部，标识游标结果集合。如果游标查询语句中带有FOR UPDATE选项，OPEN 语句还将锁定数据库表中游标结果集合对应的数据行。
      格式：
      -- open 游标名字 
OPEN cursor_name[([parameter =>] value[, [parameter =>] value]…)];
      在向游标传递参数时，可以使用与函数参数相同的传值方法，即位置表示法和名称表示法。PL/SQL 程序不能用OPEN 语句重复打开一个游标。
    3. 提取游标数据：就是检索结果集合中的数据行，放入指定的输出变量中。
      格式：
      -- fetch 有表名字 inot 
FETCH cursor_name INTO {variable_list | record_variable };
      对该记录进行处理；
      继续处理，直到活动集合中没有记录；
    4. 关闭游标：当提取和处理完游标结果集合数据后，应及时关闭游标，以释放该游标所占用的系统资源，并使该游标的工作区变成无效，不能再使用FETCH 语句取其中数据。关闭后的游标可以使用OPEN 语句重新打开。
      格式：
      CLOSE cursor_name;

    Tips
    注：定义的游标不能有INTO 子句。

    例1. 查询前10名员工的信息。
    image

    例2. 游标参数的传递方法。
    image
    或
    image

    (2) 游标属性
    %FOUND 布尔型属性，当最近一次读记录时成功返回,则值为TRUE；
    %NOTFOUND 布尔型属性，与%FOUND相反；
    %ISOPEN 布尔型属性，当游标已打开时返回 TRUE；
    %ROWCOUNT 数字型属性，返回已从游标中读取的记录数。

    示例：给工资低于3000 的员工工资调为 3000。
    image

    (3) 游标的FOR循环
    • PL/SQL语言提供了游标FOR循环语句，自动执行游标的OPEN、FETCH、CLOSE语句和循环语句的功能；当进入循环时，游标FOR循环语句自动打开游标，并提取第一行游标数据，当程序处理完当前所提取的数据而进入下一次循环时，游标FOR循环语句自动提取下一行数据供程序处理，当提取完结果集合中的所有数据行后结束循环，并自动关闭游标。
      格式：
      -- for ... in ... loop ... end loop;
FOR index_variable IN cursor_name[value[, value]…] LOOP 
	-- 游标数据处理代码 
END LOOP;
      其中：
      index_variable为游标FOR 循环语句隐含声明的索引变量，该变量为记录变量，其结构与游标查询语句返回的结构集合的结构相同。在程序中可以通过引用该索引记录变量元素来读取所提取的游标数据，index_variable中各元素的名称与游标查询语句选择列表中所制定的列名相同。如果在游标查询语句的选择列表中存在计算列，则必须为这些计算列指定别名后才能通过游标FOR 循环语句中的索引变量来访问这些列数据。

    Tips
    注：不要在程序中对游标进行人工操作；不要在程序中定义用于控制FOR 循环的记录。

    示例
    image

    示例：当所声明的游标带有参数时，通过游标FOR 循环语句为游标传递参数。
    image

    或
    image

    示例：PL/SQL还允许在游标FOR循环语句中使用子查询来实现游标的功能。
    image

    b. 处理隐式游标

    • 显式游标主要是用于对查询语句的处理，尤其是在查询结果为多条记录的情况下；而对于非查询语句，如修改、删除操作，则由ORACLE 系统自动地为这些操作设置游标并创建其工作区，这些由系统隐含创建的游标称为隐式游标，隐式游标的名字为SQL，这是由ORACLE 系统定义的。对于隐式游标的操作，如定义、打开、取值及关闭操作，都由ORACLE 系统自动地完成，无需用户进行处理。用户只能通过隐式游标的相关属性，来完成相应的操作。在隐式游标的工作区中，所存放的数据是与用户自定义的显示游标无关的、最新处理的一条SQL 语句所包含的数据。
      格式调用为： SQL%
      隐式游标属性
    SQL%FOUND 布尔型属性,当最近一次读记录时成功返回，则值为TRUE；
    SQL%NOTFOUND 布尔型属性,与%FOUND相反；
    SQL %ROWCOUNT 数字型属性, 返回已从游标中读取得记录数；
    SQL %ISOPEN 布尔型属性, 取值总是FALSE。SQL命令执行完毕立即关闭隐式游标。

    示例: 更新指定员工信息，如果该员工没有找到，则打印”查无此人”信息。
    image

    c. 关于 NO_DATA_FOUND 和 %NOTFOUND的区别

    • SELECT … INTO 语句触发 NO_DATA_FOUND；
    • 当一个显式游标的WHERE子句未找到时触发%NOTFOUND；
    • 当UPDATE或DELETE 语句的WHERE 子句未找到时触发 SQL%NOTFOUND；在提取循环中要用 %NOTFOUND 或%FOUND 来确定循环的退出条件，不要用 NO_DATA_FOUND.

    d. 游标修改和删除操作

    • 游标修改和删除操作是指在游标定位下，修改或删除表中指定的数据行。这时，要求游标查询语句中必须使用FOR UPDATE选项，以便在打开游标时锁定游标结果集合在表中对应数据行的所有列和部分列。
    • 为了对正在处理(查询)的行不被另外的用户改动，ORACLE 提供一个 FOR UPDATE 子句来对所选择的行进行锁住。该需求迫使ORACLE锁定游标结果集合的行，可以防止其他事务处理更新或删除相同的行，直到您的事务处理提交或回退为止。
    • 语法：
      SELECT . . . FROM … FOR UPDATE [OF column[, column]…] [NOWAIT]
    • 如果另一个会话已对活动集中的行加了锁，那么SELECT FOR UPDATE操作一直等待到其它的会话释放这些锁后才继续自己的操作，对于这种情况，当加上NOWAIT子句时，如果这些行真的被另一个会话锁定，则OPEN立即返回并给出：
      `ORA-0054 ：resource busy and acquire with nowait specified.``
    • 如果使用 FOR UPDATE 声明游标，则可在DELETE和UPDATE 语句中使用WHERE CURRENT OF cursor_name子句，修改或删除游标结果集合当前行对应的数据库表中的数据行。

    示例：从EMPLOYEES表中查询某部门的员工情况，将其工资最低定为 3000；
    image

    第五章 异常错误处理

    • 一个优秀的程序都应该能够正确处理各种出错情况，并尽可能从错误中恢复。ORACLE 提供异常情况(EXCEPTION)和异常处理(EXCEPTION HANDLER)来实现错误处理。

    5.1 异常处理概念

    • 异常情况处理(EXCEPTION)是用来处理正常执行过程中未预料的事件,程序块的异常处理预定义的错误和自定义错误,由于PL/SQL程序块一旦产生异常而没有指出如何处理时,程序就会自动终止整个程序运行.

    有三种类型的异常错误：

    1. 预定义 ( Predefined )错误
      ORACLE预定义的异常情况大约有24个。对这种异常情况的处理，无需在程序中定义，由ORACLE自动将其引发。.
    2. 非预定义 ( Predefined )错误
      即其他标准的ORACLE错误。对这种异常情况的处理，需要用户在程序中定义，然后由ORACLE自动将其引发。
    3. 用户定义(User_define) 错误
      程序执行过程中，出现编程人员认为的非正常情况。对这种异常情况的处理，需要用户在程序中定义，然后显式地在程序中将其引发。

    异常处理部分一般放在 PL/SQL 程序体的后半部,结构为:

    EXCEPTION 
   WHEN first_exception THEN  <code to handle first exception > 
   WHEN second_exception THEN  <code to handle second exception > 
   WHEN OTHERS THEN  <code to handle others exception > 
END;
-- 异常处理可以按任意次序排列,但 OTHERS 必须放在最后.

    a. 预定义的异常处理

    预定义说明的部分 ORACLE 异常错误

    错误号 异常错误信息名称 说明
    ORA-0001 Dup_val_on_index 试图破坏一个唯一性限制
    ORA-0051 Timeout-on-resource 在等待资源时发生超时
    ORA-0061 Transaction-backed-out 由于发生死锁事务被撤消
    ORA-1001 ORA-1001 试图使用一个无效的游标
    ORA-1012 Not-logged-on 没有连接到ORACLE
    ORA-1017 Login-denied 无效的用户名/口令
    ORA-1403 No_data_found SELECT INTO没有找到数据
    ORA-1422 Too_many_rows SELECT INTO 返回多行
    ORA-1476 Zero-divide 试图被零除
    ORA-1722 Invalid-NUMBER 转换一个数字失败
    ORA-6500 Storage-error 内存不够引发的内部错误
    ORA-6501 Program-error 内部错误
    ORA-6502 Value-error 转换或截断错误
    ORA-6504 Rowtype-mismatch 宿主游标变量与 PL/SQL变量有不兼容行类型
    ORA-6511 CURSOR-already-OPEN 试图打开一个已存在的游标
    ORA-6530 Access-INTO-null 试图为null 对象的属性赋值
    ORA-6531 Collection-is-null 试图将Exists 以外的集合( collection)方法应用于一个null pl/sql 表上或varray上
    ORA-6532 Subscript-outside-limit 对嵌套或varray索引得引用超出声明范围以外
    ORA-6533 Subscript-beyond-count 对嵌套或varray 索引得引用大于集合中元素的个数.
    • 对这种异常情况的处理，只需在PL/SQL块的异常处理部分，直接引用相应的异常情况名，并对其完成相应的异常错误处理即可。

    例1：更新指定员工工资，如工资小于300，则加100；对 NO_DATA_FOUND 异常, TOO_MANY_ROWS 进行处理.
    image

    b. 非预定义的异常处理

    对于这类异常情况的处理，首先必须对非定义的ORACLE错误进行定义。步骤如下：

    1. 在PL/SQL 块的定义部分定义异常情况：
      <异常情况> EXCEPTION;

    2. 将其定义好的异常情况，与标准的ORACLE错误联系起来，使用 PRAGMA EXCEPTION_INIT语句：
      PRAGMA EXCEPTION_INIT(<异常情况>, <错误代码>);

    3. 在PL/SQL 块的异常情况处理部分对异常情况做出相应的处理。

    例2：删除指定部门的记录信息，以确保该部门没有员工。
    image

    c. 定义的异常处理

    • 一个异常错误相关的错误出现时，就会隐含触发该异常错误。用户定义的异常错误是通过显式使用 RAISE 语句来触发。当引发一个异常错误时，控制就转向到 EXCEPTION块异常错误部分，执行错误处理代码。
    • 这类异常情况的处理，步骤如下：
      1．在PL/SQL 块的定义部分定义异常情况：
      <异常情况> EXCEPTION;
      2．RAISE <异常情况>；
      3．在PL/SQL 块的异常情况处理部分对异常情况做出相应的处理。

    例3：更新指定员工工资，增加100；若该员工不存在则抛出用户自定义异常: no_result
    image

    d. 定义的异常弹出框

    declare 
	age int:=-2;
--  age int:='&请输入年龄：'; -- 从控制器接收一个参数，必须安装了sql plus
	my_age_exception exception; /*自定义异常*/
begin
	if age <=0 or age >=120 then
		raise my_age_exception; /*产生异常情况*/
	end if;
	dbms_output.put_line(age);
exception
	when my_age_exception then
		dbms_output.put_line(age||':不在0 到 120 范围');
		--必须大写
-- 		ralse_application_error(4001,'年龄范围出错，必须是[0-120]');
		/*通过弹出框 显示异常编号和异常原因*/
		RAISE_APPLICATION_ERROR(4001,'年龄范围出错，必须是[0,120]');
	when others then 
		dbms_output.put_line('出现了其他异常');
end;

    --控制台
> ORA-21000: error number argument to raise_application_error of 4001 is out of range
ORA-06512: at line 12

    5.2 在 PL/SQL 中使用 SQLCODE, SQLERRM

    SQLCODE 返回错误代码数字
    SQLERRM 返回错误信息.
    如

    SQLCODE=-100 -> SQLERRM='no_data_found'
SQLCODE=0    ->  SQLERRM='normal, successfual completion'

    例5. 将ORACLE错误代码及其信息存入错误代码表

    CREATE TABLE errors (errnum NUMBER(4), errmsg VARCHAR2(100)); 
 
DECLARE 
   err_msg  VARCHAR2(100); 
BEGIN 
   /*  得到所有 ORACLE 错误信息  */ 
   FOR err_num IN -100 .. 0 LOOP 
      err_msg := SQLERRM(err_num); 
      INSERT INTO errors VALUES(err_num, err_msg); 
   END LOOP; 
END; 
 
DROP TABLE errors;

    例6. 查询ORACLE错误代码；

    BEGIN 
   INSERT INTO emp(empno, ename, hiredate, deptno) 
     VALUES(2222, ‘Jerry’, SYSDATE, 20); 
   DBMS_OUTPUT.PUT_LINE('插入数据记录成功!'); 
   INSERT INTO emp(empno, ename, hiredate, deptno) 
     VALUES(2222, ‘Jerry’, SYSDATE, 20); 
   DBMS_OUTPUT.PUT_LINE('插入数据记录成功!'); 
EXCEPTION 
   WHEN OTHERS THEN 
      DBMS_OUTPUT.PUT_LINE(SQLCODE||’---‘||SQLERRM); 
END;

    第六章 存储函数和过程

    6.1 引言

    • ORACLE 提供可以把PL/SQL 程序存储在数据库中，并可以在任何地方来运行它。这样就叫存储过程或函数。过程和函数统称为PL/SQL子程序，他们是被命名的PL/SQL块，均存储在数据库中，并通过输入、输出参数或输入/输出参数与其调用者交换信息。过程和函数的唯一区别是函数总向调用者返回数据，而过程则不返回数据。

    6.2 创建函数

    a. 建立内嵌函数

    语法如下：

    • 声明函数后没有分号!!! return 类型的时候也没有分号!!! 如果不声明变量也必须带一个 is/as!!!
    • 一个函数如果没有参数列表 括号不用写否则写了必须传参
    CREATE [OR REPLACE] FUNCTION function_name 
	[ (argment [ { IN | IN OUT }] Type, 
		argment [ { IN | OUT | IN OUT } ] Type )] 
	[ AUTHID DEFINER | CURRENT_USER ] 
	RETURN return_type  
{ IS | AS }  
	<类型.变量的说明>  
BEGIN 
	FUNCTION_body 
EXCEPTION 
	其它语句 
END;

    说明:

    1. OR REPLACE 为可选. 有了它, 可以或者创建一个新函数或者替换相同名字的函数, 而不会出现冲突

    2. 函数名后面是一个可选的参数列表, 其中包含 IN, OUT 或 IN OUT 标记. 参数之间用逗号隔开. IN 参数标记表示传递给函数的值在该函数执行中不改变; OUT 标记表示一个值在函数中进行计算并通过该参数传递给调用语句; IN OUT 标记表示传递给函数的值可以变化并传递给调用语句. 若省略标记, 则参数隐含为 IN。

    3. 因为函数需要返回一个值, 所以 RETURN 包含返回结果的数据类型.

    -- 判断一个数是不是质数
create or replace function 
	func_ho1(param int)
	return boolean
as
begin
 for i in 2..(param/2+1) loop
	if mod(param,2)=0 then
			return true;
		exit;
	end if;
 end loop;
 return false;
end;
-- 测试
declare 
	flag boolean;
begin
	flag:=func_ho1(22);
	if flag then 
		dbms_output.put_line('不是质数');
	else
		dbms_output.put_line('是质数');
	end if;
end;

    例1. 不带参数的函数
    image
    执行该函数
    image

    例2. 获取某部门的工资总和：
    image

    b. 内嵌函数的调用

    • 函数声明时所定义的参数称为形式参数，应用程序调用时为函数传递的参数称为实际参数。应用程序在调用函数时，可以使用以下三种方法向函数传递参数：

    • 第一种参数传递格式称为位置表示法:格式为：
      argument_value1[,argument_value2 …]

    例3：计算某部门的工资总和：
    image

    • 第二种参数传递格式称为名称表示法，格式为：
      argument => parameter [,…]
      其中：argument 为形式参数，它必须与函数定义时所声明的形式参数名称相同。Parameter 为实际参数。
      在这种格式中，形势参数与实际参数成对出现，相互间关系唯一确定，所以参数的顺序可以任意排列。

    例4：计算某部门的工资总和：
    image

    • 第三种参数传递格式称为混合表示法：
      即在调用一个函数时，同时使用位置表示法和名称表示法为函数传递参数。采用这种参数传递方法时，使用位置表示法所传递的参数必须放在名称表示法所传递的参数前面。也就是说，无论函数具有多少个参数，只要其中有一个参数使用名称表示法，其后所有的参数都必须使用名称表示法。

    例5：
    image

    • 无论采用哪一种参数传递方法，实际参数和形式参数之间的数据传递只有两种方法：传址法和传值法。所谓传址法是指在调用函数时，将实际参数的地址指针传递给形式参数，使形式参数和实际参数指向内存中的同一区域，从而实现参数数据的传递。这种方法又称作参照法，即形式参数参照实际参数数据。输入参数均采用传址法传递数据。
    • 传值法是指将实际参数的数据拷贝到形式参数，而不是传递实际参数的地址。默认时，输出参数和输入/输出参数均采用传值法。在函数调用时，ORACLE将实际参数数据拷贝到输入/输出参数，而当函数正常运行退出时，又将输出形式参数和输入/输出形式参数数据拷贝到实际参数变量中。

    c. 参数默认值

    • 在CREATE OR REPLACE FUNCTION 语句中声明函数参数时可以使用DEFAULT关键字为输入参数指定默认值。

    例6：
    image

    • 具有默认值的函数创建后，在函数调用时，如果没有为具有默认值的参数提供实际参数值，函数将使用该参数的默认值。但当调用者为默认参数提供实际参数时，函数将使用实际参数值。在创建函数时，只能为输入参数设置默认值，而不能为输入/输出参数设置默认值。

    image

    d. 使用 pl/sql调用和 select调用函数

    tips
    注意不是所有函数能使用 select
    select 是sql语句；
    function 是pl/sql，pl/sql支持所有的 sql数据类型，还支持 boolean %rowtype %type

    create or replace function -- 创建函数
	f_1(a int,b float) --创建函数所需要的参数
	return float --函数返回值
as 
	sumab float; --创建一个变量，准备返回的变量
begin 
	sumab:=a+b;-- 返回变量赋值
	return sumab; --返回变量
end;

-- pl/sql 调用
declare 
	sumab float;
begin
 sumab:=f_1(2,11.1);
 dbms_output.put_line(sumab);
end;
-- select 调用
select f_1(2,11.4) from dual;
    • 参数是 boolean：pl/sql可以调用
      select不能调用
    • 返回值是 boolean：pl/sql 可以调用
      select 不能调用
    • 参数是 %rowtype：pl/sql 可以调用
      select 不能调用
    • 返回值是 %rowtype：pl/sql 可以调用
      select 可以调用

    总结

    • 如果 function的参数类型或者返回值，值类型是 sql支持的类型或者 %type，这样的 function可以被 pl/sql调用还可以被 select调用
    • 如果 function的参数类型或者返回值类型是 boolean或者 %rowtype，这样的 function只能被 pl/sql调用，不能被 select调用

    6.3 存储过程

    a. 创建过程

    • 建立存储过程
      在 ORACLE SERVER上建立存储过程,可以被多个应用程序调用,可以向存储过程传递参数,也可以向存储过程传回参数.

    创建过程语法:

    • 声明存储过程后没有分号，一个参数使用 存储过程名字,不需要加括号。如果不声明变量也必须带一个 as/is
    CREATE [OR REPLACE] PROCEDURE Procedure_name 
		[ (argment [ { IN | IN OUT }] Type, 
		argment [ { IN | OUT | IN OUT } ] Type )] 
	[ AUTHID DEFINER | CURRENT_USER ] 
	{ IS | AS } 
	<类型.变量的说明>  
BEGIN 
	<执行部分> 
EXCEPTION 
	<可选的异常错误处理程序> 
END;

    例7．删除指定员工记录；
    image

    例8．插入员工记录；
    image

    b. 调用存储过程

    • 使用 Oracle客户端：sql plus
      打开客户端的输入流：set serverout on;
      执行 execute命令：execute Procedure_name(value1,value2...);
    • 或者在 begin end;之间调用
      begin 
	Procedure_name  [ (argment [ { IN | IN OUT }] ;
end;

    例9：查询指定员工记录；
    image
    调用方法:
    image
    例10．计算指定部门的工资总和，并统计其中的职工数量。
    image

    调用方法:
    image

    c. AUTHID

    • 在创建存储过程时, 可使用 AUTHID CURRENT_USER 或 AUTHID DEFINER 选项,以表明在执行该过程时 Oracle 使用的权限.

    1. 如果使用 AUTHID CURRENT_USER 选项创建一个过程, 则 Oracle 用调用该过程的用户权限执行该过程. 为了成功执行该过程, 调用者必须具有访问该存储过程体中引用的所有数据库对象所必须的权限

    2. 如果用默认的 AUTHID DEFINER 选项创建过程, 则 Oracle 使用过程所有者的特权执行该过程. 为了成功执行该过程, 过程的所有者必须具有访问该存储过程体中引用的所有数据库对象所必须的权限. 想要简化应用程序用户的特权管理, 在创建存储过程时, 一般选择 AUTHID DEFINER 选项 –-- 这样就不必授权给需要调用的此过程的所有用户了.

    d. 开发存储过程步骤

    • 开发存储过程、函数、包及触发器的步骤如下：
    (1) 使用文字编辑处理软件编辑存储过程源码
    • 使用文字编辑处理软件编辑存储过程源码，，需将源码存为文本格式。
    (2) 在SQLPLUS或用调试工具将存储过程程序进行解释
    • 在SQLPLUS或用调试工具将存储过程程序进行解释；
    • 在SQL>下调试，可用START 或GET 等ORACLE命令来启动解释。如：
      SQL>START c:\stat1.sql
    (3) 调试源码直到正确
    • 我们不能保证所写的存储过程达到一次就正确。所以这里的调式是每个程序员必须进行的工作之一。在SQLPLUS下来调式主要用的方法是：
      • 使用 SHOW ERROR命令来提示源码的错误位置；
      • 使用 user_errors 数据字典来查看各存储过程的错误位置。
    (4) 授权执行权给相关的用户或角色
    • 如果调式正确的存储过程没有进行授权，那就只有建立者本人才可以运行。所以作为应用系统的一部分的存储过程也必须进行授权才能达到要求。在SQL*PLUS下可以用GRANT命令来进行存储过程的运行授权。
      GRANT EXECUTE ON dbms_job TO PUBLIC WITH GRANT OPTION
    (5) 与过程相关数据字典
    • USER_SOURCE, ALL_SOURCE, DBA_SOURCE, USER_ERRORS
    • 相关的权限:
      CREATE ANY PROCEDURE
      DROP ANY PROCEDURE
    • 在SQL*PLUS 中，可以用DESCRIBE 命令查看过程的名字及其参数表。
      DESCRIBE Procedure_name;

    e. 删除过程和函数

    (1) 删除过程
    • 可以使用DROP PROCEDURE命令对不需要的过程进行删除，语法如下：
      DROP PROCEDURE [user.]Procudure_name;
    (2) 删除函数
    • 可以使用DROP FUNCTION 命令对不需要的函数进行删除，语法如下：
      DROP FUNCTION [user.]Function_name;

    第七章 包的创建和应用

    7.1 引言

    • 包是一组相关过程、函数、变量、常量和游标等PL/SQL程序设计元素的组合，它具有面向对象程序设计语言的特点，是对这些PL/SQL 程序设计元素的封装。包类似于C++和JAVA语言中的类，其中变量相当于类中的成员变量，过程和函数相当于类方法。把相关的模块归类成为包，可使开发人员利用面向对象的方法进行存储过程的开发，从而提高系统性能。
    • 与类相同，包中的程序元素也分为公用元素和私用元素两种，这两种元素的区别是他们允许访问的程序范围不同，即它们的作用域不同。公用元素不仅可以被包中的函数、过程所调用，也可以被包外的PL/SQL程序访问，而私有元素只能被包内的函数和过程序所访问。
    • 在PL/SQL程序设计中，使用包不仅可以使程序设计模块化，对外隐藏包内所使用的信息（通过使用私用变量），而且可以提高程序的执行效率。因为，当程序首次调用包内函数或过程时，ORACLE将整个包调入内存，当再次访问包内元素时，ORACLE直接从内存中读取，而不需要进行磁盘I/O操作，从而使程序执行效率得到提高。
    • 一个包由两个分开的部分组成：
      1. 包定义（PACKAGE）：包定义部分声明包内数据类型、变量、常量、游标、子程序和异常错误处理等元素，这些元素为包的公有元素。
      2. 包主体（PACKAGE BODY）：包主体则是包定义部分的具体实现，它定义了包定义部分所声明的游标和子程序，在包主体中还可以声明包的私有元素。
      3. 包定义和包主体分开编译，并作为两部分分开的对象存放在数据库字典中，详见数据字典user_source, all_source, dba_source.

    7.2 包的定义

    包定义的语法如下：

    --创建包定义: 
CREATE [OR REPLACE] PACKAGE package_name 
	[AUTHID {CURRENT_USER | DEFINER}] 
	{IS | AS} 
	[公有数据类型定义[公有数据类型定义]…] 
	[公有游标声明[公有游标声明]…] 
	[公有变量、常量声明[公有变量、常量声明]…] 
	[公有子程序声明[公有子程序声明]…] 
END [package_name];

    tips
    其中：AUTHID CURRENT_USER和AUTHID DEFINER选项说明应用程序在调用函数时所使用的权限模式，它们与CREATE FUNCTION语句中invoker_right_clause子句的作用相同。

    创建包主体:

    CREATE [OR REPLACE] PACKAGE BODY package_name 
	{IS | AS} 
	[私有数据类型定义[私有数据类型定义]…] 
	[私有变量、常量声明[私有变量、常量声明]…] 
	[私有子程序声明和定义[私有子程序声明和定义]…] 
	[公有游标定义[公有游标定义]…] 
	[公有子程序定义[公有子程序定义]…] 
BEGIN 
	PL/SQL 语句 
END [package_name];

    tips
    其中：在包主体定义公有程序时，它们必须与包定义中所声明子程序的格式完全一致。

    7.3 包的开发步骤

    与开发存储过程类似，包的开发需要几个步骤：

    1. 将每个存储过程调式正确；
    2. 用文本编辑软件将各个存储过程和函数集成在一起；
      3．按照包的定义要求将集成的文本的前面加上包定义；
      4．按照包的定义要求将集成的文本的前面加上包主体；
      5．使用SQLPLUS或开发工具进行调式。

    7.4 包定义的说明

    例1:创建的包为demo_pack, 该包中包含一个记录变量DeptRec、两个函数和一个过程。

    CREATE OR REPLACE PACKAGE demo_pack 
IS 
 DeptRec dept%ROWTYPE; 
 FUNCTION add_dept( 
dept_no NUMBER, dept_name VARCHAR2, location VARCHAR2) 
 RETURN NUMBER; 
 FUNCTION remove_dept(dept_no NUMBER) 
  RETURN NUMBER; 
 PROCEDURE query_dept(dept_no IN NUMBER); 
END demo_pack;

    包主体的创建方法，它实现上面所声明的包定义

    CREATE OR REPLACE PACKAGE BODY demo_pack 
 IS  
FUNCTION add_dept 
(dept_no NUMBER, dept_name VARCHAR2, location VARCHAR2) 
 RETURN NUMBER 
 IS  
empno_remaining EXCEPTION; 
    PRAGMA EXCEPTION_INIT(empno_remaining, -1); 
   /* -1 是违反唯一约束条件的错误代码 */ 
BEGIN 
 INSERT INTO dept VALUES(dept_no, dept_name, location); 
 IF SQL%FOUND THEN 
  RETURN 1; 
 END IF; 
EXCEPTION 
    WHEN empno_remaining THEN  
  RETURN 0; 
 WHEN OTHERS THEN 
  RETURN -1; 
END add_dept; 

    FUNCTION remove_dept(dept_no NUMBER) 
 RETURN NUMBER 
 IS  
BEGIN 
 DELETE FROM dept WHERE deptno=dept_no; 
   IF SQL%FOUND THEN 
  RETURN 1; 
 ELSE 
  RETURN 0; 
   END IF; 
EXCEPTION 
WHEN OTHERS THEN 
  RETURN -1; 
END remove_dept; 

    PROCEDURE query_dept 
(dept_no IN NUMBER) 
 IS 
BEGIN 
SELECT * INTO DeptRec FROM dept WHERE deptno=dept_no; 
EXCEPTION 
    WHEN NO_DATA_FOUND THEN   
       DBMS_OUTPUT.PUT_LINE('数据库中没有编码为'||dept_no||'的部门'); 
    WHEN TOO_MANY_ROWS THEN 
       DBMS_OUTPUT.PUT_LINE('程序运行错误!请使用游标'); 
    WHEN OTHERS THEN 
        DBMS_OUTPUT.PUT_LINE(SQLCODE||’----‘||SQLERRM); 
END query_dept; 
 
BEGIN  
 Null; 
END demo_pack;

    对包内共有元素的调用格式为：包名.元素名称
    调用demo_pack包内函数对dept表进行插入、查询和修改操作，并通过demo_pack包中的记录变量DeptRec 显示所查询到的数据库信息：

    DECLARE 
 Var NUMBER; 
BEGIN 
 Var := demo_pack.add_dept(90,’Administration’, ‘Beijing’); 
 IF var =-1 THEN 
  DBMS_OUTPUT.PUT_LINE(SQLCODE||’----‘||SQLERRM); 
 ELSIF var =0 THEN 
  DBMS_OUTPUT.PUT_LINE(‘该部门记录已经存在！’); 
ELSE 
  DBMS_OUTPUT.PUT_LINE(‘添加记录成功！’); 
  Demo_pack.query_dept(90); 
  DBMS_OUTPUT.PUT_LINE(demo_pack.DeptRec.deptno||’---‘|| 
demo_pack.DeptRec.dname||’---‘||demo_pack.DeptRec.loc); 
  var := demo_pack.remove_dept(90); 
  IF var =-1 THEN 
   DBMS_OUTPUT.PUT_LINE(SQLCODE||’----‘||SQLERRM); 
  ELSIF var=0 THEN 
   DBMS_OUTPUT.PUT_LINE(‘该部门记录不存在！’); 
  ELSE 
   DBMS_OUTPUT.PUT_LINE(‘删除记录成功！’); 
  END IF; 
 END IF; 
END;

    例2: 创建包emp_package

    CREATE OR REPLACE PACKAGE emp_package  
 IS 
 TYPE emp_table_type IS TABLE OF emp%ROWTYPE  
  INDEX BY BINARY_INTEGER; 
 PROCEDURE read_emp_table (p_emp_table OUT emp_table_type); 
END emp_package; 
CREATE OR REPLACE PACKAGE BODY emp_package  
 IS 
 PROCEDURE read_emp_table (p_emp_table OUT emp_table_type)  
 IS 
 I BINARY_INTEGER := 0; 
 BEGIN 
  FOR emp_record IN ( SELECT * FROM emp ) LOOP 
   P_emp_table(i) := emp_record; 
   I := I + 1; 
  END LOOP; 
 END read_emp_table; 
END emp_package; 

    DECLARE  
 E_table emp_package.emp_table_type; 
BEGIN 
 Emp_package.read_emp_table(e_table); 
 FOR I IN e_table.FIRST .. e_table.LAST LOOP 
  DBMS_OUTPUT.PUT_LINE(e_table(i).empno||’  ‘||e_table(i).ename); 
 END LOOP; 
END;

    例3: 创建包emp_mgmt：

    CREATE SEQUENCE empseq  
START WITH 1000  
INCREMENT BY 1  
ORDER NOCYCLE; 
 
CREATE SEQUENCE deptseq 
START WITH 50 
INCREMENT BY 10  
ORDER NOCYCLE; 
 
CREATE OR REPLACE PACKAGE emp_mgmt  
AS 
FUNCTION hire(ename VARCHAR2, job VARCHAR2, mgr NUMBER, sal NUMBER,  
comm NUMBER, deptno NUMBER) 
  RETURN NUMBER; 
 FUNCTION create_dept(dname VARCHAR2, loc VARCHAR2) 
  RETURN NUMBER; 
PROCEDURE remove_emp(empno NUMBER); 
 PROCEDURE remove_dept(deptno NUMBER); 
 PROCEDURE increase_sal(empno NUMBER, sal_incr NUMBER); 
 PROCEDURE increase_comm(empno NUMBER, comm_incr NUMBER); 
END emp_mgmt; 

    CREATE OR REPLACE PACKAGE BODY emp_mgmt  
AS 
 tot_emps NUMBER; 
 tot_depts NUMBER; 
 no_sal EXCEPTION; 
 no_comm EXCEPTION; 
FUNCTION hire(ename VARCHAR2, job VARCHAR2, mgr NUMBER, 
 sal NUMBER, comm NUMBER, deptno NUMBER) 
RETURN NUMBER IS 
 new_empno NUMBER(4); 
BEGIN 
 SELECT empseq.NEXTVAL INTO new_empno FROM dual; 
 INSERT INTO emp  
VALUES (new_empno, ename, job, mgr, sysdate, sal, comm, deptno); 
 tot_emps:=tot_emps+1; 
RETURN(new_empno); 
EXCEPTION 
   WHEN OTHERS THEN 
      DBMS_OUTPUT.PUT_LINE('发生其它错误!'); 
END hire; 

    FUNCTION create_dept(dname VARCHAR2, loc VARCHAR2) 
RETURN NUMBER IS 
 new_deptno NUMBER(4); 
BEGIN 
 SELECT deptseq.NEXTVAL INTO new_deptno FROM dual; 
INSERT INTO dept VALUES (new_deptno, dname, loc); 
Tot_depts:=tot_depts; 
 RETURN(new_deptno); 
EXCEPTION 
   WHEN OTHERS THEN 
      DBMS_OUTPUT.PUT_LINE('发生其它错误!'); 
END create_dept; 

    PROCEDURE remove_emp(empno NUMBER) IS 
No_result EXCEPTION; 
BEGIN  
 DELETE FROM emp WHERE emp.empno=remove_emp.empno; 
IF SQL%NOTFOUND THEN 
      RAISE no_result; 
END IF; 
 tot_emps:=tot_emps-1; 
EXCEPTION 
   WHEN no_result THEN  
      DBMS_OUTPUT.PUT_LINE('你需要的数据不存在!'); 
   WHEN OTHERS THEN 
      DBMS_OUTPUT.PUT_LINE('发生其它错误!'); 
END remove_emp; 

    PROCEDURE remove_dept(deptno NUMBER) IS 
   No_result EXCEPTION; 
   e_deptno_remaining EXCEPTION; 
   PRAGMA EXCEPTION_INIT(e_deptno_remaining, -2292); 
   /* -2292 是违反一致性约束的错误代码 */ 
BEGIN 
 DELETE FROM dept WHERE dept.deptno=remove_dept.deptno; 
IF SQL%NOTFOUND THEN 
      RAISE no_result; 
END IF; 
Tot_depts:=tot_depts-1; 
EXCEPTION 
   WHEN no_result THEN  
      DBMS_OUTPUT.PUT_LINE('你需要的数据不存在!'); 
   WHEN e_deptno_remaining THEN  
      DBMS_OUTPUT.PUT_LINE('违反数据完整性约束!'); 
   WHEN OTHERS THEN 
      DBMS_OUTPUT.PUT_LINE('发生其它错误!'); 
END remove_dept; 

    PROCEDURE increase_sal(empno NUMBER, sal_incr NUMBER) IS 
 curr_sal NUMBER(7, 2); 
BEGIN 
 SELECT sal INTO curr_sal FROM emp WHERE emp.empno=increase_sal.empno; 
 IF curr_sal IS NULL THEN  
RAISE no_sal; 
 ELSE 
  UPDATE emp SET sal=sal+increase_sal.sal_incr  
WHERE emp.empno=increase_sal.empno; 
 END IF; 
EXCEPTION 
   WHEN NO_DATA_FOUND THEN  
      DBMS_OUTPUT.PUT_LINE('你需要的数据不存在!'); 
   WHEN no_sal THEN  
      DBMS_OUTPUT.PUT_LINE('此员工的工资不存在!'); 
   WHEN OTHERS THEN  
      DBMS_OUTPUT.PUT_LINE('发生其它错误!'); 
END increase_sal; 

    PROCEDURE increase_comm(empno NUMBER, comm_incr NUMBER) IS 
 curr_comm NUMBER(7,2); 
BEGIN  
 SELECT comm INTO curr_comm  
FROM emp WHERE emp.empno=increase_comm.empno; 
 IF curr_comm IS NULL THEN  
RAISE no_comm; 
 ELSE 
  UPDATE emp SET comm=comm+increase_comm.comm_incr 
WHERE emp.empno=increase_comm.empno; 
 END IF; 
EXCEPTION 
   WHEN NO_DATA_FOUND THEN  
      DBMS_OUTPUT.PUT_LINE('你需要的数据不存在!'); 
   WHEN no_comm THEN  
      DBMS_OUTPUT.PUT_LINE('此员工的奖金不存在!'); 
   WHEN OTHERS THEN  
      DBMS_OUTPUT.PUT_LINE('发生其它错误!'); 
END increase_comm; 
END EMP_MGMT; 
```sql
**例4：利用游标变量创建包Curvarpack。由于游标变量指是一个指针，其状态是不确定的，因此它不能随同包存储在数据库中，既不能在PL/SQL包中声明游标变量。但在包中可以创建游标变量参照类型，并可向包中的子程序传递游标变量参数**。 
```sql
CREATE OR REPLACE PACKAGE CurVarPack AS 
 TYPE DeptCurType IS REF CURSOR RETURN dept%ROWTYPE; --强类型定义 
 TYPE CurType IS REF CURSOR;-- 弱类型定义 
 PROCEDURE OpenDeptVar( 
  Cv IN OUT DeptCurType, 
  Choice INTEGER DEFAULT 0, 
  Dept_no NUMBER DEFAULT 50, 
  Dept_name VARCHAR DEFAULT ‘%’); 
END; 

    CREATE OR REPLACE PACKAGE BODY CurVarPack AS 
 PROCEDURE OpenDeptvar( 
  Cv IN OUT DeptCurType, 
  Choice INTEGER DEFAULT 0, 
  Dept_no NUMBER DEFAULT 50, 
  Dept_name VARCHAR DEFAULT ‘%’) 
 IS  
 BEGIN 
  IF choice =1 THEN 
   OPEN cv FOR SELECT * FROM dept WHERE deptno <= dept_no; 
  ELSIF choice = 2 THEN 
   OPEN cv FOR SELECT * FROM dept WHERE dname LIKE dept_name; 
  ELSE 
   OPEN cv FOR SELECT * FROM dept; 
  END IF; 
 END OpenDeptvar; 
END CurVarPack; 

    --定义一个过程 
CREATE OR REPLACE PROCEDURE OpenCurType( 
 Cv IN OUT CurVarPack.CurType, 
 Tab CHAR)  
AS 
BEGIN 
 --由于CurVarPack.CurType采用弱类型定义 
--所以可以使用它定义的游标变量打开不同类型的查询语句 
 IF tab = ‘D’ THEN 
  OPEN cv FOR SELECT * FROM dept; 
 ELSE 
  OPEN cv FOR SELECT * FROM emp; 
 END IF; 
END OpenCurType; 

    --定义一个应用 
DECLARE  
 DeptRec Dept%ROWTYPE; 
 EmpRec Emp%ROWTYPE; 
 Cv1 Curvarpack.deptcurtype; 
 Cv2 Curvarpack.curtype; 
BEGIN 
 DBMS_OUTPUT.PUT_LINE(’游标变量强类型定义应用’); 
 Curvarpack.OpenDeptVar(cv1, 1, 30); 
 FETCH cv1 INTO DeptRec; 
 WHILE cv1%FOUND LOOP 
  DBMS_OUTPUT.PUT_LINE(DeptRec.deptno||’:’||DeptRec.dname); 
  FETCH cv1 INTO DeptRec; 
 END LOOP; 
 CLOSE cv1; 
 
 DBMS_OUTPUT.PUT_LINE(’游标变量弱类型定义应用’); 
 CurVarPack.OpenDeptvar(cv2, 2, dept_name => ‘A%’); 
 FETCH cv2 INTO DeptRec; 
 WHILE cv2%FOUND LOOP 
  DBMS_OUTPUT.PUT_LINE(DeptRec.deptno||’:’||DeptRec.dname); 
  FETCH cv2 INTO DeptRec; 
 END LOOP; 
 
 DBMS_OUTPUT.PUT_LINE(’游标变量弱类型定义应用—dept表’); 
 OpenCurtype(cv2, ‘D’); 
 FETCH cv2 INTO DeptRec; 
 WHILE cv2%FOUND LOOP 
  DBMS_OUTPUT.PUT_LINE(deptrec.deptno||’:’||deptrec.dname); 
  FETCH cv2 INTO deptrec; 
 END LOOP; 
 
 DBMS_OUTPUT.PUT_LINE(’游标变量弱类型定义应用—emp表’); 
 OpenCurtype(cv2, ‘E’); 
 FETCH cv2 INTO EmpRec; 
 WHILE cv2%FOUND LOOP 
  DBMS_OUTPUT.PUT_LINE(emprec.empno||’:’||emprec.ename); 
  FETCH cv2 INTO emprec; 
 END LOOP; 
CLOSE cv2; 
END;

    7.4.1 练习

    包声明

    create or replace package 
    pack_miao
is
    function f_1(n int) return boolean;  --判断是不是质数
    function f_2(str varchar) return varchar;--对字符串进行转换
    procedure p_1(n in out int,m int);--用n获取n+m
    procedure p_2(str in out varchar);--用s1获取s1所有不重复的字符
end pack_miao;

    包体

    create or replace package body
    pack_miao
is
    function f_1(n int) return boolean
    as
    begin
         for m in 2..n-1 loop
              if mod(n,m)=0 then
                  return false;
              end if;
         end loop;
         return n>1;
    end f_1;
    
    function f_2(str varchar) return varchar
    as
        strNew varchar(4000):='';
        c varchar(3);
    begin
        for i in 1..length(str) loop
            c:=substr(str,i,1);
            if c>= 'a' and c <='z' then
                 c:=upper(c);
                 strNew:=strNew||c;
            elsif c>= 'A' and c <='Z' then
                c:=lower(c);
                 strNew:=strNew||c;
            elsif c> '9' or c <'0' then
                 strNew:=strNew||c;
            end if;     
        end loop;
        return strNew;
    end f_2;
    
    procedure p_1(n in out int,m int)
    as
    begin
      n:=n+m;
    end p_1;
    
    procedure p_2(str in out varchar)
    as
       strNew varchar(4000):=substr(str,1,1);
       c varchar(3);
    begin
       for i in 2..length(str) loop
            c:=substr(str,i,1);
            dbms_output.put_line(c||'-'||instr(strNew,c));
            if instr(strNew,c,1)=0 then
                strNew:=strNew||c;
            end if;
       end loop;
       str:=strNew;
    end p_2;
end pack_miao;

    调用

    select pack_miao.f_2('123abcABCX呵呵&*&*') from dual;



begin
   for n in 1..100 loop
       if pack_miao.f_1(n) then
            dbms_output.put_line(n||'是质数');
       end if;
   end loop;
end;


declare
   str varchar(20):='&请输入一个字符串：';
begin
   pack_miao.p_2(str);
   dbms_output.put_line('转换后：'||str);
end;

    7.5 子程序重载

    • PL/SQL 允许对包内子程序和本地子程序进行重载。所谓重载时指两个或多个子程序有相同的名称，但拥有不同的参数变量、参数顺序或参数数据类型。
      例5：
    CREATE OR REPLACE PACKAGE demo_pack1 
IS 
 DeptRec dept%ROWTYPE; 
 V_sqlcode NUMBER; 
 V_sqlerr VARCHAR2(2048); 
 FUNCTION query_dept(dept_no IN NUMBER) 
  RETURN INTEGER; 
 FUNCTION query_dept(dept_no IN VARCHAR2) 
  RETURN INTEGER; 
END demo_pack1; 

    CREATE OR REPLACE PACKAGE BODY demo_pack1 
 IS  
FUNCTION check_dept(dept_no NUMBER) 
 RETURN INTEGER 
IS 
 Flag INTEGER; 
BEGIN 
 SELECT COUNT(*) INTO flag FROM dept WHERE deptno=dept_no; 
 IF flag > 0 THEN 
  RETURN 1; 
 ELSE 
  RETURN 0; 
 END IF; 
END check_dept; 

    FUNCTION check_dept(dept_no VARCHAR2) 
 RETURN INTEGER 
IS 
 Flag INTEGER; 
BEGIN 
 SELECT COUNT(*) INTO flag FROM dept WHERE deptno=dept_no; 
 IF flag > 0 THEN 
  RETURN 1; 
 ELSE 
  RETURN 0; 
 END IF; 
END check_dept; 
 
FUNCTION query_dept(dept_no IN NUMBER) 
 RETURN INTEGER 
IS 
BEGIN 
 IF check_dept(dept_no) =1 THEN 
  SELECT * INTO DeptRec FROM dept WHERE deptno=dept_no; 
  RETURN 1; 
 ELSE 
  RETURN 0; 
 END IF; 
END query_dept; 

    FUNCTION query_dept(dept_no IN VARCHAR2) 
 RETURN INTEGER 
IS 
BEGIN 
 IF check_dept(dept_no) =1 THEN 
  SELECT * INTO DeptRec FROM dept WHERE deptno=dept_no; 
  RETURN 1; 
 ELSE 
  RETURN 0; 
 END IF; 
END query_dept; 
 
END demo_pack1;
```sql
### 7.6  删除包 
可以使用 DROP PACKAGE 命令对不需要的包进行删除，语法如下： 
```sql
DROP PACKAGE [BODY] [user.]package_name; 
 
DROP PACKAGE demo_pack; 
DROP PACKAGE demo_pack1; 
DROP PACKAGE emp_mgmt; 
DROP PACKAGE emp_package;

    7.7 包的管理

    DBA_SOURCE, USER_SOURCE, USER_ERRORS, DBA-OBJECTS

    第八章 触发器

    • 触发器是许多关系数据库系统都提供的一项技术。在ORACLE系统里，触发器类似过程和函数，都有声明，执行和异常处理过程的PL/SQL块。

    8.1 触发器类型

    • 触发器在数据库里以独立的对象存储，它与存储过程不同的是，存储过程通过其它程序来启动运行或直接启动运行，而触发器是由一个事件来启动运行。即触发器是当某个事件发生时自动地隐式运行。并且，触发器不能接收参数。所以运行触发器就叫触发或点火（firing）。ORACLE事件指的是对数据库的表进行的INSERT、UPDATE及DELETE操作或对视图进行类似的操作。ORACLE将触发器的功能扩展到了触发ORACLE，如数据库的启动与关闭等。

    a. DML触发器

    • ORACLE可以在DML语句进行触发，可以在DML操作前或操作后进行触发，并且可以对每个行或语句操作上进行触发。

    b. 替代触发器

    • 由于在ORACLE里，不能直接对由两个以上的表建立的视图进行操作。所以给出了替代触发器。

    c. 系统触发器

    • 它可以在ORACLE数据库系统的事件中进行触发，如ORACLE系统的启动与关闭等。

    触发器组成:

    1. 触发事件：即在何种情况下触发TRIGGER; 例如：INSERT, UPDATE, DELETE。
    2. 触发时间：即该TRIGGER 是在触发事件发生之前（BEFORE）还是之后(AFTER)触发，也就是触发事件和该TRIGGER 的操作顺序。
    3. 触发器本身：即该TRIGGER 被触发之后的目的和意图，正是触发器本身要做的事情。 例如：PL/SQL 块。
    4. 触发频率：说明触发器内定义的动作被执行的次数。即语句级(STATEMENT)触发器和行级(ROW)触发器。
      语句级(STATEMENT)触发器：是指当某触发事件发生时，该触发器只执行一次；
      行级(ROW)触发器：是指当某触发事件发生时，对受到该操作影响的每一行数据，触发器都单独执行一次。

    8.2 创建触发器

    创建触发器的一般语法是:

    CREATE [OR REPLACE] TRIGGER trigger_name 
	{BEFORE | AFTER } 
	{INSERT | DELETE | UPDATE [OF column [, column …]]} 
ON [schema.] table_name  
	[FOR EACH ROW ] 
	[WHEN condition] 
trigger_body;
    • 其中：
      • BEFORE 和AFTER指出触发器的触发时序分别为前触发和后触发方式，前触发是在执行触发事件之前触发当前所创建的触发器，后触发是在执行触发事件之后触发当前所创建的触发器。
      • FOR EACH ROW选项说明触发器为行触发器。行触发器和语句触发器的区别表现在：行触发器要求当一个DML语句操做影响数据库中的多行数据时，对于其中的每个数据行，只要它们符合触发约束条件，均激活一次触发器；而语句触发器将整个语句操作作为触发事件，当它符合约束条件时，激活一次触发器。当省略FOR EACH ROW 选项时，BEFORE 和AFTER 触发器为语句触发器，而INSTEAD OF 触发器则为行触发器。
      • WHEN 子句说明触发约束条件。Condition 为一个逻辑表达时，其中必须包含相关名称，而不能包含查询语句，也不能调用PL/SQL 函数。WHEN 子句指定的触发约束条件只能用在BEFORE 和AFTER 行触发器中，不能用在INSTEAD OF 行触发器和其它类型的触发器中。
      • 当一个基表被修改( INSERT, UPDATE, DELETE)时要执行的存储过程，执行时根据其所依附的基表改动而自动触发，因此与应用程序无关，用数据库触发器可以保证数据的一致性和完整性。
    • 每张表最多可建立12 种类型的触发器，它们是:
      BEFORE INSERT 
BEFORE INSERT FOR EACH ROW 
AFTER INSERT 
AFTER INSERT FOR EACH ROW 

BEFORE UPDATE 
BEFORE UPDATE FOR EACH ROW 
AFTER UPDATE 
AFTER UPDATE FOR EACH ROW 

BEFORE DELETE 
BEFORE DELETE FOR EACH ROW 
AFTER DELETE 
AFTER DELETE FOR EACH ROW

    a. 触发器触发次序

    1. 执行 BEFORE语句级触发器;
    2. 对与受语句影响的每一行：
      执行 BEFORE行级触发器
      执行 DML语句
      执行 AFTER行级触发器
    3. 执行 AFTER语句级触发器

    b. 创建DML触发器

    • 触发器名可以和表或过程有相同的名字，但在一个模式中触发器名不能相同。
    • 触发器的限制
      1. CREATE TRIGGER语句文本的字符长度不能超过32KB；
      2. 触发器体内的SELECT 语句只能为SELECT … INTO …结构，或者为定义游标所使用的SELECT 语句。
      3. 触发器中不能使用数据库事务控制语句 COMMIT; ROLLBACK, SVAEPOINT 语句；
      4. 由触发器所调用的过程或函数也不能使用数据库事务控制语句；

    问题：当触发器被触发时，要使用被插入、更新或删除的记录中的列值，有时要使用操作前、后列的值.

    • 实现:
      :NEW 修饰符访问操作完成后列的值
      :OLD 修饰符访问操作完成前列的值
    特性 INSERT UPDATE DELETE
    OLD NULL 有效 有效
    NEW 有效 有效 NULL

    例1: 建立一个触发器, 当职工表 emp 表被删除一条记录时，把被删除记录写到职工表删除日志表中去。
    image
    image

    c. 创建替代(INSTEAD OF)触发器

    创建触发器的一般语法是:

    CREATE [OR REPLACE] TRIGGER trigger_name 
INSTEAD OF 
{INSERT | DELETE | UPDATE [OF column [, column …]]} 
ON [schema.] view_name 
[FOR EACH ROW ] 
[WHEN condition] 
trigger_body;

    其中：

    • BEFORE 和AFTER指出触发器的触发时序分别为前触发和后触发方式，前触发是在执行触发事件之前触发当前所创建的触发器，后触发是在执行触发事件之后触发当前所创建的触发器。
    • INSTEAD OF 选项使ORACLE激活触发器，而不执行触发事件。只能对视图和对象视图建立INSTEAD OF触发器，而不能对表、模式和数据库建立INSTEAD OF 触发器。
    • FOR EACH ROW选项说明触发器为行触发器。行触发器和语句触发器的区别表现在：行触发器要求当一个DML语句操做影响数据库中的多行数据时，对于其中的每个数据行，只要它们符合触发约束条件，均激活一次触发器；而语句触发器将整个语句操作作为触发事件，当它符合约束条件时，激活一次触发器。当省略FOR EACH ROW 选项时，BEFORE 和AFTER 触发器为语句触发器，而INSTEAD OF 触发器则为行触发器。
    • WHEN 子句说明触发约束条件。Condition 为一个逻辑表达时，其中必须包含相关名称，而不能包含查询语句，也不能调用PL/SQL 函数。WHEN 子句指定的触发约束条件只能用在BEFORE 和AFTER 行触发器中，不能用在INSTEAD OF 行触发器和其它类型的触发器中。
    • INSTEAD_OF 用于对视图的DML触发，由于视图有可能是由多个表进行联结(join)而成，因而并非是所有的联结都是可更新的。但可以按照所需的方式执行更新，例如下面情况：
      CREATE OR REPLACE VIEW emp_view AS  
SELECT deptno, count(*) total_employeer, sum(sal) total_salary  
FROM emp GROUP BY deptno;
    • 在此视图中直接删除是非法：
      SQL>DELETE FROM emp_view WHERE deptno=10; 
DELETE FROM emp_view WHERE deptno=10 
			* 
ERROR 位于第 1 行: 
ORA-01732: 此视图的数据操纵操作非法
    • 但是可以创建INSTEAD_OF触发器来为 DELETE 操作执行所需的处理，即删除EMP表中所有基准行：
      CREATE OR REPLACE TRIGGER emp_view_delete 
   INSTEAD OF DELETE ON emp_view FOR EACH ROW 
BEGIN 
   DELETE FROM emp WHERE deptno= :old.deptno; 
END emp_view_delete; 

DELETE FROM emp_view WHERE deptno=10; 

DROP TRIGGER emp_view_delete; 
DROP VIEW emp_view;

    d. 创建系统事件触发器

    • ORACLE提供的系统事件触发器可以在DDL或数据库系统上被触发。DDL指的是数据定义语言，如CREATE 、ALTER及DROP 等。而数据库系统事件包括数据库服务器的启动或关闭，用户的登录与退出、数据库服务错误等。创建系统触发器的语法如下：
      创建触发器的一般语法是:
    CREATE OR REPLACE TRIGGER [sachema.] trigger_name 
    {BEFORE|AFTER}   
	{ddl_event_list | database_event_list} 
    ON { DATABASE | [schema.] SCHEMA } 
    [WHEN_clause]  
    trigger_body;
    • 其中: ddl_event_list：一个或多个DDL 事件，事件间用 OR 分开；
      database_event_list：一个或多个数据库事件，事件间用 OR 分开；
    • 系统事件触发器既可以建立在一个模式上，又可以建立在整个数据库上。当建立在模式(SCHEMA)之上时，只有模式所指定用户的DDL操作和它们所导致的错误才激活触发器, 默认时为当前用户模式。当建立在数据库(DATABASE)之上时，该数据库所有用户的DDL操作和他们所导致的错误，以及数据库的启动和关闭均可激活触发器。要在数据库之上建立触发器时，要求用户具有ADMINISTER DATABASE TRIGGER权限。
    • 下面给出系统触发器的种类和事件出现的时机（前或后）：
    事件 允许的时机 说明
    启动STARTUP 之后 实例启动时激活
    关闭SHUTDOWN 之前 实例正常关闭时激活
    服务器错误SERVERERROR 之后 只要有错误就激活
    登录LOGON 之后 成功登录后激活
    注销LOGOFF 之前 开始注销时激活
    创建CREATE 之前，之后 在创建之前或之后激活
    撤消DROP 之前，之后 在撤消之前或之后激活
    变更ALTER 之前，之后 在变更之前或之后激活

    e. 系统触发器事件属性

    事件属性\事件 Startup/Shutdown Servererror Logon/Logoff DDL DML
    事件名称 * * * * *
    数据库名称 *
    数据库实例号 *
    错误号 *
    用户名 * *
    模式对象类型 * *
    模式对象名称 * *
    列 *
    • 除DML语句的列属性外，其余事件属性值可通过调用ORACLE定义的事件属性函数来读取。
    函数名称 数据类型 说 明
    Sysevent VARCHAR2（20） 激活触发器的事件名称
    Instance_num NUMBER 数据库实例名
    Database_name VARCHAR2（50） 数据库名称
    Server_error(posi) NUMBER 错误信息栈中posi指定位置中的错误号
    Is_servererror(err_number) BOOLEAN 检查err_number指定的错误号是否在错误信息栈中，如果在则返回TRUE，否则返回FALSE。在触发器内调用此函数可以判断是否发生指定的错误。
    Login_user VARCHAR2(30) 登陆或注销的用户名称
    Dictionary_obj_type VARCHAR2(20) DDL语句所操作的数据库对象类型
    Dictionary_obj_name VARCHAR2(30) DDL语句所操作的数据库对象名称
    Dictionary_obj_owner VARCHAR2(30) DDL语句所操作的数据库对象所有者名称
    Des_encrypted_password VARCHAR2(2) 正在创建或修改的经过DES算法加密的用户口令

    f. 使用触发器谓词

    • ORACLE 提供三个参数INSERTING, UPDATING, DELETING 用于判断触发了哪些操作。
    谓词 行为
    INSERTING 如果触发语句是 INSERT 语句，则为TRUE,否则为FALSE
    UPDATING 如果触发语句是 UPDATE语句，则为TRUE,否则为FALSE
    DELETING 如果触发语句是 DELETE 语句，则为TRUE,否则为FALSE

    g. 重新编译触发器

    • 如果在触发器内调用其它函数或过程，当这些函数或过程被删除或修改后，触发器的状态将被标识为无效。当DML语句激活一个无效触发器时，ORACLE将重新编译触发器代码，如果编译时发现错误，这将导致DML语句执行失败。
    • 在PL/SQL程序中可以调用ALTER TRIGGER语句重新编译已经创建的触发器，格式为：
    • ALTER TRIGGER [schema.] trigger_name COMPILE [ DEBUG]
    • 其中：DEBUG 选项要器编译器生成PL/SQL 程序条使其所使用的调试代码。

    8.3 删除和使能触发器

    • 删除触发器：
      DROP TRIGGER trigger_name;
      当删除其他用户模式中的触发器名称，需要具有DROP ANY TRIGGER系统权限，当删除建立在数据库上的触发器时，用户需要具有ADMINISTER DATABASE TRIGGER系统权限。
      此外，当删除表或视图时，建立在这些对象上的触发器也随之删除。

    • 触发器的状态
      数据库TRIGGER 的状态：
      有效状态(ENABLE)：当触发事件发生时，处于有效状态的数据库触发器TRIGGER 将被触发。
      无效状态(DISABLE)：当触发事件发生时，处于无效状态的数据库触发器TRIGGER 将不会被触发，此时就跟没有这个数据库触发器(TRIGGER) 一样。
      数据库TRIGGER的这两种状态可以互相转换。格式为：
      ALTER TIGGER trigger_name [DISABLE | ENABLE ];
      例：ALTER TRIGGER emp_view_delete DISABLE;
      ALTER TRIGGER语句一次只能改变一个触发器的状态，而ALTER TABLE语句则一次能够改变与指定表相关的所有触发器的使用状态。格式为：
      ALTER TABLE [schema.]table_name {ENABLE|DISABLE} ALL TRIGGERS;
      例：使表EMP 上的所有TRIGGER 失效：
      ALTER TABLE emp DISABLE ALL TRIGGERS;
  • 相关阅读:
    Pandas 基础(8)
    Pandas 基础(7)
    Pandas 基础(6)
    Pandas 基础(5)
    Pandas 基础(4)
    python matplotlib 图表局部放大
    python 带小数点时间格式化
    emacs elpy代码补全功能
    spacemacs 初始安装报错
    视频加载logo 2
  • 原文地址：https://www.cnblogs.com/zk2020/p/15582051.html
Copyright © 2020-2023  润新知