Windows多版本JDK切换脚本

一、根据需求安装不同版本JDK；

二、新建系统变量“CLASSPATH”和“JAVA_HOME”，“CLASSPATH”变量值中添加“%JAVA_HOME%\lib\dt.jar”和“%JAVA_HOME%\lib\tools.jar”，“JAVA_HOME”变量值中添加任意一个JDK安装路径即可，“Path”变量值中添加“%JAVA_HOME%\bin”和“%JAVA_HOME%\jre\bin”；

 

 

三、新建txt文本，复制粘贴脚本，修改文件类型为bat，根据JDK安装数量修改列表及ELSE IF语句即可。

@echo off
::获取管理员权限
%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
cd /d "%~dp0"

::设置显示模式
mode con cols=85 lines=25 & color 3f
title SWJDK批处理脚本

:menu
echo 当前的JDK版本:
java -version 
echo.
echo ============================================= 
echo ################ JDK版本列表 ################
echo.                       
echo         【8】切换至JDK8
echo         【9】切换至JDK9
echo         【0】取消
echo.
echo =============================================
echo.

set /P vb=请选择要切换的JDK版本:
IF "%vb%" EQU "8" (
    setx "JAVA_HOME" "D:\develop\Java\jdk1.8.0_321" /m
    echo 提示: JDK版本切换成功，"JAVA_HOME" 已修改为 D:\develop\Java\jdk1.8.0_321。
    echo.
) ELSE IF "%vb%" EQU "9" (
    setx "JAVA_HOME" "D:\develop\Java\jdk-9.0.4" /m
    echo 提示: JDK版本切换成功，"JAVA_HOME" 已修改为 D:\develop\Java\jdk-9.0.4。
    echo.
) ELSE IF "%vb%" EQU "0" (
       goto exit
) ELSE (
    echo.
    echo ！！！版本选择错误，请重新选择. . .
    echo.
    goto menu
)

echo 请按任意键退出. . . & pause > nul

:exit