BZOJ1196: [HNOI2006]公路修建问题

1196: [HNOI2006]公路修建问题

Time Limit: 10 Sec  Memory Limit: 162 MB
Submit: 1107  Solved: 583
[Submit][Status]

Description

OI island是一个非常漂亮的岛屿,自开发以来,到这儿来旅游的人很多。然而，由于该岛屿刚刚开发不久，所以那里的交通情况还是很糟糕。所以，OIER Association组织成立了，旨在建立OI island的交通系统。 OI island有n个旅游景点，不妨将它们从1到n标号。现在，OIER Association需要修公路将这些景点连接起来。一条公路连接两个景点。公路有，不妨称它们为一级公路和二级公路。一级公路上的车速快，但是修路的花费要大一些。 OIER Association打算修n-1条公路将这些景点连接起来（使得任意两个景点之间都会有一条路径）。为了保证公路系统的效率, OIER Association希望在这n-1条公路之中,至少有k条(0≤k≤n-1)一级公路。OIER Association也不希望为一条公路花费的钱。所以，他们希望在满足上述条件的情况下，花费最多的一条公路的花费尽可能的少。而你的任务就是，在给定一些可能修建的公路的情况下，选择n-1条公路，满足上面的条件。

Input

第一行有三个数n(1≤n≤10000),k(0≤k≤n-1),m(n-1≤m≤20000)，这些数之间用空格分开。 N和k如前所述，m表示有m对景点之间可以修公路。以下的m-1行，每一行有4个正整数a,b,c1,c2 （1≤a,b≤n,a≠b,1≤c2≤c1≤30000）表示在景点a与b 之间可以修公路,如果修一级公路,则需要c1的花费,如果修二级公路,则需要c2的花费。

Output

一个数据，表示花费最大的公路的花费。

Sample Input

10 4 20
3 9 6 3
1 3 4 1
5 3 10 2
8 9 8 7
6 8 8 3
7 1 3 2
4 9 9 5
10 8 9 1
2 6 9 1
6 7 9 8
2 6 2 1
3 8 9 5
3 2 9 6
1 6 10 3
5 6 3 1
2 7 6 1
7 8 6 2
10 9 2 1
7 1 10 2

Sample Output

5

HINT

 

Source

题解：

这种最大值最小的一般用二分。

判断是否可行我们可以利用并查集看是否能选出n-1条边

如何选呢？我们可以按c1值排序，从前往后扫

如果该边c1<=mid 或者 c1>mid and c2<=mid and tot>=k 也就是说如果可建一级公路就建，否则不能建一级公路，但可能能建二级公路，

但建二级公路的前提是已经建够了k条一级公路，否则后面c1值越来越大，更不可能建够k条一级公路

代码：

const maxm=20000+1000;
var  a,b,c,d,fa:array[0..maxm] of longint;
     i,n,m,k,l,r,mid:longint;
procedure swap(var x,y:longint);
 var t:longint;
   begin
   t:=x;x:=y;y:=t;
   end;
procedure sort(l,r:longint);
 var i,j,x,y:longint;
 begin
 i:=l;j:=r;x:=c[(i+j)>>1];
 repeat
  while c[i]<x do inc(i);
  while c[j]>x do dec(j);
  if i<=j then
   begin
   swap(a[i],a[j]);swap(b[i],b[j]);
   swap(c[i],c[j]);swap(d[i],d[j]);
   inc(i);dec(j);
   end;
 until i>j;
 if i<r then sort(i,r);
 if j>l then sort(l,j);
 end;
procedure init;
 begin
   readln(n,k,m);dec(m);
   for i:=1 to m do readln(a[i],b[i],c[i],d[i]);
 end;
function find(x:longint):longint;
 begin
 if fa[x]<>x then fa[x]:=find(fa[x]);
 exit(fa[x]);
 end;

function test(x:longint):boolean;
 var i,j,cnt,tot:longint;
 begin
 for i:=1 to n do fa[i]:=i;cnt:=0;tot:=0;
 j:=1;
 while (j<=m) do
   begin
     while (find(a[j])=find(b[j])) and (j<m) do inc(j);
     if find(a[j])=find(b[j]) then break;
     if (c[j]<=x) or ((c[j]>x) and (d[j]<=x) and (tot>=k)) then
       begin
        inc(cnt);fa[find(a[j])]:=find(b[j]);
        if c[j]<=x then inc(tot);
       end;
     inc(j);
   end;
 exit(cnt=n-1);
 end;
procedure main;
 begin
   sort(1,m);
   l:=0;r:=30000;
   while l<r do
    begin
      mid:=(l+r)>>1;
      if test(mid) then r:=mid else l:=mid+1;
    end;
   writeln(l);
 end;

begin
  assign(input,'input.txt');assign(output,'output.txt');
  reset(input);rewrite(output);
  init;
  main;
  close(input);close(output);
end.