按键消抖实验

当按键被按下在到被释放，期间产生的输入信号会发生抖动，如果不进行消抖处理，直接使用可能就会误触发。

按键消抖实验设计思路，当按键被按下，隔20ms取数据，也就是说20ms的前后各取一次数据进行边沿检测：

（1）、需要一个计数器cnt，因为按键随时都可能会被按下，所以计数器需一直启动在计数，需一直在检测。

always @(posedge clk or negedge rst_n)begin
    if(!rst_n)begin
        cnt <= 0;
    end
    else if(add_cnt)begin
        if(end_cnt)begin
            cnt <= 0;
        end
        else begin
            cnt <= cnt + 1;
        end
    end
end

assign add_cnt = 1;
assign end_cnt = add_cnt && cnt == T_20MS -1 || key_en;

（2）、需要一个边沿检测器，需要对输入pin 上的信号进行边沿检测，检测到下降沿之后，立刻马上将计数器cnt 清0 ，cnt从0开始计数，数到20ms 取一次数据

always @(posedge clk or negedge rst_n)begin
    if(!rst_n)begin
        key_rst <= 1;
        key_rst_r <= 1;
    end
    else begin
        key_rst <= wr_en;
        key_rst_r <= key_rst;
    end
end
//当key_en = 1时，说明有检测到下降沿，但这个并不能当做一个真正有效的信号去启动cnt0,
//在按键按下到释放期间可能会多次产生key_en = 1
assign key_en = key_rst_r & (~key_rst); 

//每隔20ms就取按键上的值    
always @(posedge clk or negedge rst_n)begin
    if(!rst_n) begin
        pin_status <= 1;
    end
    else if(end_cnt) begin //隔20ms 取一次数据
        pin_status <= wr_en;
    end
end

always @(posedge clk or negedge rst_n)begin
    if(!rst_n)begin 
        pin_status_r <= 1;
    end
    else begin
        pin_status_r <= pin_status;
    end
end

//前20MS的值与后20MS的值
assign pin_status_ctrl = pin_status_r & (~pin_status);//这个信号才比较稳定信号，可以当做启动计数器cnt0

完整代码：该代码是基于spi flash 一个读ID操作

module spi_flash(
                    clk,
                    rst_n,
                    wr_en,
                    spi_miso,
                    
                    spi_sclk,
                    spi_mosi,
                    spi_cs,
                    rec_buf
);
parameter         SCLK_CLK = 3'd04;
parameter         T_20MS      = 20'd1_000_000;
parameter        CMD_ID     = 8'h9f;

input            clk        ;
input            rst_n    ;
input            wr_en    ;
input            spi_miso;

output            spi_sclk;
output            spi_mosi;
output            spi_cs    ;
output[24-1:0]    rec_buf    ;

wire             add_cnt0;
wire            end_cnt0;
wire             add_cnt1;
wire            end_cnt1;
wire             add_cnt/*synthesis keep=1*/;
wire            end_cnt/*synthesis keep=1*/;
wire             key_en/*synthesis keep=1*/;

wire            key_h_2_l;
wire              pin_status_ctrl/*synthesis keep=1*/;

reg[3-1:0]        cnt0;
reg[6-1:0]        cnt1;
reg[20-1:0]     cnt/*synthesis preserve=1*/;
reg             wr_vld;
reg             key_rst;
reg             key_rst_r;
reg             pin_status;
reg             pin_status_r;


/************************************************/
//按键消抖动
always @(posedge clk or negedge rst_n)begin
    if(!rst_n)begin
        key_rst <= 1;
        key_rst_r <= 1;
    end
    else begin
        key_rst <= wr_en;
        key_rst_r <= key_rst;
    end
end

assign key_en = key_rst_r & (~key_rst);

//每隔20ms就取按键上的值    
always @(posedge clk or negedge rst_n)begin
    if(!rst_n) begin
        pin_status <= 1;
    end
    else if(end_cnt) begin
        pin_status <= wr_en;
    end
end

always @(posedge clk or negedge rst_n)begin
    if(!rst_n)begin 
        pin_status_r <= 1;
    end
    else begin
        pin_status_r <= pin_status;
    end
end

//前20MS的值与后20MS的值
assign pin_status_ctrl = pin_status_r & (~pin_status);

always @(posedge clk or negedge rst_n)begin
    if(!rst_n)begin
        cnt <= 0;
    end
    else if(add_cnt)begin
        if(end_cnt)begin
            cnt <= 0;
        end
        else begin
            cnt <= cnt + 1;
        end
    end
end

assign add_cnt = 1;
assign end_cnt = add_cnt && cnt == T_20MS -1 || key_en;


always @(posedge clk or negedge rst_n)begin
    if(!rst_n)begin
        wr_vld <= 0;
    end
    else if(pin_status_ctrl)begin
        wr_vld <= 1;
    end
    else if(end_cnt1)begin
        wr_vld <= 0;
    end
end

always @(posedge clk or negedge rst_n)begin
    if(!rst_n)begin
        cnt0 <= 0;
    end
    else if(add_cnt0)begin
        if(end_cnt0)begin
            cnt0 <= 0;
        end
        else begin
            cnt0 <= cnt0 + 1;
        end
    end
end

assign add_cnt0 = wr_vld;
assign end_cnt0 = add_cnt0 && cnt0 == SCLK_CLK -1;

always @(posedge clk or negedge rst_n)begin
    if(!rst_n)begin
        cnt1 <= 0;
    end
    else if(add_cnt1)begin
        if(end_cnt1)begin
            cnt1 <= 0;
        end
        else begin
            cnt1 <= cnt1 + 1;
        end
    end
end

assign add_cnt1 = end_cnt0;
assign end_cnt1 = add_cnt1 && cnt1 == 33 -1;

reg spi_sclk;
always @(posedge clk or negedge rst_n)begin
    if(!rst_n)begin
        spi_sclk <= 1;
    end
    else if(end_cnt0 && cnt1 != 32)begin
        spi_sclk <= 0;
    end
    else if(add_cnt0 && cnt0 == ((SCLK_CLK>>1) -1))begin
        spi_sclk <= 1;
    end
end

reg spi_cs;
always @(posedge clk or negedge rst_n)begin
    if(!rst_n)begin
        spi_cs <= 1;
    end
    else if(add_cnt0 && cnt0 == ((SCLK_CLK>>1) -1) && cnt1 == 0)begin
        spi_cs <= 0;
    end
    else if(end_cnt1)begin
        spi_cs <= 1;
    end
end

reg spi_mosi;
always @(posedge clk or negedge rst_n)begin
    if(!rst_n)begin
        spi_mosi <= 1;
    end
    else if(end_cnt0 && cnt1 >= 0 && cnt1 < 8)begin
        spi_mosi <= CMD_ID[7-cnt1];
    end
end

reg[24-1:0] rec_buf_temp;
always @(posedge clk or negedge rst_n)begin
    if(!rst_n)begin
        rec_buf_temp <= 0;
    end
    else if(add_cnt0 && cnt0 == ((SCLK_CLK>>1)-1) && cnt1 >= 9 && cnt1 < 33)begin
        rec_buf_temp[32-cnt1] <= spi_miso;
    end
end

reg dout_vld;
always @(posedge clk or negedge rst_n)begin
    if(!rst_n)begin
        dout_vld <= 0;
    end
    else begin
        dout_vld <= end_cnt1;
    end
end

reg[24-1:0] rec_buf;
always @(posedge clk or negedge rst_n)begin
    if(!rst_n)begin
        rec_buf <= 0;
    end
    else if(end_cnt1)begin
        rec_buf <= rec_buf_temp;
    end
end

endmodule 

用quartus II 的SignalTab抓取的波形：

如果pin_status_ctl 检测到多次，可以将间隔时间适当的加长点。一般的轻触按键20~50ms。

触发条件可以多开几个窗口进行捕获观察 。