欧拉回路——骑马修栅栏

题目：骑马修栅栏

描述：

Farmer John每年有很多栅栏要修理。他总是骑着马穿过每一个栅栏并修复它破损的地方。

John是一个与其他农民一样懒的人。他讨厌骑马，因此从来不两次经过一个栅栏。你必须编一个程序，读入栅栏网络的描述，并计算出一条修栅栏的路径，使每个栅栏都恰好被经过一次。John能从任何一个顶点(即两个栅栏的交点)开始骑马，在任意一个顶点结束。

每一个栅栏连接两个顶点，顶点用1到500标号(虽然有的农场并没有500个顶点)。一个顶点上可连接任意多(>=1)个栅栏。两顶点间可能有多个栅栏。所有栅栏都是连通的(也就是你可以从任意一个栅栏到达另外的所有栅栏)。

你的程序必须输出骑马的路径(用路上依次经过的顶点号码表示)。我们如果把输出的路径看成是一个500进制的数，那么当存在多组解的情况下，输出500进制表示法中最小的一个 (也就是输出第一个数较小的，如果还有多组解，输出第二个数较小的，等等)。

输入数据保证至少有一个解。

格式

PROGRAM NAME: fenceus

INPUT FORMAT：

(fenceus.in)

第1行: 一个整数F(1 <= F <= 1024)，表示栅栏的数目

第2到F+1行: 每行两个整数i, j(1 <= i,j <= 500)表示这条栅栏连接i与j号顶点。

OUTPUT FORMAT：

(fenceus.out)

输出应当有F+1行，每行一个整数，依次表示路径经过的顶点号。注意数据可能有多组解，但是只有上面题目要求的那一组解是认为正确的。

SAMPLE INPUT

9
1 2
2 3
3 4
4 2
4 5
2 5
5 6
5 7
4 6

SAMPLE OUTPUT

1
2
3
4
2
5
4
6
5
7


解析：
欧拉回路和欧拉路的典型例题，先判断是否有欧拉路，优先输出，否则输出欧拉路。但是题目比较坑的地方是，点的编号不是连续的，还要用变量记录，在找欧拉回路时要注意。

AC代码：

program zht;
var
i,j,m,n,x,y,p,tn,r:longint;

d:array[0..1000] of longint;
a:array[0..2000] of longint;
map:array[0..1000,0..1000] of longint;

function max(a,b:longint):longint;
begin
if a>b then max:=a else max:=b;
end;

function min(a,b:longint):longint;
begin
if a<b then min:=a else min:=b;
end;

procedure dfs(x:longint);
var
i:longint;
begin
for i:=1 to m do
 if map[x,i]>0 then begin

 dec(map[x,i]);
 dec(map[i,x]);
 dfs(i);
 end;
 inc(tn);
 a[tn]:=x;
end;

begin
assign(input,'fenceus.in');
assign(output,'fenceus.out');
reset(input);
rewrite(output);

readln(n);

r:=maxlongint;

for i:=1 to n do
begin
readln(x,y);
inc(map[x,y]);
inc(map[y,x]);
m:=max(m,max(x,y));
r:=min(r,min(x,y));
inc(d[x]);
inc(d[y]);
end;

tn:=0;
p:=maxlongint;

for i:=1 to m do
if d[i] mod 2=1 then if i<p then p:=i;

if p<>maxlongint then dfs(p) else dfs(r);

for i:=tn downto 1 do
writeln(a[i]);

close(input);
close(output);

end.