poj3037

首先到每个点的速度实际上是一个定值，就是v0*2^(起点与当前点高度差）

所以当前点i到任意一个相邻点的时间都是一个定值，

不难想到构图最短路径

const dx:array[1..4] of integer=(-1,1,0,0);
      dy:array[1..4] of integer=(0,0,-1,1);
      inf=999999999999;

type link=^node;
     node=record
       po:longint;
       len:double;
       next:link;
     end;
     point=record
       num:longint;
       dis:double;
     end;

var num,a:array[0..110,0..110] of longint;
    d:array[0..10010] of double;
    w:array[0..10010] of link;
    heap:array[0..10010] of point;
    where:array[0..10010] of longint;
    t,i,j,n,m,k,x,y:longint;
    v,vn,mid:double;
    p:link;

procedure add(x,y:longint;c:double);
  var p:link;
  begin
    new(p);
    p^.po:=y;
    p^.len:=c;
    p^.next:=w[x];
    w[x]:=p;
  end;

procedure swap(var a,b:point);
  var c:point;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

function calc(x:longint):double;
  var i:longint;
  begin
    calc:=1;
    if x>0 then
    begin
      for i:=1 to x do
        calc:=calc*2;
    end
    else if x<0 then
    begin
      for i:=1 to abs(x) do
        calc:=calc/2;
    end;
  end;

procedure sift(i:longint);
  var j,x,y:longint;
  begin
    j:=i shl 1;
    while j<=t do
    begin
      if (j+1<=t) and (heap[j].dis>heap[j+1].dis) then inc(j);
      if heap[i].dis>heap[j].dis then
      begin
        x:=heap[i].num;
        y:=heap[j].num;
        where[x]:=j;
        where[y]:=i;
        swap(heap[i],heap[j]);
        i:=j;
        j:=i shl 1;
      end
      else break;
    end;
  end;

procedure up(i:longint);
  var j,x,y:longint;
  begin
    j:=i shr 1;
    while j>0 do
    begin
      if heap[i].dis<heap[j].dis then
      begin
        x:=heap[i].num;
        y:=heap[j].num;
        where[x]:=j;
        where[y]:=i;
        swap(heap[i],heap[j]);
        i:=j;
        j:=j shr 1;
      end
      else break;
    end;
  end;

begin
  readln(v,n,m);
  for i:=1 to n do
  begin
    for j:=1 to m do
    begin
      read(a[i,j]);
      inc(k);
      num[i,j]:=k;
    end;
  end;
  for i:=1 to n do
    for j:=1 to m do
    begin
      vn:=v*calc(a[1,1]-a[i,j]);
      for k:=1 to 4 do
      begin
        x:=i+dx[k];
        y:=j+dy[k];
        if num[x,y]>0 then add(num[i,j],num[x,y],1/vn);
      end;
    end;

  n:=n*m;
  t:=n;
  for i:=1 to n do
  begin
    if i=1 then d[i]:=0 else d[i]:=inf;
    heap[i].num:=i;
    heap[i].dis:=d[i];
    where[i]:=i;
  end;
  for i:=1 to n do
  begin
    x:=heap[1].num;
    mid:=heap[1].dis;
    if mid=inf then break;
    y:=heap[t].num;
    where[y]:=1;
    swap(heap[1],heap[t]);
    dec(t);
    sift(1);
    p:=w[x];
    while p<>nil do
    begin
      y:=p^.po;
      if d[y]>mid+p^.len then
      begin
        d[y]:=mid+p^.len;
        k:=where[y];
        heap[k].dis:=d[y];
        up(k);
      end;
      p:=p^.next;
    end;
  end;
  writeln(d[n]:0:2);
end.