算法模板——线段树3（区间覆盖值+区间求和）

实现功能——1：区间覆盖值；2：区间求和

相比直接的区间加，这个要注重顺序，因为操作有顺序之分。所以这里面的tag应该有个pushup操作（本程序中的ext）

var
   i,j,k,l,m,n,a1,a2,a3,a4:longint;
   a,b,d:array[0..100000] of longint;
function max(x,y:longint):longint;inline;
         begin
              if x>y then max:=x else max:=y;
         end;
function min(x,y:longint):longint;inline;
         begin
              if x<y then min:=x else min:=y;
         end;
procedure ext(z,x,y:longint);inline;
          begin
               if d[z]=0 then exit;
               a[z]:=b[z]*(y-x+1);
               if x<>y then
                  begin
                       b[z*2]:=b[z];d[z*2]:=1;
                       b[z*2+1]:=b[z];d[z*2+1]:=1;
                  end;
               b[z]:=0;d[z]:=0;
          end;
function op(z,x,y,l,r,p:longint):longint;inline;
         var a3,a4:longint;
         begin
              if l>r then exit(0);
              if (x=l) and (y=r) then
                 begin
                      if d[z]=1 then a[z]:=b[z]*(r-l+1);
                      d[z]:=1;b[z]:=p;
                      exit(p*(r-l+1)-a[z]);
                 end;
              ext(z,x,y);
              a3:=op(z*2,x,(x+y) div 2,l,min(r,(x+y) div 2),p);
              a4:=op(z*2+1,(x+y) div 2+1,y,max((x+y) div 2+1,l),r,p);
              a[z]:=a[z]+a3+a4;
              exit(a3+a4);
         end;
function cal(z,x,y,l,r:longint):longint;inline;
         begin
              if l>r then exit(0);
              if d[z]=1 then exit(b[z]*(r-l+1));
              if (x=l) and (y=r) then exit(a[z]);
              exit(cal(z*2,x,(x+y) div 2,l,min(r,(x+y) div 2))+cal(z*2+1,(x+y) div 2+1,y,max(l,(x+y) div 2+1),r));
         end;
procedure built(z,x,y:longint);inline;
          begin
               if x=y then
                  read(a[z])
               else
                   begin
                        built(z*2,x,(x+y) div 2);
                        built(z*2+1,(x+y) div 2+1,y);
                        a[z]:=a[z*2]+a[z*2+1];
                   end;
               b[z]:=0;d[z]:=0;
          end;
begin
     readln(n,m);
     built(1,1,n);
     readln;
     for i:=1 to m do
         begin
              read(j);
              case j of
                   1:begin
                          readln(a1,a2,a3);
                          op(1,1,n,a1,a2,a3);
                   end;
                   2:begin
                          readln(a1,a2);
                          writeln(cal(1,1,n,a1,a2));
                   end;
                   else halt;
              end;
         end;
end.