bzoj1056

花了一上午大概复习了一下splay，treap

像这种裸的数据结构题在js应该会越来越少

不过练练手也好，

这就是平衡树+hash，如果这是单纯的BST应用，还是写treap吧，好调试

const rd=250008;
      ran=10000007;

type link=^node;
     node=record
       st:string[11];
       loc:longint;
       next:link;
     end;

var hash:array[0..rd] of link;
    son:array[0..300000,0..2] of longint;
    score,fa,count,key:array[0..300010] of longint;
    na:array[0..300010] of string[11];
    t,tot,root,x,y,i,n:longint;
    what,ch:char;
    s,ss:string;

procedure update(x:longint);
  begin
    count[x]:=count[son[x,1]]+count[son[x,2]]+1;
  end;

procedure clear(x:longint);
  begin
    count[x]:=1;
    fa[x]:=0;
    score[x]:=0;
    key[x]:=0;
    son[x,1]:=0;
    son[x,2]:=0;
    fa[0]:=0;
    count[0]:=0;
  end;

function tran(x:string):longint;
  var l,i:longint;
  begin
    l:=length(x);
    tran:=0;
    for i:=1 to l do
      tran:=tran*10+ord(x[i])-48;
  end;

function get(x:string):longint;
  var l,i,s:longint;
      p:link;
  begin
    l:=length(x);
    s:=0;
    for i:=1 to l do
      s:=(s+(sqr(ord(x[i]))*i mod rd)) mod rd;
    p:=hash[s];
    while p<>nil do
    begin
      if p^.st=x then
      begin
        get:=p^.loc;
        break;
      end;
      p:=p^.next;
    end;
    if p=nil then
    begin
      get:=-1;
      new(p);
      inc(t);
      p^.loc:=t;
      p^.st:=x;
      p^.next:=hash[s];
      hash[s]:=p;
    end
    else if what='+' then
    begin
      inc(t);
      p^.loc:=t;
    end;
  end;

procedure rotate(x,w:longint);
  var y:longint;
  begin
    y:=fa[x];
    if fa[y]=0 then root:=x
    else begin
      if son[fa[y],1]=y then son[fa[y],1]:=x
      else son[fa[y],2]:=x;
    end;
    fa[x]:=fa[y];
    son[y,3-w]:=son[x,w];
    fa[son[x,w]]:=y;
    son[x,w]:=y;
    fa[y]:=x;
    update(y);
    update(x);
  end;

procedure up(x:longint);
  var y:longint;
  begin
    y:=fa[x];
    while y<>0 do
    begin
      if key[y]>key[x] then
      begin
        if son[y,1]=x then rotate(x,2)
        else rotate(x,1);
      end
      else break;
      y:=fa[x];
    end;
    if y=0 then root:=x;
  end;

procedure sift(x:longint);
  var j1,j2:longint;
  begin
    repeat
      j1:=son[x,1];
      j2:=son[x,2];
      if (j1=0) and (j2=0) then exit;
      if j1=0 then rotate(j2,1)
      else if j2=0 then rotate(j1,2)
      else begin
        if (key[j1]>key[j2]) then rotate(j2,1)
        else rotate(j1,2);
      end;
    until false;
  end;

function rank(x:longint):longint;
  var y,p:longint;
  begin
    y:=fa[x];
    p:=x;
    rank:=count[son[x,2]];
    while y<>0 do
    begin
      if son[y,1]=p then rank:=rank+count[son[y,2]]+1;
      p:=y;
      y:=fa[p];
    end;
    rank:=rank+1;
  end;

function kth(x:longint):longint;
  var p:longint;
  begin
    p:=root;
    while true do
    begin
      if count[son[p,2]]+1=x then exit(p);
      if count[son[p,2]]+1>x then p:=son[p,2]
      else begin
        x:=x-count[son[p,2]]-1;
        p:=son[p,1];
      end;
    end;
  end;

procedure insert(s:string;x:longint);
  var p:longint;
  begin
    clear(t);
    score[t]:=x;
    key[t]:=trunc(random(ran));
    na[t]:=s;
    if root=0 then
    begin
      root:=t;
      fa[t]:=0;
    end
    else begin
      p:=root;
      repeat
        inc(count[p]);
        if x>score[p] then
        begin
          if son[p,2]=0 then break;
          p:=son[p,2];
        end
        else begin   //注意后插入的相等分数应放在左子树
          if son[p,1]=0 then break; 
          p:=son[p,1];
        end;
      until false;
      if score[p]>=x then son[p,1]:=t else son[p,2]:=t;  
      fa[t]:=p;
      up(t);
    end;
  end;

procedure delete(x:longint);
  var y:longint;
  begin
    sift(x);
    y:=fa[x];
    while y<>0 do
    begin
      dec(count[y]);
      y:=fa[y];
    end;
    y:=fa[x];
    if son[y,1]=x then son[y,1]:=0 else son[y,2]:=0;
    clear(x);
  end;

procedure ask(x:longint);
  var i,y:longint;
  begin
    if x+9>tot then y:=tot else y:=x+9;
    for i:=x to y do
    begin
      write(na[kth(i)]);
      if i<>y then write(' ');
    end;
    writeln;
  end;

begin
  randomize;
  readln(n);
  t:=0;
  for i:=1 to n do
  begin
    read(what);
    if what='?' then
    begin
      readln(s);
      if (s[1]>='0') and (s[1]<='9') then
      begin
        x:=tran(s);
        ask(x);
      end
      else begin
        x:=get(s);
        writeln(rank(x));
      end;
    end
    else begin
      s:='';
      read(ch);
      while ch<>' ' do
      begin
        s:=s+ch;
        read(ch);
      end;
      x:=0;
      readln(ss);
      x:=tran(ss);
      y:=get(s);
      if y=-1 then
      begin
        inc(tot);
        insert(s,x);
      end
      else begin
        insert(s,x);
        delete(y);
      end;
    end;
  end;
end.