sql server try catch tran

-- move approver tasks to PushTaskLog

DECLARE @approverID NVARCHAR(100) = ''
DECLARE @remark NVARCHAR(100) = CONVERT(NVARCHAR(19), GETDATE(), 120)
DECLARE @applicationID NVARCHAR(100) = ''
DECLARE @extensionID NVARCHAR(100) = ''

BEGIN TRY
    IF OBJECT_ID('tempdb..#tmpTask') IS NOT NULL
        DROP TABLE #tmpTask

    SELECT *
    INTO #tmpTask
    FROM dbo.Task
    WHERE ApproverID = @approverID
          AND ApplicationID = @applicationID
          AND ExtensionID = @extensionID

    BEGIN TRAN
    INSERT dbo.PushTaskLog
    (
        ID,
        ApplicationID,
        ExtensionID,
        TaskID,
        Approver,
        Requestor,
        Title,
        SubmittedDate,
        ApproverLevel,
        XmlBody,
        CreatedDate,
        TaskStatus,
        LogStatus
    )
    SELECT NEWID(),
           ApplicationID,
           ExtensionID,
           TaskID,
           ApproverID,
           ApplicantName,
           Title,
           SubmittedDate,
           ApproverLevel,
           NativeApplicationData,
           CreatedDate,
           @remark,
           -1
    FROM #tmpTask

    DELETE main
    FROM dbo.Task main
        INNER JOIN #tmpTask tmp
            ON tmp.ID = main.ID
    COMMIT TRAN

    DROP TABLE #tmpTask
END TRY
BEGIN CATCH
    PRINT ERROR_MESSAGE()
    IF @@TRANCOUNT > 0
    BEGIN
        ROLLBACK TRAN
    END

END CATCH