bzoj1251

这道题相比较bzoj3223只不过多了一个区间加上一个数，这显然还是类似的

和线段树经典的打标记类似

const inf=-2147483647;
      sroot=-1;
var son:array[-1..50010,1..2] of longint;
    fa,maxx,count,a,lazy:array[-1..50010] of longint;
    v:array[0..50010] of boolean;
    ch,i,n,m,l,r,z,root:longint;

function max(a,b:longint):longint;
  begin
    if a>b then exit(a) else exit(b);
  end;

procedure swap(var a,b:longint);
  var c:longint;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure work_add(x,w:longint);
  begin
    a[x]:=a[x]+w;
    lazy[x]:=lazy[x]+w;
    maxx[x]:=maxx[x]+w;
  end;

procedure change(x:longint);
  begin
    swap(son[x,1],son[x,2]);
    v[x]:=not v[x];
  end;

procedure pushdown(x:longint);
  var l,r:longint;
  begin
    l:=son[x,1];
    r:=son[x,2];
    if v[x] then
    begin
      if l<>-1 then change(l);
      if r<>-1 then change(r);
      v[x]:=false;
    end;
    if lazy[x]<>0 then
    begin
      if l<>-1 then work_add(l,lazy[x]);
      if r<>-1 then work_add(r,lazy[x]);
      lazy[x]:=0;
    end;
  end;

procedure updata(i:longint);
  begin
    count[i]:=count[son[i,1]]+count[son[i,2]]+1;
    maxx[i]:=max(max(maxx[son[i,1]],maxx[son[i,2]]),a[i]);
  end;

function find(x:longint):longint;
  var p:longint;
  begin
    p:=root;
    while true do
    begin
      pushdown(p);
      if count[son[p,1]]+1=x then exit(p);
      if count[son[p,1]]+1>x then p:=son[p,1]
      else begin
        x:=x-count[son[p,1]]-1;
        p:=son[p,2];
      end;
    end;
  end;

procedure rotate(x,w:longint);
  var y:longint;
  begin
    pushdown(x);
    y:=fa[x];
    if fa[y]<>sroot then
    begin
      if son[fa[y],1]=y then
        son[fa[y],1]:=x
      else son[fa[y],2]:=x;
    end;
    fa[x]:=fa[y];
    if son[x,w]<>-1 then fa[son[x,w]]:=y;
    son[y,3-w]:=son[x,w];
    son[x,w]:=y;
    fa[y]:=x;
    updata(y);
    updata(x);
  end;

procedure splay(x,f:longint);
  var y:longint;
  begin
    while fa[x]<>f do
    begin
      y:=fa[x];
      if fa[y]=f then
        if x=son[y,1] then rotate(x,2) else rotate(x,1)
      else
        if y=son[fa[y],1] then
          if x=son[y,1] then
          begin
            rotate(y,2);
            rotate(x,2);
          end
          else begin
            rotate(x,1);
            rotate(x,2);
          end
        else
          if x=son[y,1] then
          begin
            rotate(x,2);
            rotate(x,1);
          end
          else begin
            rotate(y,1);
            rotate(x,1);
          end;
    end;
    updata(x);
    if f=sroot then root:=x;
  end;

procedure add(l,r,w:longint);
  var p:longint;
  begin
    p:=find(l);
    splay(p,sroot);
    p:=find(r+2);
    splay(p,root);
    p:=son[son[root,2],1];
    work_add(p,w);
  end;

procedure reverse(l,r:longint);
  var p:longint;
  begin
    p:=find(l);
    splay(p,sroot);
    p:=find(r+2);
    splay(p,root);
    p:=son[son[root,2],1];
    change(p);
  end;

function ask(l,r:longint):longint;
  var p:longint;
  begin
    p:=find(l);
    splay(p,sroot);
    p:=find(r+2);
    splay(p,root);
    p:=son[son[root,2],1];
    exit(maxx[p]);
  end;

function build(l,r:longint):longint;
  var m:longint;
  begin
    m:=(l+r) shr 1;
    build:=m;
    if l+1<=m then
    begin
      son[m,1]:=build(l,m-1);
      fa[son[m,1]]:=m;
    end;
    if r-1>=m then
    begin
      son[m,2]:=build(m+1,r);
      fa[son[m,2]]:=m;
    end;
    updata(m);
  end;

begin
  readln(n,m);
  fillchar(son,sizeof(son),255);
  fillchar(lazy,sizeof(lazy),0);
  fillchar(a,sizeof(a),0);
  fillchar(v,sizeof(v),false);
  a[-1]:=inf;  //注意这个-1很重要，在splay过程，我有的地方没有判断子节点是否存在
  maxx[-1]:=inf;
  inc(n);
  root:=build(0,n);
  fa[root]:=sroot;
  for i:=1 to m do
  begin
    read(ch,l,r);
    if ch=1 then
    begin
      readln(z);
      add(l,r,z);
    end
    else begin
      readln;
      if ch=2 then reverse(l,r)
      else writeln(ask(l,r));
    end;
  end;
end.