异步复位和同步复位

异步复位实例：

module async_rst (
    input       din,
    input       clk,
    input       rst_n,
    
    output reg  dout
);

    always @ (posedge clk or negedge rst_n)
    begin
        if (!rst_n)
            dout <= 1'b0;
        else
            dout <= din;
    end

endmodule

同步复位实例：

module sync_rst (
    input       din,
    input       clk,
    input       rst_n,
    
    output reg  dout
);

    always @ (posedge clk)
    begin
        if (!rst_n)
            dout <= 1'b0;
        else
            dout <= din;
    end

endmodule

异步复位与同步复位比较：

    同步复位更耗资源，异步复位存在亚稳态。

异步复位产生亚稳态实例：

module async_rst_metastability (
    input       din,
    input       clk,
    input       rst_n,
    
    output reg  dout1,
    output reg  dout2
);

    always @ (posedge clk or negedge rst_n)
    begin
        if (!rst_n)
            dout2 <= 1'b0;
        else
            dout2 <= dout1;
    end
    
    always @ (posedge clk or negedge rst_n)
    begin
        if (!rst_n)
            dout1 <= 1'b0;
        else
            dout1 <= din;
    end

endmodule

    正常情况下，clk上升沿到来时 dout1 将更新为 din ，dout2 将更新为 dout1 。一旦复位，dout1、dout2 都为 0 ，但是并不确定复位信号什么时候结束。如果 rst_n 的撤销时间（低电平变为高电平）出现在 clk 锁存数据的建立时间或者保持时间内，此时 clk 检测到 rst_n 的状态就会是一个亚稳态（不确定是 0 还是 1）。

    由于此时 rst_n 的不确定性，可能出现四种情况，即 dout1~reg0 和 dout2~reg0 都复位或者都跳出复位，再或者一个复位一个跳出复位，那么后者就会造成系统工作不同步的问题。这个简单二级异步复位这种危害不明显，但是在大工程里隐患将非常大。

异步复位、同步释放实例：

module async_rst_sync_rel (
    input       clk,
    input       rst_n,
    
    output reg  dout
);
    reg         dout_reg;

    always @ (posedge clk or negedge rst_n)
    begin
        if (!rst_n)
            dout_reg <= 1'b0;
        else
            dout_reg <= 1'b1;
    end
    
    always @ (posedge clk or negedge rst_n)
    begin
        if (!rst_n)
            dout <= 1'b0;
        else
            dout <= dout_reg;
    end

endmodule

或者这么写：

module async_rst_sync_rel (
    input       clk,
    input       rst_n,
    
    output reg  dout );
    
    reg         dout_reg;
    
    always @ (posedge clk or negedge rst_n)
    begin
        if (!rst_n) begin
            dout_reg  <= 1'b0;
            dout      <= 1'b0;
        end
        else begin
            dout_reg  <= 1'b1;
            dout      <= dout_reg;
        end
    end

endmodule

把 dout 作为复位信号。