1. 返回值的区别,函数有1个返回值,而存储过程是通过参数返回的,可以有多个或者没有
2.调用的区别,函数可以在查询语句中直接调用,而存储过程必须单独调用.
函数一般情况下是用来计算并返回一个计算结果而存储过程一般是用来完成特定的数据操作（比如修改、插入数据库表或执行某些DDL语句等等）
游标(CURSOR)是ORACLE系统在内存中开辟的一个工作区,在其中存放SELECT语句返回的查询结果.
这个查询结果既可以是零记录,单条记录,也可以是多条记录.在游标所定义的工作区中,存在着一个指针(POINTER),
在初始状态它指向查询结果的首记录.
SQL是用于访问ORACLE数据库的语言，PL/SQL扩展和加强了SQL的功能，它同时引入了更强的程序逻辑。
PL/SQL支持DML命令和SQL的事务控制语句。DDL在PL/SQL中不被支持，这就意味作在PL/SQL程序块中不能创建表或其他任何对象。
较好的PL/SQL程序设计是在PL/SQL块中使用象DBMS_SQL这样的内建包或执行EXECUTE IMMEDIATE命令建立动态SQL来执行DDL命令，
PL/SQL编译器保证对象引用以及用户的权限。
下面我们将讨论各种用于访问ORACLE数据库的DML和TCL语句。
查询
SELECT语句用于从数据库中查询数据，当在PL/SQL中使用SELECT语句时，要与INTO子句一起使用，查询的返回值被赋予INTO子句中的变量，变量的声明是在DELCARE中。SELECT INTO语法如下：
SELECT [DISTICT|ALL]{*|column[,column,...]}
INTO (variable[,variable,...] |record)
FROM {table|(sub-query)}[alias]
WHERE............
PL/SQL中SELECT语句只返回一行数据。如果超过一行数据，那么就要使用显式游标（对游标的讨论我们将在后面进行），
INTO子句中要有与SELECT子句中相同列数量的变量。INTO子句中也可以是记录变量。
%TYPE属性
在PL/SQL中可以将变量和常量声明为内建或用户定义的数据类型，以引用一个列名，同时继承他的数据类型和大小。
这种动态赋值方法是非常有用的，比如变量引用的列的数据类型和大小改变了，如果使用了%TYPE,那么用户就不必修改代码，
否则就必须修改代码。
例：
v_empno SCOTT.EMP.EMPNO%TYPE;
v_salary EMP.SALARY%TYPE;
不但列名可以使用%TYPE,而且变量、游标、记录，或声明的常量都可以使用%TYPE。这对于定义相同数据类型的变量非常有用。
DECLARE
V_A NUMBER(5) := 10;
V_B V_A%TYPE := 15;
V_C V_A%TYPE;
BEGIN
DBMS_OUTPUT.PUT_LINE('V_A=' || V_A || 'V_B=' || V_B || 'V_C=' || V_C);
END;
SQL>/
V_A=10 V_B=15 V_C=
PL/SQL procedure successfully completed.
SQL>
其他DML语句
其它操作数据的DML语句是:INSERT、UPDATE、DELETE和LOCK TABLE,这些语句在PL/SQL中的语法与在SQL中的语法相同。
我们在前面已经讨论过DML语句的使用这里就不再重复了。在DML语句中可以使用任何在DECLARE部分声明的变量，如果是嵌套块，
那么要注意变量的作用范围。
例：
CREATE OR REPLACE PROCEDURE FIRE_EMPLOYEE(p_empno in number) AS
begin
declare
v_ename scott.EMP.ENAME%TYPE;
BEGIN
SELECT ename INTO v_ename FROM emp WHERE empno = p_empno;
INSERT INTO FORMER_EMP (EMPNO, ENAME) VALUES (p_empno, v_ename);
DELETE FROM emp WHERE empno = p_empno;
UPDATE former_emp SET HIREDATE = SYSDATE WHERE empno = p_empno;
EXCEPTION
WHEN NO_DATA_FOUND THEN
DBMS_OUTPUT.PUT_LINE('Employee Number Not Found!');
END;
end FIRE_EMPLOYEE;
DML语句的结果
当执行一条DML语句后，DML语句的结果保存在四个游标属性中，这些属性用于控制程序流程或者了解程序的状态。
当运行DML语句时，PL/SQL打开一个内建游标并处理结果，游标是维护查询结果的内存中的一个区域，游标在运行DML语句时打开，完成后关闭。
隐式游标只使用SQL%FOUND,SQL%NOTFOUND,SQL%ROWCOUNT三个属性.SQL%FOUND,SQL%NOTFOUND是布尔值，SQL%ROWCOUNT是整数值。
SQL%FOUND和SQL%NOTFOUND
在执行任何DML语句前SQL%FOUND和SQL%NOTFOUND的值都是NULL,在执行DML语句后，SQL%FOUND的属性值将是：
. TRUE :INSERT
. TRUE :DELETE和UPDATE，至少有一行被DELETE或UPDATE.
. TRUE :SELECT INTO至少返回一行
当SQL%FOUND为TRUE时,SQL%NOTFOUND为FALSE。
SQL%ROWCOUNT
在执行任何DML语句之前，SQL%ROWCOUNT的值都是NULL,对于SELECT INTO语句，如果执行成功，SQL%ROWCOUNT的值为1,如果没有成功，
SQL%ROWCOUNT的值为0，同时产生一个异常NO_DATA_FOUND.
SQL%ISOPEN
df
事务控制语句
事务是一个工作的逻辑单元可以包括一个或多个DML语句，事物控制帮助用户保证数据的一致性。
如果事务控制逻辑单元中的任何一个DML语句失败，那么整个事务都将回滚，
在PL/SQL中用户可以明确地使用COMMIT、ROLLBACK、SAVEPOINT以及SET TRANSACTION语句。
COMMIT语句终止事务，永久保存数据库的变化，同时释放所有LOCK,ROLLBACK终止现行事务释放所有LOCK，
但不保存数据库的任何变化,SAVEPOINT用于设置中间点，当事务调用过多的数据库操作时，中间点是非常有用的，
SET TRANSACTION用于设置事务属性，比如read-write和隔离级等。
显式游标
当查询返回结果超过一行时，就需要一个显式游标，此时用户不能使用select into语句。PL/SQL管理隐式游标，
当查询开始时隐式游标打开，查询结束时隐式游标自动关闭。显式游标在PL/SQL块的声明部分声明，
在执行部分或异常处理部分打开，取数据,关闭。下表显示了显式游标和隐式游标的差别：
使用游标
这里要做一个声明，我们所说的游标通常是指显式游标，因此从现在起没有特别指明的情况，我们所说的游标都是指显式游标。
要在程序中使用游标，必须首先声明游标。
声明游标
语法：
CURSOR cursor_name IS select_statement;
在PL/SQL中游标名是一个未声明变量，不能给游标名赋值或用于表达式中。
例：
DELCARE
CURSOR C_EMP IS SELECT empno,ename,salary
FROM emp
WHERE salary>2000
ORDER BY ename;
........
BEGIN
在游标定义中SELECT语句中不一定非要表可以是视图，也可以从多个表或视图中选择的列，甚至可以使用*来选择所有的列 。
打开游标
使用游标中的值之前应该首先打开游标，打开游标初始化查询处理。打开游标的语法是：
OPEN cursor_name
cursor_name是在声明部分定义的游标名。
例：
OPEN C_EMP;
关闭游标
语法：
CLOSE cursor_name
例：
CLOSE C_EMP;
从游标提取数据
从游标得到一行数据使用FETCH命令。每一次提取数据后，游标都指向结果集的下一行。语法如下：
FETCH cursor_name INTO variable[,variable,...]
对于SELECT定义的游标的每一列，FETCH变量列表都应该有一个变量与之相对应，变量的类型也要相同。
例：
DECLARE
v_ename EMP.ENAME%TYPE;
v_salary EMP.SAL%TYPE;
CURSOR c_emp IS
SELECT ename, SAL FROM emp;
BEGIN
OPEN c_emp;
FETCH c_emp
INTO v_ename, v_salary;
DBMS_OUTPUT.PUT_LINE('Salary of Employee' || v_ename || 'is' ||
v_salary);
FETCH c_emp
INTO v_ename, v_salary;
DBMS_OUTPUT.PUT_LINE('Salary of Employee' || v_ename || 'is' ||
v_salary);
FETCH c_emp
INTO v_ename, v_salary;
DBMS_OUTPUT.PUT_LINE('Salary of Employee' || v_ename || 'is' ||
v_salary);
CLOSE c_emp;
END;
这段代码无疑是非常麻烦的，如果有多行返回结果，可以使用循环并用游标属性为结束循环的条件，以这种方式提取数据，
程序的可读性和简洁性都大为提高，下面我们使用循环重新写上面的程序：
DECLARE
v_ename EMP.ENAME%TYPE;
v_salary EMP.SAL%TYPE;
CURSOR c_emp IS
SELECT ename, SAL FROM emp;
BEGIN
OPEN c_emp;
LOOP
FETCH c_emp
INTO v_ename, v_salary;
EXIT WHEN c_emp%NOTFOUND;
DBMS_OUTPUT.PUT_LINE('Salary of Employee' || v_ename || 'is' ||
v_salary);
END LOOP;
END;
记录变量
定义一个记录变量使用TYPE命令和%ROWTYPE，关于%ROWsTYPE的更多信息请参阅相关资料。
记录变量用于从游标中提取数据行，当游标选择很多列的时候，那么使用记录比为每列声明一个变量要方便得多。
当在表上使用%ROWTYPE并将从游标中取出的值放入记录中时，如果要选择表中所有列，
那么在SELECT子句中使用*比将所有列名列出来要安全得多。
例：
DECLARE
R_emp EMP%ROWTYPE;
CURSOR c_emp IS
SELECT * FROM emp;
BEGIN
OPEN c_emp;
LOOP
FETCH c_emp
INTO r_emp;
EXIT WHEN c_emp%NOTFOUND;
DBMS_OUTPUT.PUT_LINE('Salary of Employee' || r_emp.ename || 'is' ||
r_emp.sal);
END LOOP;
CLOSE c_emp;
END;
%ROWTYPE也可以用游标名来定义，这样的话就必须要首先声明游标：
DECLARE
CURSOR c_emp IS
SELECT ename, sal FROM emp;
R_emp c_emp%ROWTYPE;
BEGIN
OPEN c_emp;
LOOP
FETCH c_emp
INTO r_emp;
EXIT WHEN c_emp%NOTFOUND;
DBMS_OUTPUT.PUT_LINE('Sal of Employee' || r_emp.ename || 'is' ||
r_emp.sal);
END LOOP;
CLOSE c_emp;
END;
带参数的游标
与存储过程和函数相似，可以将参数传递给游标并在查询中使用。这对于处理在某种条件下打开游标的情况非常有用。它的语法如下：
CURSOR cursor_name[(parameter[,parameter],...)] IS select_statement;
定义参数的语法如下：
Parameter_name [IN] data_type[{:=|DEFAULT} value]
与存储过程不同的是，游标只能接受传递的值，而不能返回值。参数只定义数据类型，没有大小。
另外可以给参数设定一个缺省值，当没有参数值传递给游标时，就使用缺省值。游标中定义的参数只是一个占位符，
在别处引用该参数不一定可靠。
在打开游标时给参数赋值，语法如下：
OPEN cursor_name[value[,value]....];
参数值可以是文字或变量。
例：
DECLARE
CURSOR c_dept IS
SELECT * FROM dept ORDER BY deptno;
CURSOR c_emp(p_dept emp.deptno%type) IS
SELECT ename, sal FROM emp WHERE deptno = p_dept ORDER BY ename;
r_dept DEPT%ROWTYPE;
v_ename EMP.ENAME%TYPE;
v_salary EMP.SAL%TYPE;
v_tot_salary EMP.SAL%TYPE;
BEGIN
OPEN c_dept;
LOOP
FETCH c_dept
INTO r_dept;
EXIT WHEN c_dept%NOTFOUND;
DBMS_OUTPUT.PUT_LINE('Department:' || r_dept.deptno || '-' ||
r_dept.dname);
v_tot_salary := 0;
OPEN c_emp(r_dept.deptno);
LOOP
FETCH c_emp
INTO v_ename, v_salary;
EXIT WHEN c_emp%NOTFOUND;
DBMS_OUTPUT.PUT_LINE('Name:' || v_ename || ' sal:' || v_salary);
v_tot_salary := v_tot_salary + v_salary;
END LOOP;
CLOSE c_emp;
DBMS_OUTPUT.PUT_LINE('Toltal Sal for dept:' || v_tot_salary);
END LOOP;
CLOSE c_dept;
END;
游标FOR循环
在大多数时候我们在设计程序的时候都遵循下面的步骤：
1、打开游标
2、开始循环
3、从游标中取值
4、检查那一行被返回
5、处理
6、关闭循环
7、关闭游标
可以简单的把这一类代码称为游标用于循环。但还有一种循环与这种类型不相同，这就是FOR循环，
用于FOR循环的游标按照正常的声明方式声明，它的优点在于不需要显式的打开、关闭、取数据，测试数据的存在、定义存放数据的变量等等
。游标FOR 循环的语法如下：
FOR record_name IN
(corsor_name[(parameter[,parameter]...)]
| (query_difinition)
LOOP
statements
END LOOP;
下面我们用for循环重写上面的例子：
DECLARE
CURSOR c_dept IS
SELECT deptno, dname FROM dept ORDER BY deptno;
CURSOR c_emp(p_dept emp.deptno%type) IS
SELECT ename, sal FROM emp WHERE deptno = p_dept ORDER BY ename;
v_tot_salary EMP.SAL%TYPE;
BEGIN
FOR r_dept IN c_dept LOOP
DBMS_OUTPUT.PUT_LINE('Department:' || r_dept.deptno || '-' ||
r_dept.dname);
v_tot_salary := 0;
FOR r_emp IN c_emp(r_dept.deptno) LOOP
DBMS_OUTPUT.PUT_LINE('Name:' || r_emp.ename || ' sal:' ||
r_emp.sal);
v_tot_salary := v_tot_salary + r_emp.sal;
END LOOP;
DBMS_OUTPUT.PUT_LINE('Toltal Sal for dept:' || v_tot_salary);
END LOOP;
END;
在游标FOR循环中使用查询
在游标FOR循环中可以定义查询，由于没有显式声明所以游标没有名字，记录名通过游标查询来定义。
DECLARE
v_tot_salary EMP.SAL%TYPE;
BEGIN
FOR r_dept IN (SELECT deptno, dname FROM dept ORDER BY deptno) LOOP
DBMS_OUTPUT.PUT_LINE('Department:' || r_dept.deptno || '-' ||
r_dept.dname);
v_tot_salary := 0;
FOR r_emp IN (SELECT ename, sal
FROM emp
WHERE deptno = r_dept.deptno
ORDER BY ename) LOOP
DBMS_OUTPUT.PUT_LINE('Name:' || r_emp.ename || ' salary:' ||
r_emp.sal);
v_tot_salary := v_tot_salary + r_emp.sal;
END LOOP;
DBMS_OUTPUT.PUT_LINE('Toltal Salary for dept:' || v_tot_salary);
END LOOP;
END;
游标中的子查询
语法如下：
CURSOR C1 IS SELECT * FROM emp
WHERE deptno NOT IN (SELECT deptno
FROM dept
WHERE dname!='ACCOUNTING');
可以看出与SQL中的子查询没有什么区别。
游标中的更新和删除**************************************************************************POINT
在PL/SQL中依然可以使用UPDATE和DELETE语句更新或删除数据行。显式游标只有在需要获得多行数据的情况下使用。
PL/SQL提供了仅仅使用游标就可以执行删除或更新记录的方法。
UPDATE或DELETE语句中的WHERE CURRENT OF子串专门处理要执行UPDATE或DELETE操作的表中取出的最近的数据。
要使用这个方法，在声明游标时必须使用FOR UPDATE子串，当对话使用FOR UPDATE子串打开一个游标时，
所有返回集中的数据行都将处于行级（ROW-LEVEL)独占式锁定，其他对象只能查询这些数据行，
不能进行UPDATE、DELETE或SELECT...FOR UPDATE操作。
语法：
FOR UPDATE [OF [schema.]table.column[,[schema.]table.column]..
[nowait]
在多表查询中，使用OF子句来锁定特定的表,如果忽略了OF子句，那么所有表中选择的数据行都将被锁定。
如果这些数据行已经被其他会话锁定，那么正常情况下ORACLE将等待，直到数据行解锁。
在UPDATE和DELETE中使用WHERE CURRENT OF子串的语法如下：
WHERE{CURRENT OF cursor_name|search_condition}
例：
DECLARE
CURSOR c1 IS
SELECT empno, sal FROM test_emp WHERE comm IS NULL FOR UPDATE OF comm;
v_comm NUMBER(10, 2);
BEGIN
FOR r1 IN c1 LOOP
IF r1.sal < 500 THEN
v_comm := r1.sal * 0.25;
ELSIF r1.sal < 1000 THEN
v_comm := r1.sal * 0.20;
ELSIF r1.sal < 3000 THEN
v_comm := r1.sal * 0.15;
ELSE
v_comm := r1.sal * 0.12;
END IF;
UPDATE test_emp SET comm = v_comm WHERE CURRENT OF c1;
END LOOP;
END;