NOI2014 动物园

3670: [Noi2014]动物园

Time Limit: 10 Sec  Memory Limit: 512 MB
Submit: 174  Solved: 92
[Submit][Status]

Description

近日，园长发现动物园中好吃懒做的动物越来越多了。例如企鹅，只会卖萌向游客要吃的。为了整治动物园的不良风气，让动物们凭自己的真才实学向游客要吃的，园长决定开设算法班，让动物们学习算法。

某天，园长给动物们讲解KMP算法。

园长：“对于一个字符串S，它的长度为L。我们可以在O(L)的时间内，求出一个名为next的数组。有谁预习了next数组的含义吗？”

熊猫：“对于字符串S的前i个字符构成的子串，既是它的后缀又是它的前缀的字符串中（它本身除外），最长的长度记作next[i]。”

园长：“非常好！那你能举个例子吗？”

熊猫：“例S为abcababc，则next[5]=2。因为S的前5个字符为abcab，ab既是它的后缀又是它的前缀，并且找不到一个更长的字符串满足这个性质。同理，还可得出next[1] = next[2] = next[3] = 0，next[4] = next[6] = 1，next[7] = 2，next[8] = 3。”

园长表扬了认真预习的熊猫同学。随后，他详细讲解了如何在O(L)的时间内求出next数组。

下课前，园长提出了一个问题：“KMP算法只能求出next数组。我现在希望求出一个更强大num数组一一对于字符串S的前i个字符构成的子串，既是它的后缀同时又是它的前缀，并且该后缀与该前缀不重叠，将这种字符串的数量记作num[i]。例如S为aaaaa，则num[4] = 2。这是因为S的前4个字符为aaaa，其中a和aa都满足性质‘既是后缀又是前缀’，同时保证这个后缀与这个前缀不重叠。而aaa虽然满足性质‘既是后缀又是前缀’，但遗憾的是这个后缀与这个前缀重叠了，所以不能计算在内。同理，num[1] = 0,num[2] = num[3] = 1,num[5] = 2。”

最后，园长给出了奖励条件，第一个做对的同学奖励巧克力一盒。听了这句话，睡了一节课的企鹅立刻就醒过来了！但企鹅并不会做这道题，于是向参观动物园的你寻求帮助。你能否帮助企鹅写一个程序求出num数组呢？

特别地，为了避免大量的输出，你不需要输出num[i]分别是多少，你只需要输出对1,000,000,007取模的结果即可。

Input

第1行仅包含一个正整数n ，表示测试数据的组数。随后n行，每行描述一组测试数据。每组测试数据仅含有一个字符串S，S的定义详见题目描述。数据保证S 中仅含小写字母。输入文件中不会包含多余的空行，行末不会存在多余的空格。

Output

包含 n 行，每行描述一组测试数据的答案，答案的顺序应与输入数据的顺序保持一致。对于每组测试数据，仅需要输出一个整数，表示这组测试数据的答案对 1,000,000,007 取模的结果。输出文件中不应包含多余的空行。

Sample Input

3
aaaaa
ab
abcababc

Sample Output

36
1
32

HINT

n≤5,L≤1,000,000

Source

题解：

下了考场发现这题好像做过？不过当时肯定是暴力的。。。

在考场上我首先想的是30分的朴素，用KMP做匹配，用前半段去匹配后半段，匹配完成，匹配点NUM++

后来我又想到这题肯定与KMP有关，一定是利用NEXT数组的什么神奇的性质神奇的做到了O（n）

后来我发现NEXT的值一样的num一定一样，如果不考虑不重叠的话，这样下来就是如何把num压缩到只有不重叠的情况

我先想到了暴力，直接while。。。next。。。，我又sb的想如果数据的随机的话这样while 不了多少次。。。结果数据发下来尼玛真是卡我的啊QAQ。。。

后来（还是在考场上）我又想到在郑州培训的时候zxr讲的如果一个东西是递减的，最后减到了0或1，然后这个算法就是O(n)的了。。。（说不清。。。），类似与KMP算法中的 j 

于是我想到一个next值的计算能否用到以前计算过的某些信息呢，

我想到了它的后继结点，这样每次都让它的num先等于它的后继结点的num，然后while似乎就是O（n），但由于不确定，我还是交了暴力。。。

但在考场上我没有想到，i 与 next[i]形成父子关系，这样整张图就是一棵树，只要dfs就可以算出，从一个点到根节点上有多少个点，也就是算上重合的num

接下来在树上while，于是我才用了下面的算法：

1.对于叶节点，暴力while

2.对于非叶节点，先让num等于它的后继中num最小的，这样它的num不可能超过这个值，再while

这样下来非叶节点的计算应该会很快

但是如果叶节点很多，而非叶节点很少的话很可能就TLE了，不过数据中好象没有卡这个算法的。。。

代码：

1.考场50分

const p=1000000007;
var  i,j,n,m,l,t:longint;
     num,next,c,d,fa:array[0..1000000] of int64;
     ans:int64;
     s,a,b:ansistring;
procedure kmp;
 var i,j:longint;
 begin
 n:=length(a);
 fillchar(next,sizeof(next),0);
 next[1]:=0;j:=0;
 for i:=2 to n do
  begin
  while (j<>0) and (a[j+1]<>a[i]) do j:=next[j];
  if a[j+1]=a[i] then inc(j);
  next[i]:=j;
  end;
 end;
procedure init;
 begin
 readln(s);
 l:=length(s);
 fillchar(num,sizeof(num),0);
 end;
function check:boolean;
 var i:longint;
 begin
 for i:=2 to l do if s[i]<>s[1] then exit(false);
 exit(true);
 end;
procedure spj;
 begin
 ans:=1;
 for i:=2 to l do ans:=ans*(i>>1+1) mod p;
 writeln(ans);
 end;
procedure main;
 begin
 a:=s;kmp;c[1]:=1;
 for i:=2 to l>>1 do
  begin
  c[i]:=1;inc(c[i],c[next[i]]);
  end;
 for i:=1 to l do d[i]:=next[i];
 for i:=l downto 2 do
  begin
  j:=next[i];
  while d[i]>i>>1 do
   begin
   j:=next[j];
   d[i]:=j;
   end;
  end;
 for i:=1 to l do num[i]:=c[d[i]];
 ans:=1;
 for i:=1 to l do ans:=ans*(num[i]+1) mod p;
 writeln(ans);
 end;
begin
 assign(input,'zoo.in');assign(output,'zoo.out');
 reset(input);rewrite(output);
 readln(t);
 while t>0 do
  begin
  dec(t);
  init;
  if check then spj else main;
  end;
 close(input);close(output);
end. 

2.dfs100分（竟然1A了。。。）

{$M 1000000000,0,maxlongint}
const maxn=1000000+100;p=1000000007;
type node=record
    go,next:longint;
    end;
var i,j,n,tot,t:longint;
    ans:int64;
    num,next,point,head,s:array[0..maxn] of int64;
    e:array[0..maxn] of node;
    a:ansistring;
    function min(x,y:longint):longint;
     begin
       if x<y then exit(x) else exit(y);
     end;

procedure insert(x,y:longint);
 begin
   inc(tot);
   e[tot].go:=y;e[tot].next:=head[x];head[x]:=tot;
 end;
procedure init;
 begin
   fillchar(next,sizeof(next),0);
   fillchar(head,sizeof(head),0);
   tot:=0;
   readln(a);
   next[1]:=0;
   n:=length(a);
   j:=0;
   for i:=2 to n do
    begin
    while (j<>0) and (a[j+1]<>a[i]) do j:=next[j];
    if a[j+1]=a[i] then inc(j);
    next[i]:=j;
    end;
 end;
procedure dfs(x:longint);
 var i,y:longint;
   begin
     i:=head[x];
     while i<>0 do
       begin
       y:=e[i].go;
       s[y]:=s[x]+1;
       dfs(y);
       i:=e[i].next;
       end;
   end;
procedure solve(x:longint);
 var i,j,y:longint;
   begin
     if head[x]=0 then
       begin
         j:=next[x];
         while j>x>>1 do j:=next[j];
         num[x]:=s[j];point[x]:=j;
         exit;
       end;
     j:=maxlongint;
     i:=head[x];
     while i<>0 do
       begin
         y:=e[i].go;
         solve(y);
         j:=min(j,point[y]);
         i:=e[i].next;
       end;
     while j>x>>1 do j:=next[j];
     num[x]:=s[j];point[x]:=j;
   end;

procedure main;
 begin
   for i:=1 to n do insert(next[i],i);
   dfs(0);
   solve(0);
   ans:=1;
   for i:=1 to n do ans:=(ans*(num[i]+1)) mod p;
   writeln(ans);
 end;
begin
  assign(input,'zoo.in');assign(output,'zoo.out');
  reset(input);rewrite(output);
  readln(t);
  while t>0 do
   begin
   dec(t);
   init;
   main;
   end;
  close(input);close(output);
end.