Perl6多线程1 Thread : new / run

先看一个小例子:

sub A($name = 3) {
  #默认参数
  say $name;
}
sub B(:name($name)) {
  #默认参数为 any
  say $name;
}
A();
A(100);
B();
B(name => 'root');

这是正常的调用方式。

再看如下代码:

sub A($name) {
  #默认参数
  say $name;
}
sub B() {
  say 'BBBBBBBB';
}
A(1);
B;
B();
&A(123);
&B();

可以看到， 当函数没参数时， 可以直接用 B() 来调用，如果有参数时， 可以 A() / &A() 调用。

再看一下例子：

sub A($name) {
  #默认参数
  say $name;
}
sub B() {
  say 'BBBBBBBB';
}
say &A;
say &A(123);
say &B;
say &B();

从上例可以看出， &A / &B 并不是调用函数， 而是显示这个函数的地址(也就是这个函数的代码块形式)。

 

这个 &B 可以看做是函数的地址。

如下代码:

sub A($name) {
  #默认参数
  say $name;
  $name();
}
sub B() {
  say 'BBBBBBBB';
}

A(&B);

把 &B 传送进去， 在 A 函数中调用 $name() 就相当于: &B(), 也就是调用函数B了。

 

对于 A 函数的定义， 可以 把 $name 改为 &name, 指定参数 name 为代码块形式的参数：

sub A(&name) {
  #默认参数
  say &name;
  #$name();
}
sub B() {
  say 'BBBBBBBB';
}

A('B');

#输出:
C:p6>perl6 t.p6
Type check failed in binding to parameter '&name'; expected Callable but got Str
 ("B")
  in sub A at t.p6 line 1
  in block <unit> at t.p6 line 10

这时调用会出错， 因为我们指定参数为 &name, 也就是代码块的形式参数。

我们调用时， 发送代码块就行：

sub A(&name) {
  #默认参数
  say &name;
  &name();
}
sub B() {
  say 'BBBBBBBB';
}

A(sub test {say 'abc';});

这时程序可正常运行。

像下面这样：

sub A(&name) {
  #默认参数
  say &name;
  &name();
}
sub B() {
  say 'BBBBBBBB';
}

A(sub test {say 'abc';});
A(&B);
#输出:
C:p6>perl6 t.p6
sub test () { #`(Sub|89260968) ... }
abc
sub B () { #`(Sub|89261120) ... }
BBBBBBBB

C:p6>

 

说了这么多， 关键问题只是说明函数调用时， 参数可以为代码块形式。 可以用普通形式的参数($name)接收代码块, 或指定参数为代码块形式(&name)来接收代码块。

最后回到文章正题：perl6 多线程 。

Thread 类内置， 不用另外安装。

线程创建方法为:

method new(:&code!, Bool :$app_lifetime = False, Str :$name = '<anon>' --> Thread:D)

 new函数有个参数: :&code! 就是上面所说的例子的形式， 它是个字典形式的代码块， 调用时这样：

code => 代码块
code => &B
code => {say 'Thread';}

 对于第二个 app_lifetime参数，是用来设置线程用的。 当设置为 true 时， 主进程退出后线程跟着退出。当设置为 false 时， 线程只有它运行结束时才自动退出。

name 是指定一个标识些线程的字符串。

创建一个线程后， 线程不会自动运行， 我们可以用 run 方法运行线程。

看如下代码， app_lifetime 设置为 True:

sub B() {
  for 1..5 {
    say $_;
    sleep(2);
  }
  say "线程退出!";
}

my $t = Thread.new(code => &B, :app_lifetime, :name<thread_B>);
$t.run;
say "主进程退出!";

结果:

C:p6>perl6 t.p6
主进程退出!

C:p6>

可以看到， 主进程退出后线程也跟着退出了。

我们把 app_lifetime 设置为 false再看看：

sub B() {
  for 1..5 {
    say $_;
    sleep(2);
  }
  say "线程退出!";
}

my $t = Thread.new(code => &B, :!app_lifetime, :name<thread_B>);
$t.run;
say "主进程退出!";

 结果:

C:p6>perl6 t.p6
主进程退出!
1
2
3
4
5
线程退出!

C:p6>

可以看到主进程结束后线程还是会运行。

总结：

Thread.new创建线程。

code 参数指定代码块。

app_lifetime 设置线程是否与主进程一同退出。