FLEX SharedObject介绍及应用

ShareObject介绍：

1 ShareObject,顾名思义共享对象,而通常意义上的共享，从B/S结构上来讲,无非是客户端（浏览器端）的共享和服务器端的共享了,不错,ShareObject刚好份演了这两种角色。而且ShareObject也是按此进行了两种分类,一类是LSO——Local Share Object（本地共享对象）其实类似于cookie，而另一种RSO——Remote Share Object(远程共享对象) 我感觉比较类似于JSP中的Application对象，但好象比Application更强大。

2.存储位置 
以 Windows为例，目录为 
C:Documents and Settings[ username ] \Application Data\Macromedia\Flash 
Player\#SharedObjects\ [ random character directory name ] ， 在Mac OS X 上， 目录为 
/Users/[ username ] /Library/Preferences/Macromedia/Flash Player/#SharedObject/ [ random 
character directory name ]。随机字符目录命名是为了安全考虑 

下面我分别用实例代码来说两者的用法和用途：

一：LSO（本地共享对象）

LSO的用法比较简单，和我们平常操作Cookie大同小异：

1．得到一个共享对象：

var so:SharedObject=SharedObject.getLocal("mydata","/");

2．往共享对象里存入值：

var user:Object=new Object();

              user.userName=userName.text;

              user.passWord=passWord.text;

              user.isSaveLogin=(remember.selected==true?1:0);

              so.data.user=user;

3．清除共享对象里的值：

       var so:SharedObject=SharedObject.getLocal("mydata","/");

                            if(so.data.user!=null){

                                   so.data.user=null;

                            }

4．读取共享对象里的值：

       var so:SharedObject=SharedObject.getLocal("mydata","/");

                            if(so.data.user!=null){

                                   userName.text=so.data.user.userName;

                                   passWord.text=so.data.user.passWord;

                                   if(so.data.user.isSaveLogin.toString()=="1"){

                                          remember.selected=true;

                                   }

二：RSO（远程共享对象）：

 RSO是服务器端的共享对象，服务器端的数据共享可以实现多个客户端数据共享，在这里服务器我采用Flash Media Server3，FMS的使用非常简便，你只要在安装目录下找到Applications目录，并在其下新建一个子目录就可以成为你的工程或项目了。关于FMS的使用大家可以参考相关文章，本文不做介绍：利用FMS和RSO我们可以实现非常多的功能，诸如，聊天室，联机游戏，视频会议，在线视频录制和视频聊天。。。。。。

在这里我用一个简单的聊天室实例为例稍做讲解：

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" creationComplete="TextSO ();">
    <mx:Script>
        <![CDATA[
          import flash.events.SyncEvent;
          import flash.events.NetStatusEvent;
          import flash.events.MouseEvent;
          import flash.net.SharedObject;
          import flash.net.NetConnection;
          
        private var text_so:SharedObject;
        private var nc:NetConnection;
        private var rtmpGo:String;
        private var good:Boolean;

        public function TextSO ():void
        { 
             button.label="Send";
             button.addEventListener (MouseEvent.CLICK,sendMsg);//为发送按钮添加发送事件
             rtmpGo = "rtmp://localhost/basicSO";//这里设置FMS服务器的连接地址,basicSO即为,
             //FMS安装目录下Applications下自己手动新建的一个文件夹名称,也是FMS的工程名,就是这么简洁,不可意议
             nc = new NetConnection( );//产生一个连接对象
             nc.connect (rtmpGo);//连接到上面的地址
             nc.addEventListener (NetStatusEvent.NET_STATUS,doSO);//加入连接的监听事件,以便根据连接返回的状态做相应处理
        }

        private function doSO (e:NetStatusEvent):void
        {    
             good=e.info.code == "NetConnection.Connect.Success";//判断是否为连接成功状态
             //连接返回的状态有好几种,大家可以参看FMS的文档,很详尽
             if (good)//如果连接成轼,执行如下操作
             {
                   text_so=SharedObject.getRemote("test",nc.uri,false);//得到远程共享对象,false属性是设置共享的数据为非持久化的,
                       //即重启服务器后,先前的数据不会保存
                   text_so.connect (nc);
                   text_so.addEventListener (SyncEvent.SYNC,checkSO);
                   //为共享对象添加异步事件,这也是服务器同步处理多客户端最关键的地方,
                   //一个客户端进行了什么操作,其它客户端也会有相应的变化,就是通过此事件来完成的
             }
        }

        private function checkSO (e:SyncEvent):void
        {
             for (var chng:uint; chng<e.changeList.length; chng++)
             {
                   switch (e.changeList[chng].code)
                   {
                        case "clear" :
                             break;

                        case "success" :
                             trace (text_so.data.msg);
                             break;

                        case "change" ://一个客户端改变数据会更新所有客户端
                             textArea.htmlText+=text_so.data.msg + "
";
                             break;
                   }
             }
        }

        private function sendMsg (e:MouseEvent):void
        {
             text_so.setProperty ("msg",textInput.text);//将新的信息存入共享对象
             textArea.htmlText+=text_so.data.msg + "
";//更新客户端的信息列表
        }


        ]]>
    </mx:Script>
    <mx:VBox>
        <mx:TextArea id="textArea" width="200" height="200"/>//信息列表框
        <mx:TextInput id="textInput"/>//消息输入框
        <mx:Button id="button" />//发送按钮
    </mx:VBox>
</mx:Application>