【CF675E】Trains and Statistic（贪心，DP，线段树优化）

题意：
a[i]表示从第i个车站可以一张票到第[i+1,a[i]]这些车站;
p[i][j]表示从第i个车站到第j个车站的最少的票数,现在要求∑dp[i][j](1<=i<=n,i<j<=n);

思路：从I开始走，在i+1到a[i]之间一定会到使a[j]最大的j，因为要使步数最小，接下来能走得更快
     区间询问最值用RMQ与线段树都可以
     dp[i]表示dp[i,i+1],dp[i,i+2]...dp[i,n]这些值的和
        dp[i]=dp[k]+(n-i)-(a[i]-k),k为[i+1,a[i]]中使a[k]最大的k
        n-i：有dp[i,i+1],dp[i,i+2]...dp[i,n]一共n-i个状态要从i走到k
        -(a[i]-k)：dp[i,k+1]到 dp[i,a[i]]长度与之前相比没有变化

type ok=record
         s:int64;
         a:longint;
        end;

const oo=1000000000000000;

var dp:array[0..100000]of int64;
    a:array[1..100000]of longint;
    tree:array[1..400000]of ok;
    n,i,k:longint;
    ans:int64;

procedure pushup(p:longint);
begin
 if tree[p<<1].s>tree[p].s then tree[p]:=tree[p<<1];
 if tree[p<<1+1].s>tree[p].s then tree[p]:=tree[p<<1+1];
end;

procedure build(l,r,p:longint);
var mid:longint;
begin
 tree[p].s:=a[l];
 tree[p].a:=l;
 if l=r then exit;
 mid:=(l+r)>>1;
 build(l,mid,p<<1);
 build(mid+1,r,p<<1+1);
 pushup(p);
end;

function query(l,r,x,y,p:longint):ok;
var mid:longint;
    t:int64;
    q,tmp:ok;

begin
 if (l=x)and(r=y) then exit(tree[p]);
 mid:=(l+r)>>1;
 t:=0;
 if (x>=l)and(y<=mid) then
 begin
  q:=query(l,mid,x,y,p<<1);
  if q.s>t then begin t:=q.s; tmp:=q; end;
 end else
 if (x>mid)and(y<=r) then
 begin
  q:=query(mid+1,r,x,y,p<<1+1);
  if q.s>t then begin t:=q.s; tmp:=q; end;
 end else
 begin
  q:=query(l,mid,x,mid,p<<1);
  if q.s>t then begin t:=q.s; tmp:=q; end;
  q:=query(mid+1,r,mid+1,y,p<<1+1);
  if q.s>t then begin t:=q.s; tmp:=q; end;
 end;
 exit(tmp);
end;

begin
 //assign(input,'1.in'); reset(input);
 //assign(output,'1.out'); rewrite(output);
 readln(n);
 for i:=1 to n-1 do read(a[i]);
 a[n]:=n;
 build(1,n,1);

 for i:=n-1 downto 1 do
 begin
  k:=query(1,n,i+1,a[i],1).a;
  dp[i]:=dp[k]+(n-i)-(a[i]-k);
 end;
 for i:=1 to n do ans:=ans+dp[i];
 writeln(ans);
 //close(input);
 //close(output);
end.