StringGrid数据导出到Excel

1、控件：

　　StringGrid1: TRzStringGrid;
　　ADOConnection1: TADOConnection;
　　ADOTable1: TADOTable;
　　DataSource1: TDataSource;
　　Button1: TButton;//导出数据
　　Button2: TButton;//连接数据库
　　Button3: TButton;//初始化列表

2、双击连接数据库按钮：

  //使用之前先关闭
  ADOConnection1.Close;
  with ADOConnection1 do
  begin
    ConnectionString :='Provider=SQLOLEDB.1;Password=123;Persist Security Info=True;User ID=sa;Initial Catalog=Test_DBNAME;Data Source=127.0.0.1';
    try
      Connected := True;
      ShowMessage('数据库连接成功!');
    except
      ShowMessage('数据库连接失败!');
    end;
    //登录时不需要在输入密码了
    LoginPrompt := False;
  end;
  with ADOTable1 do
  begin
    //这三个顺序不能乱
    Connection := ADOConnection1;
    TableName := 'TableName';
    Active := True;
  end;  
  DataSource1.DataSet := ADOTable1;

3、双击初始化列表按钮：

  //记得在此过程前声明i，j变量哦
  //初始划列表
  ADOTable1.First;
  StringGrid1.RowCount := ADOTable1.RecordCount + 1;
  StringGrid1.ColCount := ADOTable1.FieldCount + 1;
  for i := 0 to ADOTable1.RecordCount - 1 do
  begin
    for j := 0 to ADOTable1.FieldCount - 1 do
    begin
      StringGrid1.Cells[j + 1, 0] := ADOTable1.Fields.Fields[j].FieldName;
      StringGrid1.Cells[0, i + 1] := IntToStr(i + 1);
      if ADOTable1.Fields.Fields[j].Value = null then
        StringGrid1.Cells[j + 1, i + 1] := ''
      else
        StringGrid1.Cells[j + 1, i + 1] := ADOTable1.Fields.Fields[j].Value;
    end;
    ADOTable1.Next;
  end;
  StringGrid1.FixedCols := 0;

4、新写一个导出数据的过程：

//把他写成了一个过程，这样其他用到这个StringGrid的控件都可以刁永红这个来导出了
procedure TForm6.ExportToExcel(RzStrGrid: TRzStringGrid);
const
  xlNormal = -4143;
var
  i, j, k, l: integer;
  filename: string;
  excel, Vrange: OleVariant;
  savedialog: tsavedialog;
begin
  filename := '';
  if RzStrGrid.RowCount > 65536 then
  begin
    if application.messagebox('需要导出的数据过大，Excel最大只能容纳65536行,是否还要继续？', '询问', mb_yesno + mb_iconquestion) = idno then
      exit;
  end;
  screen.Cursor := crHourGlass;

  try
    excel := CreateOleObject('Excel.Application');
    excel.workbooks.add;
  except
    screen.cursor := crDefault;
    showmessage('无法调用Excel！');
    exit;
  end;
  savedialog := tsavedialog.Create(nil);
  savedialog.Filter := 'Excel文件(*.xls)|*.xls';
  if savedialog.Execute then
  begin
    if FileExists(savedialog.FileName) then
    try
      if application.messagebox('该文件已经存在，要覆盖吗？', '询问', mb_yesno + mb_iconquestion) = idyes then
        DeleteFile(PChar(savedialog.FileName))
      else
      begin
        excel.Quit;
        savedialog.free;
        screen.cursor := crDefault;
        Exit;
      end;
    except
      excel.Quit;
      savedialog.free;
      screen.cursor := crDefault;
      Exit;
    end;
    filename := savedialog.FileName;
  end;
  savedialog.free;
  if filename = '' then
  begin
    excel.Quit;
    screen.cursor := crDefault;
    exit;
  end;
  //设置字体
  excel.Cells.Font.Size := 10;
  //导出数据到Excel
  for i := 0 to RzStrGrid.RowCount - 1 do
  begin
    for j := 0 to RzStrGrid.ColCount - 1 do
    begin
      excel.Cells[i + 1, j + 1] := RzStrGrid.Cells[j, i];
    end;
  end;
  //设置列宽
  excel.ActiveSheet.Columns[3].ColumnWidth := 15;
  //需要合并的单元格
  Vrange := excel.range[excel.cells[RzStrGrid.RowCount + 1, 1], excel.cells[RzStrGrid.RowCount + 1, RzStrGrid.ColCount]];
  Vrange.Select;
  //合并单元格
  Vrange.Merge(True);
  //合并后单元格内容的字体大小
  Vrange.Font.Size := 15;
  Vrange.Font.Bold := True;
  //合并单元格后的背景色
  Vrange.Interior.ColorIndex := 6;
  //最后一行加一个注解
  excel.cells[RzStrGrid.RowCount + 1, 1] := '注意：导出Excel和上一篇文章导出的Excel模板一样，可以进行导入导出';
  //整页的文本全都居中
  excel.columns.HorizontalAlignment := 3;
  try
    //判断文件名后缀是不是.xls
    if copy(filename, length(filename) - 3, 4) <> '.xls' then
      filename := filename + '.xls';
    //保存Excel
    excel.ActiveWorkbook.SaveAs(filename, xlNormal, '', '', False, False);
  except
    excel.Quit;
    screen.cursor := crDefault;
    exit;
  end;
  excel.Visible := true;
  screen.cursor := crDefault;
end;

双击导入数据按钮，来调用导出StringGrid数据的过程：

procedure TForm6.Button1Click(Sender: TObject);
begin
  ExportToExcel(StringGrid1);
end;

好了，这样就可以了