poj3692

首先这道题很容易想到二分图相关（给的很明确了）；

但是我们发现，男孩之间都互相认识，女孩之间也互相认识

这样是不能划分点集的

但是男孩之间都互相认识，女孩之间也互相认识，所以男孩和男孩，女孩和女孩之间不存在不认识关系；

如果以不认识作为边的话，这样不就能划开点集吗？

于是我们换一个思维，要找最多的男女生互相认识，不就是找最多的男女生之间不存在不认识关系吗

所以，我们在不认识之间的男女之间连边，然后对这个二分图求最大独立集即可

最大独立集=点集x+点集y-最大匹配数（最小点覆盖）

要注意思维的转化

type node=record
       point,next:longint;
     end;
var edge:array[0..200010] of node;
    p,cx,cy:array[0..500] of longint;
    v:array[0..500] of boolean;
    a:array[0..500,0..500] of boolean;
    t,len,ans,g,b,m,i,j,x,y:longint;

procedure add(x,y:longint);
  begin
    inc(len);
    edge[len].point:=y;
    edge[len].next:=p[x];
    p[x]:=len;
  end;

function find(x:longint):longint;
  var y,i:longint;
  begin
    i:=p[x];
    while i<>-1 do
    begin
      y:=edge[i].point;
      if not v[y] then
      begin
        v[y]:=true;
        if (cy[y]=-1) or (find(cy[y])=1) then
        begin
          cx[x]:=y;
          cy[y]:=x;
          exit(1);
        end;
      end;
      i:=edge[i].next;
    end;
    exit(0);
  end;

begin
  readln(g,b,m);
  while (b<>0) do
  begin
    inc(t);
    fillchar(a,sizeof(a),false);
    len:=0;
    fillchar(p,sizeof(p),255);
    for i:=1 to m do
    begin
      readln(x,y);
      a[x,y]:=true;
    end;
    for i:=1 to g do
      for j:=1 to b do
        if not a[i,j] then add(i,j);
    fillchar(cx,sizeof(cx),255);
    fillchar(cy,sizeof(cy),255);
    ans:=0;
    for i:=1 to g do
      if cx[i]=-1 then
      begin
        fillchar(v,sizeof(v),false);
        ans:=ans+find(i);
      end;
    writeln('Case ',t,': ',b+g-ans);
    readln(g,b,m);
  end;
end.