asp操作txt文件

创建、添加或删除数据，以及读取文件 
移动、复制和删除文件 
创建文件 
创建空文本文件（有时被叫做“文本流”）有三种方法。 

第一种方法是用 CreateTextFile 方法。下面的示例示范了如何用 CreateTextFile 方法创建文本文件： 

[VBScript] 
Dim fso, f1 
Set fso = CreateObject("Scripting.FileSystemObject") 
Set f1 = fso.CreateTextFile("c:\testfile.txt", True) 
[JScript] 
var fso, f1; 
fso = new ActiveXObject("Scripting.FileSystemObject"); 
f1 = fso.CreateTextFile("c:\\testfile.txt", true); 
创建文本文件的第二种方法是，使用 FileSystemObject 对象的 OpenTextFile 方法，并设置 ForWriting 标志。 

[VBScript] 
Dim fso, ts 
Const ForWriting = 2 
Set fso = CreateObject("Scripting. FileSystemObject") 
Set ts = fso.OpenTextFile("c:\test.txt", ForWriting, True) 
[JScript] 
var fso, ts; 
var ForWriting= 2; 
fso = new ActiveXObject("Scripting.FileSystemObject"); 
ts = fso.OpenTextFile("c:\\test.txt", ForWriting, true); 
创建文本文件的第三种方法是，使用 OpenAsTextStream 方法，并设置 ForWriting 标志。要使用这种方法，使用下面的代码： 

[VBScript] 
Dim fso, f1, ts 
Const ForWriting = 2 
Set fso = CreateObject("Scripting.FileSystemObject") 
fso.CreateTextFile ("c:\test1.txt") 
Set f1 = fso.GetFile("c:\test1.txt") 
Set ts = f1.OpenAsTextStream(ForWriting, True) 
[JScript] 
var fso, f1, ts; 
var ForWriting = 2; 
fso = new ActiveXObject("Scripting.FileSystemObject"); 
fso.CreateTextFile ("c:\\test1.txt"); 
f1 = fso.GetFile("c:\\test1.txt"); 
ts = f1.OpenAsTextStream(ForWriting, true); 


添加数据到文件中 
一旦创建了文本文件，使用下面的三个步骤向文件添加数据： 

打开文本文件。 

写入数据。 

关闭文件。 

要打开现有的文件，则使用 FileSystemObject 对象的 OpenTextFile 方法或 File 对象的 OpenAsTextStream 方法。 

要写数据到打开的文本文件，则根据下表所述任务使用 TextStream 对象的 Write、WriteLine 或 WriteBlankLines 方法。 

任务 方法 
向打开的文本文件写数据，不用后续一个新行字符。 Write 
向打开的文本文件写数据，后续一个新行字符。 WriteLine 
向打开的文本文件写一个或多个空白行。 WriteBlankLines 

要关闭一个打开的文件，则使用 TextStream 对象的 Close 方法。 

注意 新行字符包含一个或几个字符（取决于操作系统），以把光标移动到下一行的开始位置（回车/换行）。注意某些字符串末尾可能已经有这个非打印字符了。 
下面的例子示范了如何打开文件，和同时使用三种写方法来向文件添加数据，然后关闭文件： 

[VBScript] 
Sub CreateFile() 
Dim fso, tf 
Set fso = CreateObject("Scripting.FileSystemObject") 
Set tf = fso.CreateTextFile("c:\testfile.txt", True) 
' 写一行，并带有一个新行字符。 
tf.WriteLine("Testing 1, 2, 3.") 
' 向文件写三个新行字符。 
tf.WriteBlankLines(3) 
' 写一行。 
tf.Write ("This is a test.") 
tf.Close 
End Sub 
[JScript] 
function CreateFile() 
{ 
var fso, tf; 
fso = new ActiveXObject("Scripting.FileSystemObject"); 
tf = fso.CreateTextFile("c:\\testfile.txt", true); 
// 写一行，并带有一个新行字符。 
tf.WriteLine("Testing 1, 2, 3.")  
// 向文件写三个新行字符。 
tf.WriteBlankLines(3)  
// 写一行。 
tf.Write ("This is a test."); 
tf.Close(); 
} 
读取文件 
要从文本文件读取数据，则使用 TextStream 对象的 Read、ReadLine 或 ReadAll 方法。下表描述了不同的任务应使用哪种方法。 

任务 方法 
从文件读取指定数量的字符。 Read 
读取一整行（一直到但不包括新行字符）。 ReadLine 
读取文本文件的整个内容。 ReadAll 

如果使用 Read 或 ReadLine 方法，并且想跳过数据的特殊部分，则使用 Skip 或 SkipLine 方法。read 方法的结果文本存在一个字符串中，该字符串可以显示在一个控件中，也可以用字符串函数（如 Left、Right 和 Mid）来分析，连接等等。 

下面的例子示范了如何打开文件，和如何写数据到文件中并从文件读取数据： 

[VBScript] 
Sub ReadFiles 
Dim fso, f1, ts, s 
Const ForReading = 1 
Set fso = CreateObject("Scripting.FileSystemObject") 
Set f1 = fso.CreateTextFile("c:\testfile.txt", True) 
' 写入一行。 
Response.Write "Writing file <br>" 
f1.WriteLine "Hello World" 
f1.WriteBlankLines(1) 
f1.Close 
' 读取文件内容。 
Response.Write "Reading file <br>" 
Set ts = fso.OpenTextFile("c:\testfile.txt", ForReading) 
s = ts.ReadLine 
Response.Write "File contents = '" & s & "'" 
ts.Close 
End Sub 
[JScript] 
function ReadFiles() 
{ 
var fso, f1, ts, s; 
var ForReading = 1; 
fso = new ActiveXObject("Scripting.FileSystemObject"); 
f1 = fso.CreateTextFile("c:\\testfile.txt", true); 
// 写入一行。 
Response.Write("Writing file <br>"); 
f1.WriteLine("Hello World"); 
f1.WriteBlankLines(1); 
f1.Close(); 
// 读取文件内容。 
Response.Write("Reading file <br>"); 
ts = fso.OpenTextFile("c:\\testfile.txt", ForReading); 
s = ts.ReadLine(); 
Response.Write("File contents = '" + s + "'"); 
ts.Close(); 
} 
移动、复制和删除文件 
FSO 对象模型各有两种方法移动、复制和删除文件，如下表所述。 

任务 方法 
移动文件 File.Move 或 FileSystemObject.MoveFile 
复制文件 File.Copy 或 FileSystemObject.CopyFile 
删除文件 File.Delete 或 FileSystemObject.DeleteFile 

下面示例在驱动器 C 的根目录中创建一个文本文件，向其中写一些信息，然后把它移动到 \tmp 目录中，并在 \temp 中做一个备份，最后把它们从两个目录中删掉。 

要运行下面的示例，需要先在驱动器 C 的根目录中创建 \tmp 和 \temp 目录： 

[VBScript] 
Sub ManipFiles 
Dim fso, f1, f2, s 
Set fso = CreateObject("Scripting.FileSystemObject") 
Set f1 = fso.CreateTextFile("c:\testfile.txt", True) 
Response.Write "Writing file <br>" 
' 写入一行。 
f1.Write ("This is a test.") 
' 关闭写入到的文件。 
f1.Close 
Response.Write "Moving file to c:\tmp <br>" 
' 获取到 C:\ 根目录中文件的句柄。 
Set f2 = fso.GetFile("c:\testfile.txt") 
' 将文件移到 \tmp 目录。 
f2.Move ("c:\tmp\testfile.txt") 
Response.Write "Copying file to c:\temp <br>" 
' 将文件复制到 \temp。 
f2.Copy ("c:\temp\testfile.txt") 
Response.Write "Deleting files <br>" 
' 获得文件当前位置的句柄。 
Set f2 = fso.GetFile("c:\tmp\testfile.txt") 
Set f3 = fso.GetFile("c:\temp\testfile.txt") 
' 删除文件。 
f2.Delete 
f3.Delete 
Response.Write "All done!" 
End Sub 
[JScript] 
function ManipFiles() 
{ 
var fso, f1, f2, s; 
fso = new ActiveXObject("Scripting.FileSystemObject"); 
f1 = fso.CreateTextFile("c:\\testfile.txt", true); 
Response.Write("Writing file <br>"); 
// 写入一行。 
f1.Write("This is a test."); 
// 关闭写入到的文件。 
f1.Close(); 
Response.Write("Moving file to c:\\tmp <br>"); 
// 获取到 C:\ 根目录中文件的句柄。 
f2 = fso.GetFile("c:\\testfile.txt"); 
// 将文件移到 \tmp 目录。 
f2.Move ("c:\\tmp\\testfile.txt"); 
Response.Write("Copying file to c:\\temp <br>"); 
// 将文件复制到 \temp。 
f2.Copy ("c:\\temp\\testfile.txt"); 
Response.Write("Deleting files <br>"); 
// 获得文件当前位置的句柄。 
f2 = fso.GetFile("c:\\tmp\\testfile.txt"); 
f3 = fso.GetFile("c:\\temp\\testfile.txt"); 
// 删除文件。 
f2.Delete(); 
f3.Delete(); 
Response.Write("All done!"); 
}