bzoj1444

显然自动机上高斯消元
根据AC自动机上的转移可以列出一系列方程
但这个样的方程解出来全0是一组解
说明有线性组合的情况
考虑除非没人能赢，否则每个人赢的概率和为1
那么我们只要把原来的第一个方程换成这个即可

var ans,d:array[0..110] of double;
    a:array[0..110,0..110] of double;
    w,q,f:array[0..110] of longint;
    trie:array[0..110,0..26] of longint;
    v:array[0..110] of boolean;
    j,k,i,n,m,l,x,y,t:longint;
    s:string;

procedure swap(var a,b:double);
  var c:double;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure ac;
  var h,r,x,y,i:longint;
  begin
    h:=1;
    r:=0;
    for i:=1 to m do
      if trie[0,i]>0 then
      begin
        inc(r);
        q[r]:=trie[0,i];
      end;

    while h<=r do
    begin
      x:=q[h];
      for i:=1 to m do
        if trie[x,i]>0 then
        begin
          y:=trie[x,i];
          inc(r);
          q[r]:=y;
          j:=f[x];
          while (j>0) and (trie[j,i]=0) do j:=f[j];
          f[y]:=trie[j,i];
        end;
      inc(h);
    end;
  end;

procedure gauss;
  var i,j,k,p,u:longint;
      c:double;
  begin
    u:=0;
    for i:=0 to t do
    begin
      p:=u;
      for j:=u+1 to t do
        if abs(a[j,i])>abs(a[p,i]) then p:=j;

      if (p=u) and (a[p,i]=0) then continue;
      if p<>u then
      begin
        for j:=0 to t+1 do
          swap(a[u,j],a[p,j]);
      end;
      for j:=u+1 to t do
        if a[j,i]<>0 then
        begin
          c:=a[j,i]/a[u,i];
          for k:=0 to t+1 do
            a[j,k]:=a[j,k]-a[u,k]*c;
        end;
      inc(u);
    end;
    for i:=t downto 0 do
    begin
      if a[i,i]=0 then continue;
      for j:=i+1 to t do
        a[i,t+1]:=a[i,t+1]-ans[j]*a[i,j];
      ans[i]:=a[i,t+1]/a[i,i];
    end;
  end;

begin
  readln(n,l,m);
  for i:=1 to m do
  begin
    readln(x,y);
    d[i]:=x/y;
  end;
  for i:=1 to n do
  begin
    readln(s);
    j:=0;
    for k:=1 to l do
    begin
      x:=ord(s[k])-64;
      if trie[j,x]=0 then
      begin
        inc(t);
        trie[j,x]:=t;
      end;
      j:=trie[j,x];
    end;
    w[i]:=j;
    v[j]:=true;
  end;
  ac;
  for i:=0 to t do
  begin
    a[i,i]:=-1;
    if not v[i] then
    begin
      for k:=1 to m do
      begin
        j:=i;
        while (j>0) and (trie[j,k]=0) do j:=f[j];
        a[trie[j,k],i]:=a[trie[j,k],i]+d[k];
      end;
    end;
  end;
  for i:=0 to t do
    if not v[i] then a[0,i]:=0 else a[0,i]:=1;
  a[0,t+1]:=1;
  gauss;
  for i:=1 to n do
    if (ans[w[i]]>0) and (ans[w[i]]<=1) then
      writeln(ans[w[i]]:0:2)
    else writeln('0.00');
end.