bat定时关机

 

@ECHO OFF

title 定时关机

echo ──────────────────────
echo │  [1] 设定关机      │
echo │  [2] 取消定时关机  │
echo │  [3] 退出          │
echo ────────────────────── 
echo 请选择要进行的操作，然后按回车

:choiceONE
set /p flagOne=请选择:
if "%flagOne%"=="1" (
    goto MAIN
) ELSE if "%flagOne%"=="2" (
    Shutdown -a && echo 已经帮你取消了定时关机设置！|| cls & echo 系统没有设置定时关机！
    goto END
)ELSE if "%flagOne%"=="3" (
    goto CLOSE
)ELSE (
    echo 选项非法，请重新选择！
    goto choiceONE
)

:MAIN
set /p num=请输入几分钟后机关：
echo %num%|findstr /be "[0-9]*" >nul && goto SHOW || echo 只能输入数字，请重新输入！ & goto MAIN

:SHOW
echo ──────────────────
echo │    [1] 确认    │
echo │    [2] 重设    │
echo │    [3] 退出    │
echo ────────────────── 
echo 请选择要进行的操作，然后按回车

:CHOICE
set /p flag=请选择:
if "%flag%"=="1" (
    goto START
) ELSE if "%flag%"=="2" (
    goto MAIN
)ELSE if "%flag%"=="3" (
    goto CLOSE
)ELSE (
    echo 选项非法，请重新选择！
    goto CHOICE
)

:START
    set /a time=%num% * 60
    shutdown -s -t %time% -c "设置自动关机成功!" 
    for /l %%i in (%time%,-1,0) do (
    cls
    echo 倒计时数%%i秒后关闭计算机。。。
    ping 127.1 -n 2 >nul
    )
    goto END
    
:CLOSE
    echo 你已经选择放弃定时关机！
    goto END

:END
ECHO [暂停5秒自动关闭...]
ping -n 5 127.0.0.1>nul
@ECHO ON