3038: 上帝造题的七分钟2

3038: 上帝造题的七分钟2

Time Limit: 3 Sec  Memory Limit: 128 MB
Submit: 662  Solved: 302
[Submit][Status]

Description

XLk觉得《上帝造题的七分钟》不太过瘾，于是有了第二部。
"第一分钟，X说，要有数列，于是便给定了一个正整数数列。
第二分钟，L说，要能修改，于是便有了对一段数中每个数都开平方(下取整)的操作。
第三分钟，k说，要能查询，于是便有了求一段数的和的操作。
第四分钟，彩虹喵说，要是noip难度，于是便有了数据范围。
第五分钟，诗人说，要有韵律，于是便有了时间限制和内存限制。
第六分钟，和雪说，要省点事，于是便有了保证运算过程中及最终结果均不超过64位有符号整数类型的表示范围的限制。
第七分钟，这道题终于造完了，然而，造题的神牛们再也不想写这道题的程序了。"
——《上帝造题的七分钟·第二部》
所以这个神圣的任务就交给你了。

Input

第一行一个整数n，代表数列中数的个数。
第二行n个正整数，表示初始状态下数列中的数。
第三行一个整数m，表示有m次操作。
接下来m行每行三个整数k,l,r，k=0表示给[l,r]中的每个数开平方(下取整)，k=1表示询问[l,r]中各个数的和。

Output

对于询问操作，每行输出一个回答。

Sample Input

10
1 2 3 4 5 6 7 8 9 10
5
0 1 10
1 1 10
1 1 5
0 5 8
1 4 8

Sample Output

19
7
6

HINT

1：对于100%的数据，1<=n<=100000，1<=l<=r<=n，数列中的数大于0，且不超过1e12。

2：数据不保证L<=R 若L>R，请自行交换L,R，谢谢！

Source

Poetize4

题解：拿到此题我有些懵了——要是说加法乘法的话，至少还能通过标记来进行整个区间的维护，可是这个怎么办？我只好尝试了下暴力修改，然后又突然想到了一个问题——当某个点的值原来就是0或者1时，开方操作将无法改变其大小——这样就有了一个优化，只要某个区间内全部为0或者1，则可以在修改操作时无视之，对于区间这一性质如何识别，则只要另立一个标记，只要它的两个子树都有了标记，则它也被标记，这个向来不难维护。

然后我就这么Submit了一下，结果50分TT，查了20多分钟才发现题目中不保证L<=R（HansBug：TT phile：话说你为何总是那么充满喜剧色彩。。。），然后就Accept了，再然后就没有然后了^_^(难得代码小于100行不容易啊)

var
   i,j,k,l,m,n:longint;
   a,b,c:array[0..1000000] of int64;
procedure swap(var x,y:longint);inline;
          var z:longint;
          begin
               z:=x;x:=y;y:=z;
          end;
function max(x,y:longint):longint;inline;
         begin
              if x>y then max:=x else max:=y;
         end;
function min(x,y:longint):longint;inline;
         begin
              if x<y then min:=x else min:=y;
         end;
procedure built(z,x,y:longint);inline;
          begin
               if x=y then
                  begin
                       a[z]:=c[x];
                       if a[z]<=1 then b[z]:=1 else b[z]:=0;
                  end
               else
                   begin
                        built(z*2,x,(x+y) div 2);
                        built(z*2+1,(x+y) div 2+1,y);
                        a[z]:=a[z*2]+a[z*2+1];
                        if (b[z*2]=1) and (b[z*2+1]=1) then b[z]:=1 else b[z]:=0;
                   end;
          end;
function op(z,x,y,l,r:longint):int64;inline;
         var
            a1,a2,a3:int64;
         begin
              if l>r then exit(0);
              if (x=l) and (y=r) then if b[z]=1 then exit(0);
              if (x=y) then
                 begin
                      a1:=a[z];
                      a[z]:=trunc(sqrt(a[z]));
                      if a[z]<=1 then b[z]:=1;
                      exit(a[z]-a1);
                 end;
              a2:=op(z*2,x,(x+y) div 2,l,min(r,(x+y) div 2));
              a3:=op(z*2+1,(x+y) div 2+1,y,max(l,(x+y) div 2+1),r);
              a[z]:=a[z]+a2+a3;
              if (b[z*2]=1) and (b[z*2+1]=1) then b[z]:=1;
              exit(a2+a3);
         end;
function cal(z,x,y,l,r:longint):int64;inline;
         begin
              if l>r then exit(0);
              if (x=l) and (y=r) then exit(a[z]);
              exit(cal(z*2,x,(x+y) div 2,l,min(r,(x+y) div 2))+cal(z*2+1,(x+y) div 2+1,y,max(l,(x+y) div 2+1),r));
         end;
begin
     readln(n);
     for i:=1 to n do read(c[i]);
     readln;
     built(1,1,n);
     readln(m);
     for i:=1 to m do
         begin
              readln(j,k,l);
              if k>l then swap(k,l);
              case j of
                   0:op(1,1,n,k,l);
                   1:writeln(cal(1,1,n,k,l));
              end;
         end;
     readln;
end.