计数器练习13

当收到en = 1时 ，执行以下操作：

a. 间隔1个时钟周期后，dout产生宽度为 3 个时钟周期的高电平脉冲，然后

b. 间隔2个时钟周期后，dout产生宽度为 4 个时钟周期的高电平脉冲，然后

c. 间隔3个时钟周期后，dout产生宽度为5 个时钟周期的高电平脉冲，然后

d. 间隔4个时钟周期后，dout产生宽度为 6个时钟周期的高电平脉冲，结束。

波形如下：

第一关键点，间隔时钟，dout输出 x 个高电平，需一个计数器cnt0，引入了一个“x”变量，因为是在不同时间段赋不同值，说明该计数器可以重复利用

第二关键点，有a b c d 四轮，在需一个计数器cnt1，计数4轮

第三关键点，什么时候开始计数，收到en之后开始计数，增加一个信号进来 flag_add ， 那什么时候结束，四轮结束时，计数器停止

第四关键点， dout什么时候为高，什么时候为低，引入变量Y，也就是间隔Y个时钟

module cnt_test(
                clk,
                rst_n,
                en,
                dout
);

input     clk;
input     rst_n;
input      en;

output    dout;

reg     dout;
reg     flag_add;

reg [3:0] cnt0;
reg [3:0] cnt1;
reg [3:0] x;
reg [3:0] y;

wire add_cnt0;
wire end_cnt0;

wire add_cnt1;
wire end_cnt1;


always @(posedge clk or negedge rst_n)begin
    if(!rst_n)begin
        cnt0 <= 0;
    end
    else if(add_cnt0)begin
        if(end_cnt0)begin
            cnt0 <= 0;
        end
        else begin
            cnt0 <= cnt0 + 1;
        end
    end
end

assign add_cnt0 = flag_add;
assign end_cnt0 = add_cnt0 && cnt0 == x - 1;


always @(posedge clk or negedge rst_n)begin
    if(!rst_n)begin
        cnt1 <= 0;
    end
    else if(add_cnt1)begin
        if(end_cnt1)begin
            cnt1 <= 0;
        end
        else begin
            cnt1 <= cnt1 + 1;
        end
    end
end

assign add_cnt1 = end_cnt0;
assign end_cnt1 = add_cnt1 && cnt1 == 4 - 1;

always @(posedge clk or negedge rst_n)begin
    if(!rst_n)begin
        flag_add <= 0;
    end
    else if(en == 1)begin
        flag_add <= 1;
    end
    else if(end_cnt1)begin
        flag_add <= 0;
    end
end

always @(*)begin
    if(cnt1 == 0)begin
        x = 4;
        y = 1;
    end
    else if(cnt1 == 1)begin
        x = 6;
        y = 2;
    end
    else if(cnt1 == 2)begin
        x = 8;
        y = 3;
    end
/*    
    else if(cnt1 == 3)begin  //这里可以不添加if判断语句 ,否则必须将if else 补全，在其他状态时，一定要确保x有个确定值
        x = 2;
    end
*/
    else if(cnt1 == 3)begin
        x = 10;
        y = 4;
    end
    else begin  //if else 补全 ，以确保在其他状态时，x始终都能确定某一个固定值
        x = 0; 
        y = 0;
    end
    
end

always @(posedge clk or negedge rst_n)begin
    if(!rst_n)begin
        dout <= 0;
    end
    else if(add_cnt0 && cnt0 == y-1)begin //对某个点进行赋值，记得用“-1”写法
        dout <= 1;
    end
    else if(end_cnt0) begin    //对某个点进行赋值
        dout <= 0;    
    end
end

endmodule

仿真波形：