BZOJ1089 [SCOI2003]严格n元树

又是一道奇怪的DP（?）题
一个非常好的想法是：
令f[i]表示深度小于等于i的n元树的总个数，于是
f[i] = f[i - 1] ^ n + 1 (这是因为加了一层以后新的根的n个儿子可以随便选，再加上没有儿子的情况)
但是还要写高精。。。还好一边A了，手感不错~

/**************************************************************
    Problem: 1089
    User: rausen
    Language: Pascal
    Result: Accepted
    Time:32 ms
    Memory:1204 kb
****************************************************************/
 
const
  m : longint = 10000;
 
type
  arr = array[0..10000] of longint;
 
var
  f : array[0..20] of arr;
  ans : arr;
  i, n, d : longint;
 
operator + (const a : arr; const b : longint) c : arr;
var
  l : longint;
 
begin
  fillchar(c, sizeof(c), 0);
  for l := 1 to a[0] do
    c[l] := a[l];
  c[1] := c[1] + b;
  l := 1;
  while c[l] >= m do begin
    c[l + 1] := c[l + 1] + c[l] div m;
    c[l] := c[l] mod m;
    inc(l);
  end;
  l := a[0] + 1;
  while c[l] = 0 do dec(l);
  c[0] := l;
end;
 
operator * (const a : arr; const b : arr) c : arr;
var
  i, j, x, l : longint;
 
begin
  fillchar(c, sizeof(c), 0);
  for i := 1 to a[0] do
    for j := 1 to b[0] do begin
      x := i + j - 1;
      c[x] := c[x] + a[i] * b[j];
      c[x + 1] := c[x + 1] + c[x] div m;
      c[x] := c[x] mod m;
    end;
  l := 0;
  while l <= a[0] + b[0] + 1 do begin
    c[l + 1] := c[l + 1] + c[l] div m;
    c[l] := c[l] mod m;
    inc(l);
  end;
  l := a[0] + b[0] + 1;
  while c[l] = 0 do dec(l);
  c[0] := l;
end;
 
operator - (const a : arr; const b : arr) c :arr;
var
  l, del : longint;
 
begin
  fillchar(c, sizeof(c), 0);
  l := 1;
  del := 0;
  while l <= a[0] do begin
    c[l] := a[l] - b[l] - del;
    if c[l] < 0 then begin
      del := 1;
      c[l] := c[l] + m;
    end else del := 0;
    inc(l);
  end;
  l := a[0];
  while c[l] = 0 do
    dec(l);
  c[0] := l;
end;
 
procedure refresh(var a : arr);
begin
  fillchar(a, sizeof(a), 0);
end;
 
function pow(a : arr; x : longint) : arr;
var
  b : arr;
 
begin
  refresh(b);
  b := b + 1;
  while x > 0 do begin
    if x and 1 = 1 then b := b * a;
    a := a * a;
    x := x shr 1;
  end;
  exit(b);
end;
 
procedure print(a : arr);
var
  i : longint;
 
begin
  for i := a[0] downto 1 do begin
    if i <> a[0] then begin
      if a[i] < 1000 then write(0);
      if a[i] < 100 then write(0);
      if a[i] < 10 then write(0);
    end;
    write(a[i]);
  end;
end;
 
begin
  readln(n, d);
  refresh(f[0]);
  f[0] := f[0] + 1;
  for i := 1 to d do
    f[i] := pow(f[i - 1], n) + 1;
  if d = 0 then writeln(1) else begin
    ans := f[d] - f[d - 1];
    print(ans);
  end;
end.