JZOJ_4735. 最小圈 (Standard IO)

Description

对于一张有向图，要你求图中最小圈的平均值最小是多少，即若一个圈经过k个节点，那么一个圈的平均值为圈上k条边权的和除以k，现要求其中的最小值

Input

第一行2个正整数，分别为n和m
   以下m行，每行3个数，表示边连接的信息

Output

一行一个数，表示最小圈的值。你的答案被视为正确当且仅当与标准答案的绝对误差不超过1e-5

Solution

新思想：分数规划，将求值问题变成可行性判断问题。

然后要利用深搜版的 SPFA或者dfs，用于判负环，来求可行性，如果是宽搜版的会被卡 TLE。

代码

type
  arr=record
    y,next:longint;
    w:real;
  end;
var
  bo:boolean;
  n,m,nm:longint;
  a:array [0..10001] of arr;
  d:array [0..3001] of real;
  ls,v:array [0..3001] of longint;
procedure add(x,y:longint;z:real);
begin
  inc(nm);
  a[nm].y:=y; a[nm].w:=z;
  a[nm].next:=ls[x]; ls[x]:=nm;
end;

procedure init;
var
  i,x,y:longint;
  z:real;
begin
  readln(n,m);
  nm:=0;
  for i:=1 to m do
    begin
      readln(x,y,z);
      add(x,y,z);
    end;
end;

procedure dfs(x:longint;mid:real);
var
  i:longint;
begin
  v[x]:=1; i:=ls[x];
  while i<>0 do
    with a[i] do
      begin
        if d[x]+w-mid<d[y] then
          begin
            if v[y]=1 then
              begin
                bo:=true;
                exit;
              end;
            d[y]:=d[x]+w-mid;
            dfs(y,mid);
            if bo then exit;
          end;
        i:=next;
      end;
  v[x]:=0;
end;

function pd(mid:real):boolean;
var
  i:longint;
begin
  for i:=1 to n do
    begin
      d[i]:=0; v[i]:=0;
    end;
  for i:=1 to n do
    begin
      bo:=false;
      dfs(i,mid);
      if bo then exit(true);
    end;
  exit(false);
end;

procedure main;
var
  l,r,mid:real;
begin
  l:=-100000; r:=100000;
  while r-l>=0.0000001 do
    begin
      mid:=(l+r)/2;
      if pd(mid) then r:=mid
                 else l:=mid;
    end;
  writeln(mid:0:6);
end;

begin
  init;
  main;
end.