bzoj4044

这题简直了…………

首先根据操作可知，我们肯定是先造出某个偶数长度的回文串，然后添加若干字符得到设回文串长为len[x]

则ans=min(n-len[x]+f[x]);

那么问题就是制造这个串的回文串，最少的操作次数

对于回文串x，我们有这种情况

f[x]=min(f[y]+1,(y是x去掉首尾）,f[y]+len[x]-len[y]（y是最长回文前缀，(其实这个可以不考虑，因为这就相当于直接制造y)

=(f[y]+len[x] div 2-len[y]+1，y是长度不超过x一半的最长回文后缀）

dp大家都会，但状态怎么表示呢？………………

显然一个串回文串不超过n，但是怎么表示之间的关系呢？

我曾yy了一种manacher+后缀自动机的做法，结果是又WA又T一时爽……

无奈学了一下回文树，感觉是非常简洁明快的

学习可以转到：http://pan.baidu.com/s/1hqzRlvm

感觉有点像ac自动机，还是比较好懂的，这样就简单了

但我pascal本地AC交上去不停RE不知为何……

var go:array[0..200010,1..4] of longint;
    len,fa,sub,a,q,f:array[0..200010] of longint;
    last,t,ans,i,tt,n:longint;
    s:ansistring;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

function what(ch:char):longint;
  begin
    if ch='A' then exit(1);
    if ch='T' then exit(2);
    if ch='C' then exit(3);
    if ch='G' then exit(4);
    exit(-1);
  end;

procedure getchar;
  var i:longint;
  begin
    readln(s);
    n:=length(s);
    a[n+1]:=-1;
    for i:=1 to n do
      a[i]:=what(s[i]);
  end;

function getf(x:longint):longint;
  begin
    while a[i-len[x]-1]<>a[i] do x:=fa[x];
    exit(x);
  end;

procedure newnode(l:longint);
  begin
    inc(t);
    fillchar(go[t],sizeof(go[t]),0);
    len[t]:=l;
    fa[t]:=0;
  end;

procedure add(c:longint);
  var now,cur,x:longint;
  begin
    cur:=getf(last);
    if go[cur,c]=0 then
    begin
      newnode(len[cur]+2); now:=t;
      fa[now]:=go[getf(fa[cur]),c];
      go[cur,c]:=now;
      if len[now]<=2 then f[now]:=len[now]
      else begin
        x:=sub[cur];
        while (a[i-len[x]-1]<>a[i]) or (2*(len[x]+2)>len[now]) or (len[x] mod 2=1) do x:=fa[x];
        sub[now]:=go[x,c];
      end;
    end;
    last:=go[cur,c];
  end;

procedure bfs;
  var h,r,x,y,i,w:longint;
  begin
    h:=1;
    r:=1;
    q[1]:=0;
    f[0]:=1;
    while h<=r do
    begin
      x:=q[h];
      for i:=1 to 4 do
      begin
        y:=go[x,i];
        if y<>0 then
        begin
          inc(r);
          q[r]:=y;
          if len[y]>2 then
          begin
            f[y]:=min(f[x]+1,len[y] div 2-len[sub[y]]+f[sub[y]]+1);
            ans:=min(ans,n-len[y]+f[y]);
          end;
        end;
      end;
      inc(h);
    end;
  end;

begin
  readln(tt);
  while tt>0 do
  begin
    dec(tt);
    getchar;
    t:=-1;
    newnode(0);
    newnode(-1);
    fa[0]:=1;
    last:=0;
    for i:=1 to n do
      add(a[i]);
    ans:=n;
    bfs;
    writeln(ans);
  end;
end.