邮票面值设计（codevs 1047） 题解

【问题描述】

给定一个信封，最多只允许粘贴N张邮票，计算在给定K（N+K≤40）种邮票的情况下（假定所有的邮票数量都足够），如何设计邮票的面值，能得到最大值MAX，使在1～MAX之间的每一个邮资值都能得到。例如，N=3，K=2，如果面值分别为1分、4分，则在1分～6分之间的每一个邮资值都能得到（当然还有8分、9分和12分）；如果面值分别为1分、3分，则在1分～7分之间的每一个邮资值都能得到。可以验证当N=3，K=2时，7分就是可以得到的连续的邮资最大值，所以MAX=7，面值分别为1分、3分。

【样例输入】

    3 2

【样例输出】

    1 3

    MAX=7

【解题思路】

    本题为NOIP1999第三题，初看感觉挺简单的（不就一个搜索吗，一个一个往上搜就行了啊），但写着写着，就发现出了点问题……

    下面说一说正解。

    首先，我们设定一个数组，用来存放对于某一个值x它所需要的最少邮票数是多少，当某个值所需要的邮票数大于K的时候，就可以不要再往下了（因为再往下就不是连续的了）。

    这样一来就好办了，每一次找出来连续的邮票数最多的时候，就更新最优解。详见代码。

【代码实现】

var a,b,f:array[-1..40] of longint;//f记录用x种邮票所取得的连续的邮票面值的最大值是多少，b是目前来说的最优解，a是最终结果
    v:array[0..10000] of longint;//记录x至少需要多少张邮票
    i,j,n,k:longint;
procedure dfs(x,y:longint);//y是当前能取的最大值，x是当前取第几张
var i,j,z,m:longint;
    ss:array[0..10000] of longint;//方便回溯
begin
 if y<b[x-1] then
  exit;//如果y比在没有这次搜索前的最大值还小，就不需要搜索，肯定不是最优解
 if x>k then
  exit;//已取完k张
 ss:=v;
 for i:=b[x-1]+1 to y+1 do
  begin
   b[x]:=i;//第x张取i
   m:=y;
   j:=0;
   while v[j]<=n do
    begin
     for z:=1 to x do
      if v[j+b[z]]>v[j]+1 then
       v[j+b[z]]:=v[j]+1;//更新面额所需的最少邮票数
     inc(j);
    end;
   while v[m+1]<=n do
    inc(m);//连续能取到的邮票的最大面值
   if (m>f[x])and(x=k) then//如果全部取完了，更新最优值
    a:=b;
   if m>f[x] then//更新取x种邮票的最优值
    f[x]:=m;
   dfs(x+1,m);
   v:=ss;
  end;
end;
begin
 readln(n,k);
 for i:=1 to 10000 do
  v[i]:=maxlongint;//初始化
 dfs(1,0);
 for i:=1 to k do
  write(a[i],' ');
 writeln;
 writeln('MAX=',f[k]);
end.