树链剖分入门

声明

---

 　　　  树链剖分前置知识：链式前向星、线段树。

　　　　模板题：洛谷 P3384 

---

　　　　这里就转载别人的博客吧（内含C++标程）~

　

　　　　　　

type
        tree=record
                data,delta,l,r:longint;
        end;
var
        t:array[0..300001] of tree;
        size,fa,deep,son,top,dfn,a,rank,en,first,next:array[0..200001] of longint;
        cnt,tot,n,m,i,r,p,x,y,z,k:longint;
procedure add(x,y:longint);
begin
        inc(cnt);
        next[cnt]:=first[x];
        first[x]:=cnt;
        en[cnt]:=y;
end;
procedure down(tot:longint);
begin
        t[tot*2].data:=(t[tot*2].data+t[tot].delta*(t[tot*2].r-t[tot*2].l+1) mod p) mod p;
        t[tot*2+1].data:=(t[tot*2+1].data+t[tot].delta*(t[tot*2+1].r-t[tot*2+1].l+1) mod p) mod p;
        t[tot*2].delta:=(t[tot*2].delta+t[tot].delta) mod p;
        t[tot*2+1].delta:=(t[tot*2+1].delta+t[tot].delta) mod p;
        t[tot].delta:=0;
end;
procedure dfs1(x,f:longint);
var
        t,e:longint;
begin
        fa[x]:=f;
        deep[x]:=deep[f]+1;
        size[x]:=1;
        t:=first[x];
        while t<>0 do
        begin
                e:=en[t];
                if e<>f then
                begin
                        dfs1(e,x);
                        inc(size[x],size[e]);
                        if (son[x]=0) or (size[e]>size[son[x]]) then son[x]:=e;
                end;
                t:=next[t];
        end;
end;
procedure dfs2(x,f:longint);
var
        t,e:longint;
begin
        inc(tot);
        dfn[x]:=tot;
        top[x]:=f;
        rank[tot]:=x;
        if son[x]=0 then exit;
        dfs2(son[x],f);
        t:=first[x];
        while t<>0 do
        begin
                e:=en[t];
                if (e<>son[x]) and (e<>fa[x]) then dfs2(e,e);
                t:=next[t];
        end;
end;
procedure build(tot,l,r:longint);
var
        mid:longint;
begin
        if l=r then
        begin
                t[tot].data:=a[rank[l]] mod p;
                t[tot].l:=l;
                t[tot].r:=r;
                exit;
        end;
        t[tot].l:=l;
        t[tot].r:=r;
        mid:=(t[tot].l+t[tot].r) div 2;
        build(tot*2,l,mid);
        build(tot*2+1,mid+1,r);
        t[tot].data:=(t[tot*2].data+t[tot*2+1].data) mod p;
end;
procedure changesubtree(l,r,c,tot:longint);
var
        mid:longint;
begin
        if (l<=t[tot].l) and (t[tot].r<=r) then
        begin
                t[tot].data:=(t[tot].data+c*(t[tot].r-t[tot].l+1) mod p) mod p;
                t[tot].delta:=(t[tot].delta+c) mod p;
                exit;
        end;
        mid:=(t[tot].l+t[tot].r) div 2;
        if t[tot].delta<>0 then down(tot);
        if l<=mid then changesubtree(l,r,c,tot*2);
        if r>mid then changesubtree(l,r,c,tot*2+1);
        t[tot].data:=(t[tot*2].data+t[tot*2+1].data) mod p;
end;
function querysubtree(l,r,tot:longint):longint;
var
        mid:longint;
begin
        if (l<=t[tot].l) and (t[tot].r<=r) then exit(t[tot].data);
        mid:=(t[tot].l+t[tot].r) div 2;
        if t[tot].delta<>0 then down(tot);
        querysubtree:=0;
        if l<=mid then querysubtree:=(querysubtree+querysubtree(l,r,tot*2)) mod p;
        if r>mid then querysubtree:=(querysubtree+querysubtree(l,r,tot*2+1)) mod p;
end;
procedure changeedge(x,y,c:longint);
begin
        while top[x]<>top[y] do
                if deep[top[x]]>=deep[top[y]] then
                begin
                        changesubtree(dfn[top[x]],dfn[x],c,1);
                        x:=fa[top[x]];
                end else
                begin
                        changesubtree(dfn[top[y]],dfn[y],c,1);
                        y:=fa[top[y]];
                end;
        if dfn[x]<=dfn[y] then changesubtree(dfn[x],dfn[y],c,1)
                else changesubtree(dfn[y],dfn[x],c,1);
end;
function queryedge(x,y:longint):longint;
begin
        queryedge:=0;
        while top[x]<>top[y] do
                if deep[top[x]]>=deep[top[y]] then
                begin
                        queryedge:=(queryedge+querysubtree(dfn[top[x]],dfn[x],1)) mod p;
                        x:=fa[top[x]];
                end else
                begin
                        queryedge:=(queryedge+querysubtree(dfn[top[y]],dfn[y],1)) mod p;
                        y:=fa[top[y]];
                end;
        if dfn[x]<=dfn[y] then queryedge:=(queryedge+querysubtree(dfn[x],dfn[y],1)) mod p
                else queryedge:=(queryedge+querysubtree(dfn[y],dfn[x],1)) mod p;
end;
begin
        readln(n,m,r,p);
        for i:=1 to n do
                read(a[i]);
        readln;
        for i:=1 to n-1 do
        begin
                readln(x,y);
                add(x,y);
                add(y,x);
        end;
        dfs1(r,0);
        dfs2(r,r);
        build(1,1,n);
        for i:=1 to m do
        begin
                read(k);
                if k=1 then
                begin
                        readln(x,y,z);
                        changeedge(x,y,z);
                end else if k=2 then
                begin
                        readln(x,y);
                        writeln(queryedge(x,y));
                end else if k=3 then
                begin
                        readln(x,z);
                        changesubtree(dfn[x],dfn[x]+size[x]-1,z,1);
                end else
                begin
                        readln(x);
                        writeln(querysubtree(dfn[x],dfn[x]+size[x]-1,1));
                end;
        end;
end.