Flash3D学习计划（三）——学习VB，IB相关，理解三角形顶点顺序；在屏幕上显示2D矩形，并实现缩放，平移，旋转

VB：顶点缓冲

IB: 顶点索引缓冲

三角形的顶点顺序决定了三角形是顺时针还是逆时针，从而决定了三角形在背面剔除的过程中是否会被剔除掉。

相关理论知识可以在前面的文章中找到更多的说明。

实现效果

sfw下载

主要代码

package
{
    import com.adobe.utils.AGALMiniAssembler;
    import com.adobe.utils.PerspectiveMatrix3D;
    
    import flash.display.Sprite;
    import flash.display.Stage3D;
    import flash.display3D.Context3D;
    import flash.display3D.Context3DProgramType;
    import flash.display3D.Context3DVertexBufferFormat;
    import flash.display3D.IndexBuffer3D;
    import flash.display3D.Program3D;
    import flash.display3D.VertexBuffer3D;
    import flash.events.Event;
    import flash.geom.Matrix3D;
    import flash.geom.Vector3D;
    
    /**
     * @author smartqi
     * @E-mail: 
     * 创建时间：2013-6-29 上午9:36:36
     * 
     */
    public class RectangleTest extends Sprite
    {
        
        private var context:Context3D;
        private var vertexBuff:VertexBuffer3D;
        private var indexBuff:IndexBuffer3D;
        private var vertexData:Vector.<Number>;
        private var indexData:Vector.<uint>;
        private var shaderProgram:Program3D;
        private var perspectiveMatrix:PerspectiveMatrix3D;
        private var i:int;
        private var sign:int = 1;
        private const angleGap:Number = 20;
        private var angle:Number = 0;
        private var modelMatrix:Matrix3D;
        private var viewMatrix:Matrix3D;
        private var finalMatrix:Matrix3D;
        
        
        public function RectangleTest()
        {
            var stage3d:Stage3D = stage.stage3Ds[0];
            stage3d.addEventListener(Event.CONTEXT3D_CREATE,onContextCreate);
            stage3d.requestContext3D();
        }
        
        private function onContextCreate(e:Event):void{
            context = (e.target as Stage3D).context3D;
            if(context == null) return;
            context.enableErrorChecking = true; //允许进行错误检测，release版本应设置
            context.configureBackBuffer(500,500,0); //设置显示区域的大小
            setupVertexBuff(); //设置顶点缓冲
            setupShaderProgram(); //设置shander
            setupPerspectiveMatrix(); //设置投影矩阵
            initMatrix();
            addEventListener(Event.ENTER_FRAME,onEnterFrame);
        }
        
        private function setupVertexBuff():void{
            vertexData = Vector.<Number>([
                // x    y     z     r     g     b
                40,        40,        -40,    1,    0,    0,
                40,        -40,    -40,    0,    1,    0,
                -40,    -40,    -40,    0,    0,    1,
                -40,    40,        -40,    1,    1,    1,
            ]);
            
            indexData = Vector.<uint>([0,1,2,0,2,3]);
            vertexBuff = context.createVertexBuffer(4,vertexData.length/4);
            vertexBuff.uploadFromVector(vertexData,0,4);
            indexBuff = context.createIndexBuffer(6);
            indexBuff.uploadFromVector(indexData,0,6);
            context.setVertexBufferAt(0,vertexBuff,0,Context3DVertexBufferFormat.FLOAT_3);
            context.setVertexBufferAt(1,vertexBuff,3,Context3DVertexBufferFormat.FLOAT_3);
        }
        
        private function setupShaderProgram():void{
            var vertexProgram:AGALMiniAssembler =  new AGALMiniAssembler();
            vertexProgram.assemble(Context3DProgramType.VERTEX,
                "m44 op,va0,vc0
" +
                "mov v1,va1
");
            var fragmentProgram:AGALMiniAssembler = new AGALMiniAssembler();
            fragmentProgram.assemble(Context3DProgramType.FRAGMENT,
                "mov oc,v1");
            shaderProgram = context.createProgram();
            shaderProgram.upload(vertexProgram.agalcode,fragmentProgram.agalcode);
            context.setProgram(shaderProgram);
        }
        
        private function setupPerspectiveMatrix():void{
            perspectiveMatrix = new PerspectiveMatrix3D();
            perspectiveMatrix.perspectiveFieldOfViewRH(Math.PI*90/180,1,1,1000);  //注意这里的角度使用的是弧度
        }
        
        private function initMatrix():void{
            modelMatrix = new Matrix3D();
            viewMatrix = new Matrix3D();
            finalMatrix = new Matrix3D();
        }
        
        private function onEnterFrame(e:Event):void{
            context.clear(0,0,0);
            angle += angleGap;
            modelMatrix.identity();
            modelMatrix.prependRotation(angle,Vector3D.Z_AXIS);  //绕着Z轴旋转物体，注意这里的角度使用的是角度
            if(i>30){
                sign = -1;
            }
            if(i<0){
                sign = 1;
            }
            i += sign;
            viewMatrix.identity();
            viewMatrix.prependTranslation(0,0,-30 + i); //将相机向后移，使物体看起来变小了,将相机向前移，使物体看起来变大
            finalMatrix.identity();
            finalMatrix.append(modelMatrix);
            finalMatrix.append(viewMatrix);
            finalMatrix.append(perspectiveMatrix);
            context.setProgramConstantsFromMatrix(Context3DProgramType.VERTEX,0,finalMatrix,true); //上传最终的顶点转换矩阵，注意这里最后一个参数为true
            context.drawTriangles(indexBuff,0,2);
            context.present();
        }
    }
}