bzoj3631

其实这道题其实可以转化为这样一个问题

给定n-1对点，将这两点x,y间简单路径上的点（包括起点终点）权值+1

（最后再把除了起点外的点的权值-1，注意终点没糖吃）

求每个点的权值

首先想到的是先找LCA然后暴力的对权值加，显然这样效率不够好

想到了树状数组完成区间修改和单点求值，是先将[l,r]中a[l]++,然后a[r+1]--;

这样就避免了对每个数都修改；

以此类推，我们可以假定路径使x-->root-->y上的点+1,

这样每个点的权值即为其所在子树和

设lca(x,y)=z 同样的道理，我们只要对a[x]++,a[y]++,然后对a[z]--，a[fa[z]]--

因为每个点的权值即为其所在子树和，所以只有x-->y的简单路径上的点权值+1了

这样的话我们可以做一遍LCA-tarjan就可以搞出来了（当然也可以再单独扫一遍）

type node=record
       po,next:longint;
       can:boolean;
     end;
 
var a,q:array[0..600010] of node;
    fa,f,p,w,ans,g:array[0..300010] of longint;
    v:array[0..300010] of boolean;
    st,i,j,n,m,x,y,t:longint;
 
function getf(x:longint):longint;
  begin
    if fa[x]<>x then fa[x]:=getf(fa[x]);
    exit(fa[x]);
  end;
 
procedure addq(x,y:longint);
  begin
    inc(m);
    q[m].po:=y;
    q[m].next:=w[x];
    w[x]:=m;
  end;
 
procedure add(x,y:longint);
  begin
    inc(t);
    a[t].po:=y;
    a[t].next:=p[x];
    p[x]:=t;
  end;
 
procedure tarjan(x:longint);
  var i,y,z:longint;
  begin
    i:=p[x];
    v[x]:=true;
    while i<>0 do
    begin
      y:=a[i].po;
      if not v[y] then
      begin
        f[y]:=x;
        tarjan(y);
        fa[y]:=x;
      end;
      i:=a[i].next;
    end;
    i:=w[x];
    while i<>-1 do
    begin
      y:=q[i].po;
      if v[y] and not q[i].can then
      begin
        z:=getf(y);
        q[i].can:=true;
        q[i xor 1].can:=true;
        inc(g[z]);
        inc(g[f[z]]);
      end;
      i:=q[i].next;
    end;
    ans[x]:=ans[x]-g[x]; 
    ans[f[x]]:=ans[f[x]]+ans[x];//做到这已经说明x的子树已经被访问完了，x的权值已经确定，直接加即可，不需要再dfs一遍
  end;
 
begin
  m:=-1;
  fillchar(w,sizeof(w),255);
  readln(n);
  read(x);
  st:=x;
  ans[x]:=1;
  for i:=1 to n-1 do
  begin
    read(y);
    addq(x,y);
    addq(y,x);
    inc(ans[y]);
    if i<>n-1 then inc(ans[y]);
    x:=y;
  end;
  for i:=1 to n-1 do
  begin
    readln(x,y);
    add(x,y);
    add(y,x);
  end;
  for i:=1 to n do
    fa[i]:=i;
 
  tarjan(1);
  for i:=1 to n do
  begin
    if i<>st then dec(ans[i]);
    writeln(ans[i]);
  end;
end.