【PowerOJ1740&网络流24题】圆桌聚餐（最大流）

题意：

来自n个不同国家的代表开会，每个国家代表数为ci 会场有m张圆桌，每张桌子可容纳mi人 不希望有同一个国家的代表在同一张桌子上就餐 设计一个合法方案

(n,m<=300)

思路：最大流，保存原边上限，与残余网络比较是否有所变动即可。

【问题分析】

二分图多重匹配问题，可以用最大流解决。

【建模方法】

建立二分图，每个单位为X集合中的顶点，每个餐桌为Y集合中的顶点，增设附加源S和汇T。

1、从S向每个Xi顶点连接一条容量为该单位人数的有向边。

2、从每个Yi顶点向T连接一条容量为该餐桌容量的有向边。

3、X集合中每个顶点向Y集合中每个顶点连接一条容量为1的有向边。

求网络最大流，如果最大流量等于所有单位人数之和，则存在解，否则无解。对于每个单位，从X集合对应点出发的所有满流边指向的Y集合的顶点就是该单位人员的安排情况（一个可行解）。

【建模分析】

对于一个二分图，每个顶点可以有多个匹配顶点，称这类问题为二分图多重匹配问题。X，Y集合之间的边容量全部是1，保证两个点只能匹配一次（一个餐桌上只能有一个单位的一个人），源汇的连边限

制了每个点匹配的个数。求出网络最大流，如果流量等于X集合所有点与S边容量之和，那么则说明X集合每个点都有完备的多重匹配。

【问题另解】

贪心，更好的方法其实是贪心。首先把所有单位和餐桌按人数从大到小排序，一种适当的贪心策略就是对于每个单位，所有人每次尽量去剩余容量较大的餐桌就坐。按照这种贪心策略，如果某时发现有人

已经无法就坐，则无解。具体方法为用线段树维护餐桌的剩余容量，按人数从多到少安排每个单位的人员，每次安排就是把容量餐桌前k大的餐桌人数减1（k为该单位人数）。为保证线段树前k位时刻为前

k大，要维护第k与第k+1,k+2,...人数与第k相等的位置，减少第k大时要减少尽量靠后的，这样才能保证单调。

UPD（19.10.28）：显然这个线段树维护的贪心做法只有在判断是否有解的时候有用，因为光输出方案的复杂度就比它大

其次这个前k大变动的时刻真的能维护？理解不能……

UPD（19.10.29）：听说splay可以做，要支持区间-1和把前k大的区间抠出来，等其他题目结束以后写一下，感觉细节有点多

var head,vet,next,len,dis,gap,ob,save,fan:array[0..300000]of longint;
    a,b,q:array[1..300]of longint;
    num:array[1..200,1..300]of longint;
    n,m,i,j,src,source,tot,s,sum:longint;

procedure add(a,b,c:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 len[tot]:=c;
 head[a]:=tot;

 inc(tot);
 next[tot]:=head[b];
 vet[tot]:=a;
 len[tot]:=0;
 head[b]:=tot;
end;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

function dfs(u,aug:longint):longint;
var e,v,t,val,flow:longint;
begin
 if u=src then exit(aug);
 e:=head[u]; val:=s-1; flow:=0;
 while e<>0 do
 begin
  v:=vet[e];
  if len[e]>0 then
  begin
   if dis[u]=dis[v]+1 then
   begin
    t:=dfs(v,min(len[e],aug-flow));
    len[e]:=len[e]-t;
    len[fan[e]]:=len[fan[e]]+t;
    flow:=flow+t;
    if dis[source]>=s then exit(flow);
    if aug=flow then break;
   end;
   val:=min(val,dis[v]);
  end;
  e:=next[e];
 end;
 if flow=0 then
 begin
  dec(gap[dis[u]]);
  if gap[dis[u]]=0 then dis[source]:=s;
  dis[u]:=val+1;
  inc(gap[dis[u]]);
 end;
 exit(flow);
end;

function maxflow:longint;
var ans:longint;
begin
 fillchar(gap,sizeof(gap),0);
 fillchar(dis,sizeof(dis),0);
 gap[0]:=s; ans:=0;
 while dis[source]<s do ans:=ans+dfs(source,maxlongint);
 exit(ans);
end;

procedure print;
var i,j,s:longint;
begin
 writeln(1);
 for i:=1 to n do
 begin
  s:=0;
  for j:=1 to m do
   if len[num[i,j]]<>save[num[i,j]] then begin inc(s); q[s]:=j; end;
  for j:=1 to s-1 do write(q[j],' ');
  write(q[s]);
  writeln;
 end;
end;

begin
 assign(input,'poweroj1740.in'); reset(input);
 assign(output,'poweroj1740.out'); rewrite(output);
 readln(n,m);
 for i:=1 to 200000 do
  if i mod 2=1 then fan[i]:=i+1
   else fan[i]:=i-1;
 for i:=1 to n do begin read(a[i]); sum:=sum+a[i]; end;
 for i:=1 to m do read(b[i]);
 s:=n+m+2; source:=n+m+1; src:=n+m+2;
 for i:=1 to n do
  for j:=1 to m do
  begin
   num[i,j]:=tot+1; add(i,j+n,1);
  end;
 for i:=1 to tot do save[i]:=len[i];
 for i:=1 to n do add(source,i,a[i]);
 for i:=1 to m do add(i+n,src,b[i]);
 if maxflow<sum then writeln(0)
  else print;
 close(input);
 close(output);
end.