bzoj2243

很明显是树链剖分吧
然后很明显要用线段树维护吧，即维护一段区间首、尾颜色和区间内颜色总数
然后修改lazy tag弄一弄，查询注意这一段尾和下一段首的颜色可能相同
然后就没什么了

type node=record
       po,next:longint;
     end;
     link=record
       l,r,s:longint;
     end;

var tree:array[0..400010] of link;
    lazy:array[0..400010] of longint;
    w:array[0..200010] of node;
    top,fa,d,size,a,b,c,p:array[0..100010] of longint;
    cas,i,n,m,x,y,z,len,t,prf,plf,rf,lf:longint;
    ch:char;

procedure swap(var a,b:longint);
  var c:longint;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure add(x,y:longint);
  begin
    inc(len);
    w[len].po:=y;
    w[len].next:=p[x];
    p[x]:=len;
  end;

procedure dfs1(x:longint);
  var i,y:longint;
  begin
    size[x]:=1;
    i:=p[x];
    while i<>0 do
    begin
      y:=w[i].po;
      if fa[x]<>y then
      begin
        d[y]:=d[x]+1;
        fa[y]:=x;
        dfs1(y);
        size[x]:=size[x]+size[y];
      end;
      i:=w[i].next;
    end;
  end;

procedure dfs2(x:longint);
  var q,i,y:longint;
  begin
    i:=p[x];
    q:=0;
    inc(t);
    c[x]:=t;
    b[t]:=x;
    while i<>0 do
    begin
      y:=w[i].po;
      if fa[x]<>y then
        if size[q]<size[y] then q:=y;
      i:=w[i].next;
    end;
    if q<>0 then
    begin
      top[q]:=top[x];
      dfs2(q);
    end;
    i:=p[x];
    while i<>0 do
    begin
      y:=w[i].po;
      if top[y]=0 then
      begin
        top[y]:=y;
        dfs2(y);
      end;
      i:=w[i].next;
    end;
  end;

procedure update(i:longint);
  begin
    tree[i].l:=tree[i*2].l;
    tree[i].r:=tree[i*2+1].r;
    tree[i].s:=tree[i*2].s+tree[i*2+1].s;
    if tree[i*2].r=tree[i*2+1].l then dec(tree[i].s);
  end;

procedure build(i,l,r:longint);
  var m:longint;
  begin
    if l=r then
    begin
      tree[i].l:=a[b[l]];
      tree[i].r:=a[b[l]];
      tree[i].s:=1;
    end
    else begin
      m:=(l+r) shr 1;
      build(i*2,l,m);
      build(i*2+1,m+1,r);
      update(i);
    end;
  end;

procedure push(i:longint);
  begin
    tree[i*2].l:=lazy[i];
    tree[i*2+1].l:=lazy[i];
    tree[i*2].r:=lazy[i];
    tree[i*2+1].r:=lazy[i];
    tree[i*2+1].s:=1;
    tree[i*2].s:=1;
    lazy[i*2]:=lazy[i];
    lazy[i*2+1]:=lazy[i];
    lazy[i]:=-1;
  end;

procedure change(i,l,r,x,y,z:longint);
  var m:longint;
  begin
    if (x<=l) and (y>=r) then
    begin
      tree[i].l:=z;
      tree[i].r:=z;
      tree[i].s:=1;
      lazy[i]:=z;
    end
    else begin
      m:=(l+r) shr 1;
      if lazy[i]<>-1 then push(i);
      if x<=m then change(i*2,l,m,x,y,z);
      if y>m then change(i*2+1,m+1,r,x,y,z);
      update(i);
    end;
  end;

procedure work(x,y,z:longint);
  var f1,f2:longint;
  begin
    f1:=top[x];
    f2:=top[y];
    while f1<>f2 do
    begin
      if d[f1]>=d[f2] then
      begin
        change(1,1,n,c[f1],c[x],z);
        x:=fa[f1];
      end
      else begin
        change(1,1,n,c[f2],c[y],z);
        y:=fa[f2];
      end;
      f1:=top[x];
      f2:=top[y];
    end;
    if c[x]>c[y] then swap(x,y);
    change(1,1,n,c[x],c[y],z);
  end;

function getans(i,l,r,x,y:longint):longint;
  var m:longint;
  begin
    if (x<=l) and (y>=r) then getans:=tree[i].s
    else begin
      m:=(l+r) shr 1;
      if lazy[i]<>-1 then push(i);
      getans:=0;
      if x<=m then getans:=getans+getans(i*2,l,m,x,y);
      if y>m then getans:=getans+getans(i*2+1,m+1,r,x,y);
      if (x<=m) and (y>m) and (tree[i*2].r=tree[i*2+1].l) then
        getans:=getans-1;
    end;
    if l=x then
    begin
      if cas=1 then
        lf:=tree[i].l
      else rf:=tree[i].l;
    end;
    if r=y then t:=tree[i].r;
  end;

function ask(x,y:longint):longint;
  var f1,f2,s:longint;
  begin
    f1:=top[x];
    f2:=top[y];
    s:=0;
    prf:=-1;
    plf:=-1;
    lf:=-1;
    rf:=-1;
    while f1<>f2 do
    begin
      if d[f1]>=d[f2] then
      begin
        cas:=1;
        s:=s+getans(1,1,n,c[f1],c[x]);
        if t=plf then dec(s); //维护x链的尾部
        plf:=lf;
        x:=fa[f1];
      end
      else begin
        cas:=2;
        s:=s+getans(1,1,n,c[f2],c[y]);
        if t=prf then dec(s);  //维护y链尾部
        prf:=rf;
        y:=fa[f2];
      end;
      f1:=top[x];
      f2:=top[y];
    end;

    if c[x]>c[y] then
    begin
      swap(x,y);
      swap(prf,plf);
    end;
    cas:=1;
    s:=s+getans(1,1,n,c[x],c[y]);
    if lf=plf then dec(s); //注意这里有两种情况
    if t=prf then dec(s);
    exit(s);
  end;

begin
  readln(n,m);
  for i:=1 to n do
    read(a[i]);
  for i:=1 to n-1 do
  begin
    readln(x,y);
    add(x,y);
    add(y,x);
  end;
  d[1]:=1;
  dfs1(1);
  top[1]:=1;
  dfs2(1);
  build(1,1,n);
  fillchar(lazy,sizeof(lazy),255);
  for i:=1 to m do
  begin
    read(ch);
    if ch='C' then
    begin
      readln(x,y,z);
      work(x,y,z);
    end
    else begin
      readln(x,y);
      writeln(ask(x,y));
    end;
  end;
end.