【POJ1741】Tree（点分治）

题意：

思路：点分治论文题

我们知道一条路径要么过根结点，要么在一棵子树中，这启发了我们可以使用分治算法。

记 Depth(i)表示点i 到根结点的路径长度， Belong(i) = X ( X 为根结点的某个儿子，且结点i 在以 X 为根的子树内)。

那么我们要统计的就是：

满足 Depth (i) + Depth ( j)<= K 且 Belong(i) <>Belong(j) 的 (i, j) 个数

= 满足 Depth(i) +Depth( j) <= K 的 (i, j) 个数

– 满足 Depth(i) + Depth( j) <= K 且 Belong(i) =Belong( j)的 (i, j) 个数

而对于这两个部分，都是要求出满足 Ai+Aj <= k 的(i, j) 的对数。

将 A 排序后利用单调性我们很容易得出一个O(N) 的算法，所以我们

可以用O(N log N)的时间来解决这个问题。

综上，此题使用树的分治算法时间复杂度为O(N log^2 N) 。 

var head,vet,next,len,son,flag,d:array[1..50000]of longint;
    dep,f:array[0..50000]of longint;
    n,m,i,x,y,z,tot,ans,sum,root,k:longint;

procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

procedure add(a,b,c:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 len[tot]:=c;
 head[a]:=tot;
end;

function max(x,y:longint):longint;
begin
 if x>y then exit(x);
 exit(y);
end;

procedure getroot(u,fa:longint);
var e,v:longint;
begin
 son[u]:=1; f[u]:=0;
 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  if (v<>fa)and(flag[v]=0) then
  begin
   getroot(v,u);
   son[u]:=son[u]+son[v];
   f[u]:=max(f[u],son[v]);
  end;
  e:=next[e];
 end;
 f[u]:=max(f[u],sum-f[u]);
 if f[u]<f[root] then root:=u;
end;

procedure getdeep(u,fa:longint);
var e,v:longint;
begin
 inc(dep[0]); dep[dep[0]]:=d[u];
 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  if (v<>fa)and(flag[v]=0) then
  begin
   d[v]:=d[u]+len[e];
   getdeep(v,u);
  end;
  e:=next[e];
 end;
end;

procedure qsort(l,r:longint);
var i,j,mid:longint;
begin
 i:=l; j:=r; mid:=dep[(l+r)>>1];
 repeat
  while mid>dep[i] do inc(i);
  while mid<dep[j] do dec(j);
  if i<=j then
  begin
   swap(dep[i],dep[j]);
   inc(i); dec(j);
  end;
 until i>j;
 if l<j then qsort(l,j);
 if i<r then qsort(i,r);
end;

function clac(u,now:longint):longint;
var l,r:longint;
begin
 d[u]:=now; dep[0]:=0;
 getdeep(u,0);
 qsort(1,dep[0]);
 clac:=0;
 l:=1; r:=dep[0];
 while l<r do
 begin
  if dep[l]+dep[r]<=k then begin clac:=clac+r-l; inc(l); end
   else dec(r);
 end;
end;

procedure work(u:longint);
var e,v:longint;
begin
 ans:=ans+clac(u,0);
 flag[u]:=1;
 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  if flag[v]=0 then
  begin
   ans:=ans-clac(v,len[e]);
   sum:=son[v];
   root:=0;
   getroot(v,root);
   work(root);
  end;
  e:=next[e];
 end;
end;

begin
 assign(input,'poj1741.in'); reset(input);
 assign(output,'poj1741.out'); rewrite(output);
 while not eof do
 begin
  fillchar(head,sizeof(head),0);
  fillchar(flag,sizeof(flag),0);
  tot:=0;
  readln(n,k);
  if (n=0)and(m=0) then break;
  for i:=1 to n-1 do
  begin
   readln(x,y,z);
   add(x,y,z);
   add(y,x,z);
  end;
  sum:=n; f[0]:=maxlongint; ans:=0;
  getroot(1,0);
  work(root);
  writeln(ans);
 end;
 close(input);
 close(output);
end.