bzoj1453

这是一道好题，按行建线段树，每个点维护上下边界的连通性，详细见代码注释

网上写法不一，自认为比较简单，就放出来相出来献丑吧

var u,d:array[0..810,0..205] of longint;  //u[]上边界,d[]下边界
    s,fa,q:array[0..810] of longint;
    c:array[0..810,0..1] of longint;  //维护对应颜色块数
    a:array[0..205,0..205] of longint;
    j,i,n,m,x,y:longint;

function getf(x:longint):longint;
  begin
    if fa[x]<>x then fa[x]:=getf(fa[x]);
    exit(fa[x]);
  end;

procedure union(i,m:longint);
  var j,k1,k2,t:longint;
  begin
    c[i,0]:=c[i*2,0]+c[i*2+1,0];
    c[i,1]:=c[i*2,1]+c[i*2+1,1];
    for j:=1 to n do
    begin
      fa[j]:=u[i*2,j];
      fa[j+n]:=d[i*2,j];
      fa[j+2*n]:=u[i*2+1,j]+2*n;  //防止编号重复
      fa[j+3*n]:=d[i*2+1,j]+2*n;
    end;
    for j:=1 to n do
      if a[m+1,j]=a[m,j] then  //子区间相邻连通块合并
      begin
        k1:=getf(fa[j+n]);
        k2:=getf(fa[j+2*n]);
        if k1<>k2 then
        begin
          fa[k2]:=k1;
          dec(c[i,a[m,j]]);
        end;
      end;
    t:=0;
    for j:=1 to n do
    begin
      k1:=getf(fa[j]); //对整个区间上边界连通性重新标号
      if s[k1]=0 then
      begin
        inc(t);
        q[t]:=k1;
        s[k1]:=j;  
      end;
      u[i,j]:=s[k1];
      k2:=getf(fa[j+3*n]); //对整个区间下边界连通性重新标号
      if s[k2]=0 then
      begin
        inc(t);
        q[t]:=k2;
        s[k2]:=j+n;  //防止编号重复,上边界编号1~n,下边界编号n+1~2n
      end;
      d[i,j]:=s[k2];
    end;
    for j:=1 to t do
      s[q[j]]:=0;
  end;

procedure leaf(i,row:longint);
  var j,t:longint;
  begin
    t:=0;
    c[i,0]:=0; c[i,1]:=0;
    for j:=1 to n do
      if (j<>1) and (a[row,j]=a[row,j-1]) then
      begin
        u[i,j]:=u[i,j-1];
        d[i,j]:=d[i,j-1];
      end
      else begin
        inc(c[i,a[row,j]]);
        u[i,j]:=j; d[i,j]:=j; //连通块以起始位置为编号,这样比较方便
      end;
  end;

procedure build(i,l,r:longint);
  var m:longint;
  begin
    if l=r then leaf(i,l)
    else begin
      m:=(l+r) shr 1;
      build(i*2,l,m);
      build(i*2+1,m+1,r);
      union(i,m);
    end;
  end;

procedure work(i,l,r:longint);
  var m:longint;
  begin
    if l=r then leaf(i,l)
    else begin
      m:=(l+r) shr 1;
      if x<=m then work(i*2,l,m)
      else work(i*2+1,m+1,r);
      union(i,m);
    end;
  end;

begin
  readln(n);
  for i:=1 to n do
    for j:=1 to n do
      read(a[i,j]);
  build(1,1,n);
  readln(m);
  for i:=1 to m do
  begin
    readln(x,y);
    a[x,y]:=1-a[x,y];
    work(1,1,n);
    writeln(c[1,1],' ',c[1,0]);
  end;
end.