业务逻辑与界面元素分离的一次小尝试

项目中有一个需求，为单据的表头增加自定义项。受制于现在的架构和表头布局自定义的实现机制，自定义项的内容只能预先在IDE里面创建好，而不能通过代码动态创建，只好在单据基类里面预先放入一组控件。由于自定义项本身需要提供编辑、参照、配置、读取与保存等操作，而基类本身已经臃肿不堪，接这个机会尝试一次界面与业务逻辑分离的尝试。因为架构中本身没有数据访问曾的设计和实现，而这个仅仅是作为一个尝试，因此控制类里面并没有对数据访问这块进行分离。类图如下：

因为自定义项目前支持的是3个，所以定义了一个常量来描述自定义项的个数，以后如果有扩充，修改这个常量即可。

详细代码如下：

{
  该类用于控制单据表头自定义项。
  created by fhying@2012.05.04
}
unit BillTitleCustomItemClass;

interface

uses
  SysUtils, Classes, Controls, Variants, Dialogs, DB, DBClient, cxEdit, cxDBEdit,
  Forms, Messages;

const
  Const_BillTitleCustomItem_MAX = 3;

type
  TBillTitleCustomItem = record
        itemindex : Integer; {自定义项序号（1-3）}
        itemtype : Integer; {自定义项类型（0编辑、1参照）}
        itemdatasource : string; {参照的话，数据来源（目前考虑的是基本信息表，如附加说明）}
        itemdatafield : string; {参照的话，数据来源的字段}
  end;
  TBillTitleCustomItems = array[1..Const_BillTitleCustomItem_MAX] of TBillTitleCustomItem;

  TBillTitleCustomItemClass = class(TComponent)
  private
    FcdsSQL : TClientDataSet;
    FBillType: Integer;
    FBillTitleCustomItems : TBillTitleCustomItems;
    FBillTitleCustomDataSource: TDataSource;
    function GetBillTitleCustomItems: TBillTitleCustomItems;
    procedure SetBillTitleCustomDataSource(const Value: TDataSource);
  protected
    { 根据索引获取自定义项的编辑组件 }
    function GetButtonEdit(AItemIndex : Integer) : TcxDBButtonEdit; virtual;
    { 初始化自定义项内容 }
    procedure InitBillTitleCustomItems;
    { 创建cds，用于执行sql语句 }
    procedure CreateCDS;
    { 保存自定义项配置到数据库 }
    function SaveBillTitleCustomItems(AItemIndex : Integer = 0) : Boolean;
    { 从数据库读取自定义项配置 }
    procedure LoadBillTitleCustomItems;
    { 为自定义项编辑组件进行事件绑定 }
    procedure BindcxButtonEdits(AItemIndex : Integer = 0); virtual;
    { 绑定自定义项组件的按钮单击事件 }
    procedure PropertiesButtonClick(Sender: TObject; AButtonIndex: Integer);
    { 执行自定义项编辑组件的参照功能 }
    procedure Reference(AItemIndex : Integer);
    { 打开自定义项的配置界面 }
    procedure CustomConfig(AItemIndex : Integer);
    { 绑定数据源 }
    procedure SetEditDataSource;
  public
    { 自定义构造函数，传入单据类型。 }
    constructor CreateMy(AOwnerForm : TComponent; ABillType : Integer); virtual;
    destructor Destroy; override;
    { 对外部调用者公布自定义项配置内容 }
    property BillTitleCustomItems : TBillTitleCustomItems read GetBillTitleCustomItems;
    { 外部调用者给对象设置数据源 }
    property BillTitleCustomDataSource : TDataSource read FBillTitleCustomDataSource write SetBillTitleCustomDataSource;
  end;

implementation

uses BillTitleCustomItemForm, un_DM, un_ShowForm, Main, PDWizard,
  BaseBillA, ProdDw, un_ToolsLC;

{ TBillTitleCustomItemClass }

procedure TBillTitleCustomItemClass.BindcxButtonEdits(AItemIndex : Integer);
var
  i : Integer;
  procedure BindcxButtonEdit(AItemIndex : Integer);
  var
    AItemType : Integer;
    AEdit : TcxDBButtonEdit;
  begin
    AItemType := FBillTitleCustomItems[AItemIndex].itemtype;
    AEdit := GetButtonEdit(AItemIndex);
    if AEdit = nil then
      Exit;
    case AItemType of
    0 : { 编辑 }
      begin
        AEdit.Properties.Buttons[0].Visible := False;
        AEdit.Properties.ReadOnly := False;
      end;
    1 : { 参照 }
      begin
        AEdit.Properties.Buttons[0].Visible := True;
        AEdit.Properties.ReadOnly := True;      
      end;
    end;
    { 用tag来标记是哪个自定义项 }
    AEdit.Tag := AItemIndex;
    { 与内置事件绑定 }
    AEdit.Properties.OnButtonClick := PropertiesButtonClick;
  end;
begin
  if AItemIndex = 0 then
  begin
    for i := 1 to Const_BillTitleCustomItem_MAX do
    begin
      BindcxButtonEdit(i);
    end;
  end
  else
  begin
    BindcxButtonEdit(AItemIndex);
  end;
end;

procedure TBillTitleCustomItemClass.CreateCDS;
begin
  if FcdsSQL = nil then
  begin
    FcdsSQL := TClientDataSet.Create(nil);
    FcdsSQL.RemoteServer := DM.Con_SubWork;
    FcdsSQL.ProviderName := 'dsp_Oper';
  end;
end;

constructor TBillTitleCustomItemClass.CreateMy(AOwnerForm: TComponent;
  ABillType: Integer);
begin
  inherited Create(AOwnerForm);
  FBillType := ABillType;
  InitBillTitleCustomItems;
  LoadBillTitleCustomItems;
  BindcxButtonEdits;
end;

procedure TBillTitleCustomItemClass.CustomConfig(AItemIndex : Integer);
var
  frmBillTitleCustomItem: TfrmBillTitleCustomItem;
begin
  frmBillTitleCustomItem := TfrmBillTitleCustomItem.Create(Application);
  with frmBillTitleCustomItem do
  begin
    try
      ItemType := FBillTitleCustomItems[ItemIndex].itemtype;
      ShowModal;
      if ModalResult = mrOK then
      begin
        FBillTitleCustomItems[AItemIndex].itemtype := ItemType; // 现在只能设置类型。
        if SaveBillTitleCustomItems(AItemIndex) then
        begin
          { 保存前，已经更新了本地变量，所以不需要再从数据库获取一次。及时性要求不需要这样高。 }
          {LoadBillTitleCustomItems;}
          BindcxButtonEdits(AItemIndex);
        end;
      end;
    finally
      Free;
    end;
  end;
end;

destructor TBillTitleCustomItemClass.Destroy;
begin
  if FcdsSQL <> nil then
  begin
    FcdsSQL.Close;
    FcdsSQL.Free;
  end;
  inherited;
end;

function TBillTitleCustomItemClass.GetBillTitleCustomItems: TBillTitleCustomItems;
begin
  Result := FBillTitleCustomItems;
end;

function TBillTitleCustomItemClass.GetButtonEdit(
  AItemIndex: Integer): TcxDBButtonEdit;
var
  AEditName : string;
  AEdit : TComponent;
begin
  AEditName := 'edtBillTitleCustomItem' + IntToStr(AItemIndex);
  AEdit := TForm(Owner).FindComponent(AEditName);
  if (AEdit <> nil) and (AEdit is TcxDBButtonEdit) then
    Result := TcxDBButtonEdit(AEdit)
  else
    Result := nil;
end;

procedure TBillTitleCustomItemClass.InitBillTitleCustomItems;
var
  i : Integer;
begin
  for i := 1 to Const_BillTitleCustomItem_MAX do
  begin
    FBillTitleCustomItems[i].itemindex := i;
    FBillTitleCustomItems[i].itemtype := 0;
    FBillTitleCustomItems[i].itemdatasource := 'commoninfo';
    FBillTitleCustomItems[i].itemdatafield := 'u_Remark';
  end;
end;

procedure TBillTitleCustomItemClass.LoadBillTitleCustomItems;
begin
  CreateCDS;
  FcdsSQL.CommandText :=
    'select * from BillTitleCustomItem where billtype = '+IntToStr(FBillType)+' order by ItemIndex';
  FcdsSQL.Open;
  with FcdsSQL do
  begin
    if RecordCount > Const_BillTitleCustomItem_MAX then
    begin
      Exit;
    end;
    First;
    while not Eof do
    begin
      FBillTitleCustomItems[RecNo].itemindex := FieldByName('ItemIndex').AsInteger;
      FBillTitleCustomItems[RecNo].itemtype := FieldByName('itemtype').AsInteger;
      FBillTitleCustomItems[RecNo].itemdatasource := FieldByName('itemdatasource').AsString;
      FBillTitleCustomItems[RecNo].itemdatafield := FieldByName('itemdatafield').AsString;

      Next;
    end;
  end;
end;

procedure TBillTitleCustomItemClass.PropertiesButtonClick(Sender: TObject;
  AButtonIndex: Integer);
begin
  case AButtonIndex of
  0 : Reference(TcxDBButtonEdit(Sender).Tag);
  1 : CustomConfig(TcxDBButtonEdit(Sender).Tag);
  end;
end;

{ 因为现在这里只是针对进货单和销售单，且参照仅针对附加说明，所以先这样处理。 }
procedure TBillTitleCustomItemClass.Reference(AItemIndex : Integer);
var
  szFieldName : string;
begin
  if tclientdataset(BillTitleCustomDataSource.DataSet).ReadOnly then
    Exit;

  fm_main.vpSingleType := 13;

  fm_ProdDw := Tfm_ProdDw.create(application);
  try
    with fm_ProdDw do
    begin
      fm_ProdDw.vpCalltype := 3;

      T1_Showmodal(fm_ProdDw);
      if modalresult = mrok then
      begin
        szFieldName := 'Item' + IntToStr(AItemIndex);
        tclientdataset(BillTitleCustomDataSource.DataSet).Edit;
        tclientdataset(BillTitleCustomDataSource.DataSet).FieldByName(szFieldName).AsString := cds_SingleList.FieldByName('U_Remark').AsString;
        tclientdataset(BillTitleCustomDataSource.DataSet).Post;
      end;
    end;
  finally
    gl_Trans.Info1 := '';
    fm_ProdDw.free;
  end;
end;

function TBillTitleCustomItemClass.SaveBillTitleCustomItems(AItemIndex : Integer): Boolean;
var
  szSQL : string;
  function MakeSaveSQL : string;
  var
    i : Integer;
    szDelete : string;
    szTmp : string;
  begin
    Result := '';
    if AItemIndex = 0 then
    begin
      szDelete := ' delete from BillTitleCustomItem where BillType = '+IntToStr(FBillType);

      for i := 1 to Const_BillTitleCustomItem_MAX do
      begin
        szTmp := ' insert into BillTitleCustomItem (BillType, itemindex, itemtype, itemdatasource, itemdatafield) values (%d,%d,%d,'+Char(39)+'%s'+Char(39)+','+Char(39)+'%s'+Char(39)+')';
        with FBillTitleCustomItems[i] do
          szTmp := Format(szTmp, [FBillType, itemindex, itemtype, itemdatasource, itemdatafield]);

        Result := Result + szTmp ;//+ Char(13)+Char(10);
      end;
    end
    else
    begin
      szDelete := ' delete from BillTitleCustomItem where BillType = '+IntToStr(FBillType) + ' and itemindex =' + IntToStr(AItemIndex);
      szTmp := ' insert into BillTitleCustomItem (BillType, itemindex, itemtype, itemdatasource, itemdatafield) values (%d,%d,%d,'+Char(39)+'%s'+Char(39)+','+Char(39)+'%s'+Char(39)+')';
      with FBillTitleCustomItems[AItemIndex] do
        szTmp := Format(szTmp, [FBillType, AItemIndex, itemtype, itemdatasource, itemdatafield]);
      Result := Result + szTmp ;
    end;

    Result := szDelete + Result;
  end;
begin
  szSQL := MakeSaveSQL;
  FcdsSQL.CommandText := szSQL;
  try
    FcdsSQL.Execute;

    Result := True;
  except
    on e : Exception do
    begin
      Result := False;
      ShowDlg(1, '保存单据表头自定义项设置失败。'+#13+'错误信息：'+#13+e.Message);
    end;
  end;
end;          

procedure TBillTitleCustomItemClass.SetBillTitleCustomDataSource(
  const Value: TDataSource);
begin
  FBillTitleCustomDataSource := Value;
  SetEditDataSource;
end;

procedure TBillTitleCustomItemClass.SetEditDataSource;
var
  i : Integer;
  AEdit : TcxDBButtonEdit;
begin
  for i := 1 to Const_BillTitleCustomItem_MAX do
  begin
    AEdit := GetButtonEdit(i);
    AEdit.DataBinding.DataSource := BillTitleCustomDataSource;
    AEdit.DataBinding.DataField := 'Item'+IntToStr(i);
  end;
end;

end.

此外，对于多账户支付的功能，我也用类似的思路设计了一个类，但是感觉里面比较紊乱，应该能够分得更清晰，降低耦合，增强内聚。请达者指教。谢谢。