poj3233

这道题其实算是把快速幂的思想用在多项式之中

A+A^2+A^3+…+A^n=(A+A^1…+A^[n/2])+A^[n/2](A+A+A^1…+A^[n/2])+n mod 2*A^n

然后就是打码的问题了

var ans,a,b,c,f:array[0..30,0..30] of longint;
    d:array[0..30] of longint;
    i,j,n,m,p:longint;

procedure mul;
  var i,j,k:longint;
  begin
    for i:=1 to n do
      for j:=1 to n do
      begin
        c[i,j]:=0;
        for k:=1 to n do
          c[i,j]:=(c[i,j]+a[i,k]*b[k,j] mod p) mod p;
      end;
  end;

procedure add;
  var i,j:longint;
  begin
    for i:=1 to n do
      for j:=1 to n do
        ans[i,j]:=(ans[i,j]+c[i,j]) mod p;
  end;

procedure quick(x:longint);
  var i,j:longint;
  begin
    j:=0;
    while x<>0 do
    begin
      inc(j);
      d[j]:=x mod 2;
      x:=x shr 1;
    end;
    fillchar(c,sizeof(c),0);
    for i:=1 to n do
      c[i,i]:=1;
    for i:=j downto 1 do
    begin
      a:=c;
      b:=c;
      mul;
      if d[i]=1 then
      begin
        a:=c;
        b:=f;
        mul;
      end;
    end;
  end;

procedure work(x:longint);
  begin
    if x=1 then ans:=f
    else begin
      work(x shr 1);
      quick(x shr 1);
      a:=c;
      b:=ans;
      mul;
      add;
      if x mod 2=1 then
      begin
        quick(x);
        add;
      end;
    end;
  end;

begin
  readln(n,m,p);
  for i:=1 to n do
    for j:=1 to n do
      read(f[i,j]);
  work(m);
  for i:=1 to n do
  begin
    for j:=1 to n do
    begin
      write(ans[i,j]);
      if j<>n then write(' ');
    end;
    writeln;
  end;
end.