bzoj2738: 矩阵乘法

2738: 矩阵乘法

Time Limit: 20 Sec  Memory Limit: 256 MB
Submit: 1396  Solved: 603
[Submit][Status][Discuss]

Description

　　给你一个N*N的矩阵，不用算矩阵乘法，但是每次询问一个子矩形的第K小数。

Input

 

　　第一行两个数N,Q，表示矩阵大小和询问组数；
　　接下来N行N列一共N*N个数，表示这个矩阵；
　　再接下来Q行每行5个数描述一个询问：x1,y1,x2,y2,k表示找到以(x1,y1)为左上角、以(x2,y2)为右下角的子矩形中的第K小数。

Output

　　对于每组询问输出第K小的数。

Sample Input

2 2
2 1
3 4
1 2 1 2 1
1 1 2 2 3

Sample Output

1
3

HINT

　　矩阵中数字是109以内的非负整数；

　　20%的数据：N<=100,Q<=1000；

　　40%的数据：N<=300,Q<=10000；

　　60%的数据：N<=400,Q<=30000；

　　100%的数据：N<=500,Q<=60000。

题解

整体二分，把正常区间k大的做法中的一维树状数组和二维树状数组就行了。

我把数组开大十倍……就不T了……感觉奥妙重重啊

program j01;
type xx=record x1,y1,x2,y2,k,id:longint; end;
     yy=record x,y,w:longint; end;
var c:array[0..600,0..600]of longint;
    op,tmp:array[0..600086]of xx;
    ans:array[0..600086]of longint;
    a:array[0..3000000]of yy;
    tt,n,m,i,j:longint;

procedure qsort(l,r:longint);
var i,j,x:longint;y:yy;
begin
  i:=l;j:=r;x:=a[i].w;
  repeat
    while a[i].w<x do inc(i);
    while x<a[j].w do dec(j);
    if i<=j then
    begin
      y:=a[i];a[i]:=a[j];a[j]:=y;
      inc(i);dec(j);
    end;
  until i>j;
  if i<r then qsort(i,r);
  if l<j then qsort(l,j);
end;

procedure add(x,y,dd:longint);
var i,j:longint;
begin
  i:=x;
  while i<=n do
  begin
    j:=y;
    while j<=n do
    begin
      inc(c[i,j],dd);j:=j+(j and(-j));
    end;
    i:=i+(i and(-i));
  end;
end;

function ask(x,y:longint):longint;
var i,j:longint;
begin
  ask:=0;i:=x;
  while i>0 do
  begin
    j:=y;
    while j>0 do
    begin
      inc(ask,c[i,j]);j:=j-(j and(-j));
    end;
    i:=i-(i and(-i));
  end;
end;

procedure solve(ql,qr,l,r:longint);
var i,tmpp,lt,rt,mid:longint;
begin
  if ql>qr then exit;
  if l=r then
  begin
    for i:=ql to qr do ans[op[i].id]:=a[l].w;
    exit;
  end;
  lt:=ql-1;rt:=qr+1;mid:=(l+r)div 2;
  for i:=l to mid do
    add(a[i].x,a[i].y,1);
  for i:=ql to qr do
  begin
    tmpp:=ask(op[i].x2,op[i].y2)-ask(op[i].x2,op[i].y1-1)-ask(op[i].x1-1,op[i].y2)+ask(op[i].x1-1,op[i].y1-1);
    if tmpp>=op[i].k then
    begin
      inc(lt);tmp[lt]:=op[i];
    end else
    begin
      op[i].k:=op[i].k-tmpp;
      dec(rt);tmp[rt]:=op[i];
    end;
  end;
  for i:=l to mid do
    add(a[i].x,a[i].y,-1);
  for i:=ql to qr do op[i]:=tmp[i];
  solve(ql,lt,l,mid);
  solve(rt,qr,mid+1,r);
end;

begin
  readln(n,m);
  tt:=0;
  for i:=1 to n do
    for j:=1 to n do
    begin
      inc(tt);a[tt].x:=i;a[tt].y:=j;
      read(a[tt].w);
    end;
  qsort(1,tt);
  for i:=1 to m do
  begin
    read(op[i].x1,op[i].y1,op[i].x2,op[i].y2,op[i].k);
    op[i].id:=i;
  end;
  solve(1,m,1,tt);
  for i:=1 to m do writeln(ans[i]);
end.