3631: [JLOI2014]松鼠的新家

3631: [JLOI2014]松鼠的新家

Time Limit: 10 Sec  Memory Limit: 128 MB
Submit: 707  Solved: 342
[Submit][Status][Discuss]

Description

松鼠的新家是一棵树，前几天刚刚装修了新家，新家有n个房间，并且有n-1根树枝连接，每个房间都可以相互到达，且俩个房间之间的路线都是唯一的。天哪，他居然真的住在“树”上。松鼠想邀请小熊维尼前来参观，并且还指定一份参观指南，他希望维尼能够按照他的指南顺序，先去a1，再去a2，……，最后到an，去参观新家。

可是这样会导致维尼重复走很多房间，懒惰的维尼不听地推辞。可是松鼠告诉他，每走到一个房间，他就可以从房间拿一块糖果吃。维尼是个馋家伙，立马就答应了。

现在松鼠希望知道为了保证维尼有糖果吃，他需要在每一个房间各放至少多少个糖果。因为松鼠参观指南上的最后一个房间an是餐厅，餐厅里他准备了丰盛的大餐，所以当维尼在参观的最后到达餐厅时就不需要再拿糖果吃了。

Input

第一行一个整数n，表示房间个数

第二行n个整数，依次描述a1-an

接下来n-1行，每行两个整数x，y，表示标号x和y的两个房间之间有树枝相连。

Output

一共n行，第i行输出标号为i的房间至少需要放多少个糖果，才能让维尼有糖果吃。

Sample Input

5
1 4 5 3 2
1 2
2 4
2 3
4 5

Sample Output

1
2
1
2
1

HINT

2<= n <=300000

Source

题解：很明显是树链剖分！！！（HansBug：达成成就——第一棵树链剖分，get！），其实所谓的行走路径就是树链上的区间加法（呵呵呵其实这题里面由于只需要区间加最后求出各个值的和，所以连线段树都不要，干脆一个数组搞定），注意题目中说最后一个点不算，记得减去（HansBug：第一棵树链剖分，代码有点丑= =）

/**************************************************************
    Problem: 3631
    User: HansBug
    Language: Pascal
    Result: Accepted
    Time:2660 ms
    Memory:48396 kb
****************************************************************/
 
type
    point=^node;
    node=record
               g:longint;
               next:point;
    end;
var
   i,j,k,l,m,n,root,tot:longint;
   a:array[0..300005] of point;
   len,son,siz,d,top,e,num,anum,f:array[0..300005] of longint;
   c:array[0..20,0..300005] of longint;
procedure add(x,y:longint);
          var p:point;
          begin
               new(p);p^.g:=y;p^.next:=a[x];a[x]:=p;
          end;
function max(x,y:longint):longint;
         begin
              if x>y then max:=x else max:=y;
         end;
function min(x,y:longint):longint;
         begin
              if x<y then min:=x else min:=y;
         end;
procedure swap(var x,y:longint);
          var z:longint;
          begin
               z:=x;x:=y;y:=z;
          end;
procedure dfs(y,x:longint);
          var p:point;
          begin
               len[x]:=len[y]+1;
               c[0,x]:=y;son[x]:=0;
               siz[x]:=1;
               p:=a[x];
               while p<>nil do
                     begin
                          if p^.g<>y then
                             begin
                                  dfs(x,p^.g);
                                  inc(siz[x],siz[p^.g]);
                                  if (siz[p^.g]>siz[son[x]]) or (son[x]=0) then son[x]:=p^.g;
                             end;
                          p:=p^.next;
                     end;
          end;
procedure dfs2(y,x,z:longint);
          var p:point;
          begin
               top[x]:=z;inc(tot);num[x]:=tot;anum[tot]:=x;
               if son[x]<>0 then dfs2(x,son[x],z);p:=a[x];
               while p<>nil do
                     begin
                          if (p^.g<>y) and (p^.g<>son[x]) then dfs2(x,p^.g,p^.g);
                          p:=p^.next;
                     end;
          end;
procedure addd(x,y,z:longint);
          begin
               inc(d[x],z);
               dec(d[y+1],z);
          end;
function getup(x,y:longint):longint;
         var i:longint;
         begin
              i:=0;
              while y<>0 do
                    begin
                         if odd(y) then x:=c[i,x];
                         inc(i);y:=y div 2;
                    end;
              exit(x);
         end;
function getcom(x,y:longint):longint;
         var i:longint;
         begin
              if len[x]<len[y] then swap(x,y);
              x:=getup(x,len[x]-len[y]);
              if x=y then exit(x);
              for i:=trunc(round(ln(len[x])/ln(2))) downto 0 do
                  if c[i,x]<>c[i,y] then
                     begin
                          x:=c[i,x];
                          y:=c[i,y];
                     end;
              exit(c[0,x]);
         end;
procedure treeadd(x,y:longint);
          var z,i:longint;
          begin
               z:=getcom(x,y);
               repeat
                     if len[top[x]]<len[z] then i:=z else i:=top[x];
                     addd(num[i],num[x],1);
                     if i=z then break;
                     x:=c[0,i];
               until false;
               repeat
                     if len[top[y]]<len[z] then i:=z else i:=top[y];
                     addd(num[i],num[y],1);
                     if i=z then break;
                     y:=c[0,i];
               until false;
               addd(num[z],num[z],-1);
          end;
begin
     readln(n);
     for i:=1 to n do read(e[i]);readln;
     for i:=1 to n do a[i]:=nil;
     for i:=1 to n-1 do
         begin
              readln(j,k);
              add(j,k);add(k,j);
         end;
     fillchar(d,sizeof(d),0);
     root:=1;dfs(0,root);
     dfs2(0,root,root);
     for i:=1 to trunc(round(ln(n)/ln(2)))+1 do
         for j:=1 to n do
             c[i,j]:=c[i-1,c[i-1,j]];
     for i:=1 to n-1 do treeadd(e[i],e[i+1]);
     for i:=2 to n do addd(num[e[i]],num[e[i]],-1);
     l:=0;
     for i:=1 to n do
         begin
              inc(l,d[i]);
              f[anum[i]]:=l;
         end;
     for i:=1 to n do writeln(f[i]);
     readln;
end.