bzoj3926

题目的意思是叶子不超过20个……听说当初zjoi不少人被坑

分别对每个叶子以它为根dfs出20个dfs树，这样整个树的任何一个子串，都是某个dfs树上一个点到它的一个子孙的路径

每个dfs树，根到叶子相当于一个串，这样相当于统计20*19个串的不同字串数目

这样我们很容易想到建立多串SAM（广义后缀树）统计不同的子串数即可

type node=record
       po,next:longint;
     end;

var go:array[0..4000010,0..10] of longint;
    fa,mx:array[0..4000010] of longint;
    c,d,p:array[0..100010] of longint;
    e:array[0..200010] of node;
    v:array[0..100010] of boolean;
    t,i,len,x,y,n,m:longint;
    ans:int64;

procedure add(x,y:longint);
  begin
    inc(len);
    e[len].po:=y;
    e[len].next:=p[x];
    p[x]:=len;
    inc(d[y]);
  end;

function work(c,last:longint):longint;
  var np,q,p,nq:longint;
  begin
    p:=last;
    if go[p,c]=0 then
    begin
      inc(t); work:=t; np:=t;
      mx[np]:=mx[p]+1;
      while (p>0) and (go[p,c]=0) do
      begin
        go[p,c]:=np;
        p:=fa[p];
      end;
      if p=0 then fa[np]:=1
      else begin
        q:=go[p,c];
        if mx[q]=mx[p]+1 then fa[np]:=q
        else begin
          inc(t); nq:=t;
          mx[nq]:=mx[p]+1;
          go[nq]:=go[q];
          fa[nq]:=fa[q];
          fa[q]:=nq; fa[np]:=nq;
          while go[p,c]=q do
          begin
            go[p,c]:=nq;
            p:=fa[p];
          end;
        end;
      end;
    end
    else begin
      q:=go[p,c];
      if mx[q]=mx[p]+1 then exit(q)
      else begin
        inc(t); nq:=t;
        mx[nq]:=mx[p]+1;
        go[nq]:=go[q];
        fa[nq]:=fa[q];
        fa[q]:=nq;
        while go[p,c]=q do
        begin
          go[p,c]:=nq;
          p:=fa[p];
        end;
      end;
      exit(go[last,c]);
    end;
  end;

procedure dfs(x,last:longint);
  var i,y:longint;
  begin
    last:=work(c[x],last);
    v[x]:=true;
    i:=p[x];
    while i<>0 do
    begin
      y:=e[i].po;
      if not v[y] then dfs(y,last);
      i:=e[i].next;
    end;
  end;

begin
  readln(n,m);
  for i:=1 to n do
    read(c[i]);
  for i:=1 to n-1 do
  begin
    readln(x,y);
    add(x,y);
    add(y,x);
  end;
  t:=1;
  for i:=1 to n do
    if d[i]=1 then
    begin
      fillchar(v,sizeof(v),false);
      dfs(i,1);
    end;
  for i:=2 to t do
    ans:=ans+mx[i]-mx[fa[i]];
  writeln(ans);
end.