昂贵的聘礼 最短路 dijkstra

题意/Description：

        年轻的探险家来到了一个印第安部落里。在那里他和酋长的女儿相爱了，于是便向酋长去求亲。酋长要他用10000个金币作为聘礼才答应把女儿嫁给他。探险家拿不出这么多金币，便请求酋长降低要求。酋长说：“嗯，如果你能够替我弄到大祭司的皮袄，我可以只要8000金币。如果你能够弄来他的水晶球，那么只要5000金币就行了。”探险家就跑到大祭司那里，向他要求皮袄或水晶球，大祭司要他用金币来换，或者替他弄来其他的东西，他可以降低价格。探险家于是又跑到其他地方，其他人也提出了类似的要求，或者直接用金币换，或者找到其他东西就可以降低价格。不过探险家没必要用多样东西去换一样东西，因为不会得到更低的价格。探险家现在很需要你的帮忙，让他用最少的金币娶到自己的心上人。另外他要告诉你的是，在这个部落里，等级观念十分森严。地位差距超过一定限制的两个人之间不会进行任何形式的直接接触，包括交易。他是一个外来人，所以可以不受这些限制。但是如果他和某个地位较低的人进行了交易，地位较高的的人不会再和他交易，他们认为这样等于是间接接触，反过来也一样。因此你需要在考虑所有的情况以后给他提供一个最好的方案。 
　　为了方便起见，我们把所有的物品从1开始进行编号，酋长的允诺也看作一个物品，并且编号总是1。每个物品都有对应的价格P，主人的地位等级L，以及一系列的替代品Ti和该替代品所对应的“优惠”Vi。如果两人地位等级差距超过了M，就不能“间接交易”。你必须根据这些数据来计算出探险家最少需要多少金币才能娶到酋长的女儿。 

读入/Input：

       输入包括了多个测试数据。每个测试数据的第一行是两个整数M，N（1<=N<=100），依次表示地位等级差距限制和物品的总数。接下来按照编号从小到大依次给出了N个物品的描述。每个物品的描述开头是三个非负整数P、L、X（X＜N），依次表示该物品的价格、主人的地位等级和替代品总数。接下来X行每行包括两个整数T和V，分别表示替代品的编号和“优惠价格”。 

输出/Output：

       对于每个测试数据，在单独一行内输出最少需要的金币数。 

题解/solution：

       题目乍一看好像十分难，因为多了一个等级，还有等级差距。举个例子：

       A1=3   A2=3   A3=2   A4=1   A5=1    等级差距是1

       A1可以和A2、A3做交易，如果A2和A4做交易，A1不能和A2做交易，因为A1和A4的等级差距为2，超出范围。

       这个题目还要自己建路，不过这相信大家都会。不过根据上面的例子，建路也是一个难题，怎么建才能得到最小金币数呢？本人是十分暴力的，枚举不就OK了，每枚举一次更新一次最短路就行了，在注意一下枚举的等级差距，本题就被解决了。

代码/Code：

 

var
  n,m:longint;
  a:array [0..111,0..111] of longint;
  dj,jg:array [0..111] of longint;
  dis:array [0..111] of int64;
  b,f:array [0..111] of boolean;
function dijkstra:longint;
var
  i,j,k,min:longint;
begin
  fillchar(b,sizeof(b),0);
  for i:=1 to n do
    dis[i]:=a[1,i];
  dis[1]:=0; b[1]:=true;;
  for i:=1 to n do
    begin
      min:=maxlongint;
      for j:=1 to n do
        begin
          if (not b[j]) and (f[j]) and (dis[j]<min) then
            begin
              k:=j;
              min:=dis[j];
            end;
        end;
      if min=maxlongint then break;
      b[k]:=true;
      dis[k]:=min;
      for j:=1 to n do
        if (not b[j]) and (f[j]) and (dis[k]+a[k,j]<dis[j]) then
          dis[j]:=dis[k]+a[k,j];
    end;
  min:=maxlongint;
  for i:=1 to n do
    if (dis[i]+jg[i]<min) and (b[i]) then
      min:=dis[i]+jg[i];
  dijkstra:=min;
end;

procedure main;
var
  t,k,i,j,dijmin,min,mint:longint;
begin
  readln(m,n);
  for i:=1 to n do
    for j:=1 to n do
      if i=j then a[i,j]:=0 else a[i,j]:=maxlongint;
  for i:=1 to n do
    begin
      readln(jg[i],dj[i],t);
      for j:=0 to t-1 do
        begin
          read(k); readln(a[i,k]);
        end;
    end;

  dijmin:=dj[1]; min:=maxlongint;
  for i:=0 to m do
    begin
      fillchar(f,sizeof(f),0);
      for j:=1 to n do
        if (dijmin-dj[j]<=m-i) and (dj[j]-dijmin<=i) then
          f[j]:=true;
      mint:=dijkstra;
      if mint<min then
        min:=mint;
    end;
  write(min);
end;

begin
  main;
end.