最小生成树计数（matrix tree矩阵树定理）

Matrix-Tree 定理是解决生成树计数问题最有力的武器之一。它首先于 1847 年被Kirchhoff 证明。 在介绍定理之前， 我们首先明确几个概念： 

1、 G 的度数矩阵 D[G]是一个 n*n 的矩阵， 并且满足： 当 i≠j 时,dij=0；当 i=j时， dij 等于 vi 的度数。

2、 G 的邻接矩阵 A[G]也是一个 n*n 的矩阵， 并且满足： 如果 vi、 vj 之间有边直接相连，则 aij=1，否则为 0。 

我们定义 G 的 Kirchhoff 矩阵(也称为拉普拉斯算子)C[G]为 C[G]=D[G]-A[G]，则 Matrix-Tree 定理可以描述为：

　　G 的所有不同的生成树的个数等于其 Kirchhoff矩阵 C[G]任何一个 n-1 阶主子式的行列式的绝对值。

　　　　所谓 n-1 阶主子式，就是对于 r(1≤r≤n)，将 C[G]的第 r 行、第 r 列同时去掉后得到的新矩阵，用 Cr[G]表示。 

证明略

[HEOI2015] 小z的房间

Description

你突然有了一个大房子，房子里面有一些房间。事实上，你的房子可以看做是一个包含n*m个格子的格状矩形，每个格子是一个房间或者是一个柱子。在一开始的时候，相邻的格子之间都有墙隔着。

你想要打通一些相邻房间的墙，使得所有房间能够互相到达。在此过程中，你不能把房子给打穿，或者打通柱子（以及柱子旁边的墙）。同时，你不希望在房子中有小偷的时候会很难抓，所以你希望任意两个房间之间都只有一条通路。现在，你希望统计一共有多少种可行的方案。

Input

第一行两个数分别表示n和m。

接下来n行，每行m个字符，每个字符都会是’.’或者’*’，其中’.’代表房间，’*’代表柱子。

Output

 一行一个整数，表示合法的方案数 Mod 10^9

Sample Input

3 3
...
...
.*.

Sample Output

15

HINT

对于前100%的数据，n,m<=9

建模后跑基尔霍夫行列式即可，注意减法取模问题。

const mo=1000000000;
var
    n,m,i,j,tot,cnt                            :longint;
    map                                        :array[0..10,0..10] of char;
    num                                        :array[0..10,0..10] of longint;
    con                                        :array[0..105,0..105] of longint;
    g                                        :array[0..105,0..105] of int64;
    
procedure swap(var x,y:int64);
var
    z                                        :int64;
begin
    z:=x;
    x:=y;
    y:=z;
end;
    
function det():int64;
var
    i,j,k                                    :longint;
    ret,tt                                    :int64;
begin
    for i:=1 to tot do
    for j:=1 to tot do g[i,j]:=(g[i,j]+mo) mod mo;
    ret:=1;
    for i:=2 to tot do
    begin
        for j:=i+1 to tot do
        begin
            while g[j,i]<>0 do
            begin
                tt:=g[i,i] div g[j,i];
                for k:=i to tot do g[i,k]:=((g[i,k]-(tt*g[j,k]) mod mo)+mo) mod mo;
                for k:=i to tot do swap(g[i,k],g[j,k]);
                ret:=-ret;
            end;
        end;
        if g[i,i]=0 then exit(0);
        ret:=(ret*g[i,i]) mod mo;
    end;
    exit((ret+mo)mod mo)
end;
    
begin
    readln(n,m);
    for i:=1 to n do
    begin
        for j:=1 to m do read(map[i,j]);
        readln;
    end;
    for i:=1 to n do
    for j:=1 to m do 
    begin
        if map[i,j]='*' then continue;
        inc(tot);
        num[i,j]:=tot;
    end;
    for i:=1 to n do
    for j:=1 to m do
    begin
        if map[i,j]='*' then continue;
        if (i>1) and (map[i-1,j]<>'*') then con[num[i,j],num[i-1,j]]:=1;
        if (i<n) and (map[i+1,j]<>'*') then con[num[i,j],num[i+1,j]]:=1;
        if (j>1) and (map[i,j-1]<>'*') then con[num[i,j],num[i,j-1]]:=1;
        if (j<m) and (map[i,j+1]<>'*') then con[num[i,j],num[i,j+1]]:=1;
    end;
    for i:=1 to tot do
    begin
        cnt:=0;
        for j:=1 to tot do
        begin
            if i=j then continue;
            if (con[i,j]=1) then
            begin
                inc(cnt);
                g[i,j]:=-1;
            end;
        end;
        g[i,i]:=cnt;
    end;
    writeln(det());
end.