FPGA入门——basys2开发板的伪随机gold码的生成

本文原创，转载请注明出处。

1.gold码简介

gold码是一种伪随机码，由两个m序列通过不同的相位抽头与或产生，具有很好的自相关与互相关特性，广泛应用于扩频通信。GPS中使用的C/A扩频码即10位寄存器长度的gold码。

2.设计目标

本文在basys2内部产生10位寄存器长度的gold码，通过开关控制相位抽头，并通过0.5s刷新速度的LED流水灯显示。

3.vhdl源码

library IEEE;
use IEEE.STD_LOGIC_1164.ALL;
use IEEE.STD_LOGIC_ARITH.ALL;
use IEEE.STD_LOGIC_UNSIGNED.ALL;

entity top is
    port(
            clk        :    in        STD_LOGIC;    --系统时钟
            rst        :    in     STD_LOGIC;    --reset
            tap_1        :    in        STD_LOGIC_VECTOR ( 3 downto 0 );    --m序列相位选择，根据具体输入硬件而定
            tap_2        :    in        STD_LOGIC_VECTOR ( 3 downto 0 );    
            led        :    out    STD_LOGIC_VECTOR ( 7 downto 0 )    --led流水灯控制，根据具体输出硬件而定
            );
end top;

architecture Behavioral of top is
    signal    reg_1        :    STD_LOGIC_VECTOR( 9 downto 0 );    --10位循环移位寄存器
    signal    reg_2        :    STD_LOGIC_VECTOR( 9 downto 0 );
    signal    reg_gold    :    STD_LOGIC_VECTOR( 7 downto 0 );    --gold码8位缓存用于显示
    signal    tmp_1        :    STD_LOGIC;    --循环移位反馈信号
    signal    tmp_2        :    STD_LOGIC;
    signal    m_1        :    STD_LOGIC;    --m序列
    signal    m_2        :    STD_LOGIC;
    signal    gold        :    STD_LOGIC;    --gold序列
    signal    clk_sec    :    STD_LOGIC:='0';    --秒时钟
    signal    cnt_sec    :    INTEGER;    --用于产生秒时钟的模
    
begin
led(7 downto 0)<=reg_gold(7 downto 0);    --输出给8个Led灯

    --产生秒时钟clk_sec的模块
    process(clk,rst)
    begin
    if (rst='0') then
        cnt_sec<=0;
    elsif(clk'event and clk='1') then
        if(cnt_sec=12500000) then
            cnt_sec<=0;
            clk_sec<=not clk_sec;
        else
            cnt_sec<=cnt_sec+1;
        end if;
    end if;
    end process;    

    --产生m序列1
    process(clk_sec,rst,reg_1)
    begin
    tmp_1<=reg_1(2) xor reg_1(9);    --反馈抽头在第3、10位
        if (rst='0') then
            reg_1<=(others=>'1');
        elsif (clk_sec'event and clk_sec='1') then
            reg_1<=reg_1(8 downto 0)&tmp_1;    --循环移位
        end if;
    end process;
    
    --产生m序列2
    process(clk_sec,rst,reg_2)
    begin
    tmp_2<=(reg_2(1) xor reg_2(2))xor(reg_2(7) xor reg_2(9));    --反馈抽头在2、3、8、10位
        if (rst='0') then
            reg_2<=(others=>'1');
        elsif (clk_sec'event and clk_sec='1') then
            reg_2<=reg_2(8 downto 0)&tmp_2;    --循环移位
        end if;
    end process;    
    
    --m序列1的相位抽头选择，本部分根据具体输入硬件编程
    process(tap_1,reg_1)
    begin
        case tap_1 is
            when    b"0001"=>m_1<=reg_1(1);
            when    b"0010"=>m_1<=reg_1(2);
            when    b"0011"=>m_1<=reg_1(3);
            when    b"0100"=>m_1<=reg_1(4);
            when    b"0101"=>m_1<=reg_1(5);
            when    b"0110"=>m_1<=reg_1(6);
            when    b"0111"=>m_1<=reg_1(7);
            when    b"1000"=>m_1<=reg_1(8);
            when    b"1001"=>m_1<=reg_1(9);
            when    others =>m_1<=reg_1(0);
        end case;
    end process;
    
    --m序列2的相位抽头选择，本部分根据具体输入硬件编程
    process(tap_2,reg_2)
    begin
        case tap_2 is
            when    b"0001"=>m_2<=reg_2(1);
            when    b"0010"=>m_2<=reg_2(2);
            when    b"0011"=>m_2<=reg_2(3);
            when    b"0100"=>m_2<=reg_2(4);
            when    b"0101"=>m_2<=reg_2(5);
            when    b"0110"=>m_2<=reg_2(6);
            when    b"0111"=>m_2<=reg_2(7);
            when    b"1000"=>m_2<=reg_2(8);
            when    b"1001"=>m_2<=reg_2(9);
            when    others =>m_2<=reg_2(0);
        end case;
    end process;
    
    --gold码生成
    process(clk_sec,rst,m_1,m_2)
    begin
    gold<=m_1 xor m_2;
        if (rst='0') then
            reg_gold<=(others=>'0');
        elsif (clk_sec'event and clk_sec='1') then
            reg_gold<=reg_gold(6 downto 0)&gold;
        end if;
    end process;    
    
end Behavioral;

4.引脚定义

NET    "clk"             LOC="B8";
NET    "rst"             LOC="G12";
NET    "tap_1<0>"        LOC="N3";
NET    "tap_1<1>"        LOC="E2";
NET    "tap_1<2>"        LOC="F3";
NET    "tap_1<3>"        LOC="G3";
NET    "tap_2<0>"        LOC="B4";
NET    "tap_2<1>"        LOC="K3";
NET    "tap_2<2>"        LOC="L3";
NET    "tap_2<3>"        LOC="P11";
NET    "led<0>"          LOC="M5";
NET    "led<1>"          LOC="M11";
NET    "led<2>"          LOC="P7";
NET    "led<3>"          LOC="P6";
NET    "led<4>"          LOC="N5";
NET    "led<5>"          LOC="N4";
NET    "led<6>"          LOC="P4";
NET    "led<7>"          LOC="G1";