2007: [Noi2010]海拔

Description

YT市是一个规划良好的城市，城市被东西向和南北向的主干道划分为n×n个区域。简单起见，可以将YT市看作一个正方形，每一个区域也可看作一个正方形。从而，YT城市中包括(n+1)×(n+1)个交叉路口和2n×(n+1)条双向道路（简称道路），每条双向道路连接主干道上两个相邻的交叉路口。下图为一张YT市的地图(n = 2)，城市被划分为2×2个区域，包括3×3个交叉路口和12条双向道路。 小Z作为该市的市长，他根据统计信息得到了每天上班高峰期间YT市每条道路两个方向的人流量，即在高峰期间沿着该方向通过这条道路的人数。每一个交叉路口都有不同的海拔高度值，YT市市民认为爬坡是一件非常累的事情，每向上爬h的高度，就需要消耗h的体力。如果是下坡的话，则不需要耗费体力。因此如果一段道路的终点海拔减去起点海拔的值为h(注意h可能是负数)，那么一个人经过这段路所消耗的体力是max{0, h}（这里max{a, b}表示取a, b两个值中的较大值）。 小Z还测量得到这个城市西北角的交叉路口海拔为0，东南角的交叉路口海拔为1(如上图所示)，但其它交叉路口的海拔高度都无法得知。小Z想知道在最理想的情况下（即你可以任意假设其他路口的海拔高度），每天上班高峰期间所有人爬坡所消耗的总体力和的最小值。
Input

第一行包含一个整数n，含义如上文所示。 接下来4n(n + 1)行，每行包含一个非负整数分别表示每一条道路每一个方向的人流量信息。输入顺序：n(n + 1)个数表示所有从西到东方向的人流量，然后n(n + 1)个数表示所有从北到南方向的人流量，n(n + 1)个数表示所有从东到西方向的人流量，最后是n(n + 1)个数表示所有从南到北方向的人流量。对于每一个方向，输入顺序按照起点由北向南，若南北方向相同时由西到东的顺序给出(参见样例输入)。
Output

仅包含一个数，表示在最理想情况下每天上班高峰期间所有人爬坡所消耗的总体力和（即总体力和的最小值），结果四舍五入到整数。
Sample Input
1

1

2

3

4

5

6

7

8

Sample Output
3

【样例说明】
样例数据见下图。


最理想情况下所有点的海拔如上图所示。

【数据规模】
对于20%的数据：n ≤ 3；

对于50%的数据：n ≤ 15；

对于80%的数据：n ≤ 40；

对于100%的数据：1 ≤ n ≤ 500，0 ≤ 流量 ≤ 1,000,000且所有流量均为整数。

一不小心就看到了是最小割233，然后就想到了最小割构图

因为左上角是0右下角是1，所以我们海拔肯定是0或者1，于是最小割就很明显了，就是他给你的这张图，左上角为源右下角为汇

数据太大所以我们又只能换成对偶图最短路了，可以参考bzoj1001狼与兔子，不过那是无向图，这个是有向图

于是右→下，下→左，左→上，上→右（还成环了233）,跑一遍右上到左下的最短路就行了，直接SPFA有两个点过不去，所以我加了heap

const
    maxn=510;
    inf=1000000000;
var
    first:array[0..maxn*maxn]of longint;
    next,last,w:array[0..maxn*maxn*4]of longint;
    n,tot:longint;
 
function calc(x,y:longint):longint;
begin
    if (x=0) or (y=n+1) then exit(0);
    if (x=n+1) or (y=0) then exit(n*n+1);
    exit((x-1)*n+y);
end;
 
procedure insert(x,y:longint);
begin
    inc(tot);
    last[tot]:=y;
    next[tot]:=first[x];
    first[x]:=tot;
end;
 
var
    q,h,dis:array[0..maxn*maxn]of longint;
    flag:array[0..maxn*maxn]of boolean;
    r:longint;
 
procedure swap(var x,y:longint);
var
    t:longint;
begin
    t:=x;x:=y;y:=t;
end;
 
procedure up(x:longint);
var
    i:longint;
begin
    while x>1 do
        begin
            i:=x>>1;
            if dis[q[x]]<dis[q[i]] then
                begin
                    swap(q[x],q[i]);
                    h[q[x]]:=x;h[q[i]]:=i;
                    x:=i;
                end
            else exit;
        end;
end;
 
procedure down(x:longint);
var
    i:longint;
begin
    i:=x<<1;
    while i<=r do
        begin
            if (i<r) and (dis[q[i+1]]<dis[q[i]]) then inc(i);
            if dis[q[i]]<dis[q[x]] then
                begin
                    swap(q[i],q[x]);
                    h[q[x]]:=x;h[q[i]]:=i;
                    x:=i;i:=x<<1;
                end
            else exit;
        end;
end;
 
procedure delete;
begin
    swap(q[1],q[r]);
    h[q[1]]:=1;
    dec(r);
    down(1);
end;
 
procedure spfa;
var
    i:longint;
begin
    r:=1;q[1]:=0;flag[0]:=true;h[0]:=1;
    for i:=1 to n*n+1 do dis[i]:=inf;
    while r>0 do
        begin
            if q[1]=n*n+1 then break;
            i:=first[q[1]];
            while i<>0 do
                begin
                    if dis[q[1]]+w[i]<dis[last[i]] then
                    begin
                        if not flag[last[i]] then
                        begin
                            inc(r);q[r]:=last[i];h[last[i]]:=r;
                            flag[last[i]]:=true;
                        end;
                        dis[last[i]]:=dis[q[1]]+w[i];up(h[last[i]]);
                    end;
                    i:=next[i];
                end;
            flag[q[1]]:=false;delete;
        end;
end;
 
procedure main;
var
    i,j:longint;
begin
    read(n);
    for i:=1 to 4*n*(n+1) do read(w[i]);
    for i:=0 to n do
        for j:=1 to n do
            insert(calc(i,j),calc(i+1,j));
    for i:=1 to n do
        for j:=0 to n do
            insert(calc(i,j+1),calc(i,j));
    for i:=0 to n do
        for j:=1 to n do
            insert(calc(i+1,j),calc(i,j));
    for i:=1 to n do
        for j:=0 to n do
            insert(calc(i,j),calc(i,j+1));
    spfa;
    writeln(dis[n*n+1]);
end;
 
begin
    main;
end.