linux awk命令详解

简介

awk是一个强大的文本分析工具，相对于grep的查找，sed的编辑，awk在其对数据分析并生成报告时，显得尤为强大。简单来说awk就是把文件逐行的读入，以空格为默认分隔符将每行切片，切开的部分再进行各种分析处理。

awk有3个不同版本: awk、nawk和gawk，未作特别说明，一般指gawk，gawk 是 AWK 的 GNU 版本。

awk其名称得自于它的创始人 Alfred Aho 、Peter Weinberger 和 Brian Kernighan 姓氏的首个字母。实际上 AWK 的确拥有自己的语言： AWK 程序设计语言 ， 三位创建者已将它正式定义为“样式扫描和处理语言”。它允许您创建简短的程序，这些程序读取输入文件、为数据排序、处理数据、对输入执行计算以及生成报表，还有无数其他的功能。

使用方法

awk '{pattern + action}' {filenames}

尽管操作可能会很复杂，但语法总是这样，其中 pattern 表示 AWK 在数据中查找的内容，而 action 是在找到匹配内容时所执行的一系列命令。花括号（{}）不需要在程序中始终出现，但它们用于根据特定的模式对一系列指令进行分组。 pattern就是要表示的正则表达式，用斜杠括起来。

awk语言的最基本功能是在文件或者字符串中基于指定规则浏览和抽取信息，awk抽取信息后，才能进行其他文本操作。完整的awk脚本通常用来格式化文本文件中的信息。

通常，awk是以文件的一行为处理单位的。awk每接收文件的一行，然后执行相应的命令，来处理文本。

调用awk

有三种方式调用awk

1.命令行方式
awk [-F  field-separator]  'commands'  input-file(s)
其中，commands 是真正awk命令，[-F域分隔符]是可选的。 input-file(s) 是待处理的文件。
在awk中，文件的每一行中，由域分隔符分开的每一项称为一个域。通常，在不指名-F域分隔符的情况下，默认的域分隔符是空格。

2.shell脚本方式
将所有的awk命令插入一个文件，并使awk程序可执行，然后awk命令解释器作为脚本的首行，一遍通过键入脚本名称来调用。
相当于shell脚本首行的：#!/bin/sh
可以换成：#!/bin/awk

3.将所有的awk命令插入一个单独文件，然后调用：
awk -f awk-script-file input-file(s)
其中，-f选项加载awk-script-file中的awk脚本，input-file(s)跟上面的是一样的。

 本章重点介绍命令行方式。

入门实例

假设last -n 5的输出如下

[root@www ~]# last -n 5 <==仅取出前五行
root     pts/1   192.168.1.100  Tue Feb 10 11:21   still logged in
root     pts/1   192.168.1.100  Tue Feb 10 00:46 - 02:28  (01:41)
root     pts/1   192.168.1.100  Mon Feb  9 11:41 - 18:30  (06:48)
dmtsai   pts/1   192.168.1.100  Mon Feb  9 11:41 - 11:41  (00:00)
root     tty1                   Fri Sep  5 14:09 - 14:10  (00:01)

如果只是显示最近登录的5个帐号

#last -n 5 | awk  '{print $1}'
root
root
root
dmtsai
root

awk工作流程是这样的：读入有' '换行符分割的一条记录，然后将记录按指定的域分隔符划分域，填充域，$0则表示所有域,$1表示第一个域,$n表示第n个域。默认域分隔符是"空白键" 或 "[tab]键",所以$1表示登录用户，$3表示登录用户ip,以此类推。

如果只是显示/etc/passwd的账户

#cat /etc/passwd |awk  -F ':'  '{print $1}'  
root
daemon
bin
sys

这种是awk+action的示例，每行都会执行action{print $1}。

-F指定域分隔符为':'。

如果只是显示/etc/passwd的账户和账户对应的shell,而账户与shell之间以tab键分割

#cat /etc/passwd |awk  -F ':'  '{print $1"	"$7}'
root    /bin/bash
daemon  /bin/sh
bin     /bin/sh
sys     /bin/sh

如果只是显示/etc/passwd的账户和账户对应的shell,而账户与shell之间以逗号分割,而且在所有行添加列名name,shell,在最后一行添加"blue,/bin/nosh"。

cat /etc/passwd |awk  -F ':'  'BEGIN {print "name,shell"}  {print $1","$7} END {print "blue,/bin/nosh"}'
name,shell
root,/bin/bash
daemon,/bin/sh
bin,/bin/sh
sys,/bin/sh
....
blue,/bin/nosh

awk工作流程是这样的：先执行BEGING，然后读取文件，读入有/n换行符分割的一条记录，然后将记录按指定的域分隔符划分域，填充域，$0则表示所有域,$1表示第一个域,$n表示第n个域,随后开始执行模式所对应的动作action。接着开始读入第二条记录······直到所有的记录都读完，最后执行END操作。

搜索/etc/passwd有root关键字的所有行

#awk -F: '/root/' /etc/passwd
root:x:0:0:root:/root:/bin/bash

这种是pattern的使用示例，匹配了pattern(这里是root)的行才会执行action(没有指定action，默认输出每行的内容)。

搜索支持正则，例如找root开头的: awk -F: '/^root/' /etc/passwd

搜索/etc/passwd有root关键字的所有行，并显示对应的shell

# awk -F: '/root/{print $7}' /etc/passwd             
/bin/bash

 这里指定了action{print $7}

awk内置变量

awk有许多内置变量用来设置环境信息，这些变量可以被改变，下面给出了最常用的一些变量。

ARGC               命令行参数个数
ARGV               命令行参数排列
ENVIRON            支持队列中系统环境变量的使用
FILENAME           awk浏览的文件名
FNR                浏览文件的记录数
FS                 设置输入域分隔符，等价于命令行 -F选项
NF                 浏览记录的域的个数
NR                 已读的记录数
OFS                输出域分隔符
ORS                输出记录分隔符
RS                 控制记录分隔符

 此外,$0变量是指整条记录。$1表示当前行的第一个域,$2表示当前行的第二个域,......以此类推。

统计/etc/passwd:文件名，每行的行号，每行的列数，对应的完整行内容:

#awk  -F ':'  '{print "filename:" FILENAME ",linenumber:" NR ",columns:" NF ",linecontent:"$0}' /etc/passwd
filename:/etc/passwd,linenumber:1,columns:7,linecontent:root:x:0:0:root:/root:/bin/bash
filename:/etc/passwd,linenumber:2,columns:7,linecontent:daemon:x:1:1:daemon:/usr/sbin:/bin/sh
filename:/etc/passwd,linenumber:3,columns:7,linecontent:bin:x:2:2:bin:/bin:/bin/sh
filename:/etc/passwd,linenumber:4,columns:7,linecontent:sys:x:3:3:sys:/dev:/bin/sh

使用printf替代print,可以让代码更加简洁，易读

 awk  -F ':'  '{printf("filename:%10s,linenumber:%s,columns:%s,linecontent:%s
",FILENAME,NR,NF,$0)}' /etc/passwd

print和printf

awk中同时提供了print和printf两种打印输出的函数。

其中print函数的参数可以是变量、数值或者字符串。字符串必须用双引号引用，参数用逗号分隔。如果没有逗号，参数就串联在一起而无法区分。这里，逗号的作用与输出文件的分隔符的作用是一样的，只是后者是空格而已。

printf函数，其用法和c语言中printf基本相似,可以格式化字符串,输出复杂时，printf更加好用，代码更易懂。

 awk编程

 变量和赋值

除了awk的内置变量，awk还可以自定义变量。

下面统计/etc/passwd的账户人数

awk '{count++;print $0;} END{print "user count is ", count}' /etc/passwd
root:x:0:0:root:/root:/bin/bash
......
user count is  40

count是自定义变量。之前的action{}里都是只有一个print,其实print只是一个语句，而action{}可以有多个语句，以;号隔开。

这里没有初始化count，虽然默认是0，但是妥当的做法还是初始化为0:

awk 'BEGIN {count=0;print "[start]user count is ", count} {count=count+1;print $0;} END{print "[end]user count is ", count}' /etc/passwd
[start]user count is  0
root:x:0:0:root:/root:/bin/bash
...
[end]user count is  40

统计某个文件夹下的文件占用的字节数

ls -l |awk 'BEGIN {size=0;} {size=size+$5;} END{print "[end]size is ", size}'
[end]size is  8657198

如果以M为单位显示:

ls -l |awk 'BEGIN {size=0;} {size=size+$5;} END{print "[end]size is ", size/1024/1024,"M"}' 
[end]size is  8.25889 M

注意，统计不包括文件夹的子目录。

条件语句

 awk中的条件语句是从C语言中借鉴来的，见如下声明方式：

if (expression) {
    statement;
    statement;
    ... ...
}

if (expression) {
    statement;
} else {
    statement2;
}

if (expression) {
    statement1;
} else if (expression1) {
    statement2;
} else {
    statement3;
}

统计某个文件夹下的文件占用的字节数,过滤4096大小的文件(一般都是文件夹):

ls -l |awk 'BEGIN {size=0;print "[start]size is ", size} {if($5!=4096){size=size+$5;}} END{print "[end]size is ", size/1024/1024,"M"}' 
[end]size is  8.22339 M

循环语句

awk中的循环语句同样借鉴于C语言，支持while、do/while、for、break、continue，这些关键字的语义和C语言中的语义完全相同。

数组

  因为awk中数组的下标可以是数字和字母，数组的下标通常被称为关键字(key)。值和关键字都存储在内部的一张针对key/value应用hash的表格里。由于hash不是顺序存储，因此在显示数组内容时会发现，它们并不是按照你预料的顺序显示出来的。数组和变量一样，都是在使用时自动创建的，awk也同样会自动判断其存储的是数字还是字符串。一般而言，awk中的数组用来从记录中收集信息，可以用于计算总和、统计单词以及跟踪模板被匹配的次数等等。

显示/etc/passwd的账户

awk -F ':' 'BEGIN {count=0;} {name[count] = $1;count++;}; END{for (i = 0; i < NR; i++) print i, name[i]}' /etc/passwd
0 root
1 daemon
2 bin
3 sys
4 sync
5 games
......

这里使用for循环遍历数组

awk编程的内容极多，这里只罗列简单常用的用法，更多请参考 http://www.gnu.org/software/gawk/manual/gawk.html

一、RS 与 ORS 差在哪

  我们经常会说，awk是基于行列操作文本的，但如何定义“行”呢？这就是RS的作用。
  默认情况下，RS的值是 。下面通过实例来理解下RS。 
echo '1a2a3a4a5' | awk '{print $1}'

1a2a3a4a5

echo '1a2a3a4a5' | awk 'BEGIN{RS="a"}{print $1}'

1

2

3

4

5
我们可以看到，在更改了RS的值后，awk定义的行已经不是我们实际意义中的行了。
  上面RS固定的字符串，RS也可以定义为正则表达式。 
echo '1ab2bc3cd4de5' | awk 'BEGIN{RS="[a-z]+"}{print $1,RS,RT}'

1 [a-z]+ ab

2 [a-z]+ bc

3 [a-z]+ cd

4 [a-z]+ de

5 [a-z]+ 
当我们将RS设置为正则表达式的时候，RT这个变量就有作用了，RS的值始终为我们设定的正则，RT的值则是这个正则实际匹配到的内容。

如果RS被设置为空，那么awk会将连续的空行作为行分隔符，与RS设置成" +"有什么区别？？？
  1、忽略文件开头和结尾的空行。且文件不以记录分隔符结束，即最后不是空行，会将最后一个记录的尾 去掉
  2、不设置RT变量（测试未发现规律，暂时认为RT变量不可用）
  3、影响FS变量

  总结下RS的3种情况：
  1) 非空字符串
     以固定字符串作为行分隔符，同时设置变量RT为固定字符串
  2) 正则表达式
     以正则表达式作为行分隔符，同时设置变量RT为正则表达式实际匹配到的字符串
  3) 空字符
     以连续的空行作为行分隔符，如果FS为单个字符，会将 强制加入到FS变量中

  理解了RS，再来理解ORS就简单了。RS是awk读取文件时的行分隔符，ORS则是awk输出时的行结束符。
  更简单的讲，就是awk在输出时，会在每行记录后面增加一个ORS变量所设定的值。
  ORS的值只能设定为字符串，默认情况下，ORS的值是  
seq 5 | awk '{print $0}'

1

2

3

4

5

seq 5 | awk 'BEGIN{ORS="a"}{print $0}'

1a2a3a4a5a
我们平常用的 print $0 等价于 printf $0 ORS

二、FS 与 OFS 差在哪

  RS是awk用来定义“行”的，那么FS就是awk用来定义“列”的。
  设置变量 FS 与使用 -F 参数是一样的。 
echo '1,2' | awk -F , '{print $1}'

1

echo '1,2' | awk 'BEGIN{FS=","}{print $1}'

1
与 RS 类似，FS 同样可以设置为正则表达式 
echo '1ab2bc3cd4de5' | awk 'BEGIN{FS="[a-z]+"}{print $1,$2,$5}'

1 2 5
FS 有1个特例，就是将FS设置为一个空格，FS=" " ，这也是FS的默认值 
1.In the special case that FS is a single space, fields are separated by runs of spaces and/or tabs and/or newlines.
此时，awk会将连续的 空格 或 制表符( ) 或 换行符( ) 作为列的分隔符
  那么，FS=" " 与 FS="[ ]+" 有区别么？？？
  答案是肯定的 
echo ' 1 2' | awk 'BEGIN{FS=" "}{print $1}'

1

echo ' 1 2' | awk 'BEGIN{FS="[ ]+"}{print $1}'

当FS=" "时，awk会自动去掉行首和行尾的 空格 或 制表符( ) 或 换行符( )，但FS="[ ]+"是不会的
  同样，FS也可以设置为空 
echo '123' | awk 'BEGIN{FS=""}{print $1,$2}'

1 2
当FS被设置为空字符串的时候，awk会将一行记录的每个字符做为单独的一列
  类似的，当我们想以固定的长度来分隔列的时候，可以使用 FIELDWIDTHS 来代替 FS
  例如，一行记录的前3个字符作为第一列，接下来的2个字符作为第二列，接下来的4个字符作为第三列 
echo '123456789' | awk 'BEGIN{FIELDWIDTHS="3 2 4"}{print $1,$2,$3}'

123 45 6789

echo '123456789' | awk 'BEGIN{FIELDWIDTHS="3 2 3"}{print $1,$2,$3}'

123 45 678

 echo '123456789' | awk 'BEGIN{FIELDWIDTHS="3 2 5"}{print $1,$2,$3}'

123 45 6789
如果定义的长度小于实际的长度，awk会截断，如果大于实际长度，则以实际长度为准。

  总结下FS的4种情况：
  1) 非空字符串
     以固定字符串作为列分隔符
  2) 正则表达式
     以正则表达式作为列分隔符
  3) 单个空格
     以连续的 空格 或 制表符( ) 或 换行符( )作为列分隔符
  4) 空字符
     以每个字符做为单独的一列

  接下来我们来看看上节提到的问题：
  当 RS="" 时，会将 强制加入到FS变量中 
cat urfile

1

a

 

2

a

 

 

3

awk -v RS="" '{print "#" $0 "#"}' urfile

#1

a#

#2

a#

#3#

awk -F "b" -v RS="" '{print $1}' urfile

1

2

3

awk -F "c" -v RS="" '{print $1}' urfile

1

2

3

awk -F "c" -v RS=" +" '{print "#" $1 "#"}' urfile

#1

a#

#2

a#

#3

#
如果FS为单个字符， 始终存在在 FS 中，而 RS=" +" 则不会。

  了解的 FS ，我们来看看 OFS ，FS是awk读入记录时的列分隔符，OFS则是awk输出时的列分隔符。
  我们平时使用的 print $1,$2 等价于 print $1 OFS $2 
echo '1 2' | awk -v OFS="|" '{print $1,$2}'

1|2

echo '1 2' | awk -v OFS="|" '{print $1 OFS $2}'

1|2
如果一行记录有很多列，同时想改变输出的分隔符，print $1,$2,$3 ... 启不是很麻烦？
  当然有简单的方法： 
echo '1 2 3 4 5' | awk -v OFS="|" '{print $0}'

1 2 3 4 5

 echo '1 2 3 4 5' | awk -v OFS="|" '{$1=$1;print $0}'

1|2|3|4|5

echo '1 2 3 4 5' | awk -v OFS="|" '{NF+=0;print $0}'

1|2|3|4|5

为了使OFS的设置生效，需要改变 $0 ，这里我们是对 awk 撒了个小谎
  $1=$1 或者 NF+=0， $0 本身的内容实际上没有任何改变，只是为了使 OFS 的设置生效

  在理解了 RS 和 FS 之后，我们来回顾开始的那句话：“awk是基于行列操作文本的”
  这个说法实际上不是很准确，因为在改变了 RS 后，awk 中的“行”已经不是一般的“行”了
  同样，改变了 FS 后，awk 中的“列”也已经不是一般的“列”了
  因此，准确的应该这样讲：“awk是基于 记录(record) 和 域(field) 操作文本的”

三、0 与 "0" 差在哪

  我们先来看一个例子： 
awk 'BEGIN{if(0) print "true";else print "false"}'

false

awk 'BEGIN{if("0") print "true";else print "false"}'

true
为什么同样是 0 ，结果却不一样？
  其实要解释这个问题，只需要弄清楚awk中的“真”与“假”。
  以下3种情况是“假”，其他情况都为“真”
  1) 数字 0
  2) 空字符串
  3) 未定义的值 
 awk 'BEGIN{a=0;if(a) print "true";else print "false"}'

false

awk 'BEGIN{a="";if(a) print "true";else print "false"}'

false

awk 'BEGIN{if(a) print "true";else print "false"}'

false

awk如何去重？ 
1.awk '! a[$0] ++'

在解释之前，我们先要了解awk的一个特性：
  awk 会根据语境来给未定义的变量赋初始值 
awk 'BEGIN{print a "" 1}'

1

 awk 'BEGIN{print a + 1}'

1

对于未定义的变量，如果要进行字符串操作，会被赋成空字符串 ""
  如果要进行数学运算，会被赋成数字 0

  现在我们看看上面的代码 ! a[$0] ++ 等价于 if(! a[$0] ++) print $0
  对于首次出现的记录，a[$0]的值是未定义的，由于后面的 ++ 是数学计算，所以a[$0]会被赋值成数字0
  也是由于 ++ 操作符，会先取值，再计算，所以对于第一行记录实际上是if(! 0) print $0
  ! 是取反，0 是假，! 0 就是真，那么就会执行后面的 print $0
  对于后面出现的重复记录，a[$0] 经过 ++ 的计算已经变为 1、2、3 。。。
  而 ! 1  ! 2  ! 3 ... 都为假，不会打印。

  下面我们用黑哥的一段代码来深刻体会一下，用awk打印奇数行： 
seq 10 | awk 'i=!i'

1

3

5

7

9