Delphi 消息之拦截篇拦截系统关机、重启、注销

　　最近做的项目中需要拦截系统关机，因为我在FormCloseQuery中总是把CanClose设为False，不拦截关机的话直接导致系统中的关机、重启、注销都失效了！导致用户不能关机！(提示用户说要关机的话直接按电源^^)这样肯定是不行的！

要完成这个功能只需要拦截到WM_QUERYENDSESSION消息就万事Ok!

　　Windows在关机的时候会想(向)所有顶层窗口广播一个消息WM_QUERYENDSESSION，其lParam参数可以区分是关机还是注销用户(注销用 户时lParam是ENDSESSION_LOGOFF)。然后Windows会等到所有的应用程序都对这个消息返回TRUE才会关机，因此，只要我们的 应用程序对这个消息的处理返回FALSE，Windows就不会关机了。

　　这个消息不能直接让应用程序退出，这个消息主要是询问应用程序是否已经作好了退出的准备，当所有的应用程序都对这个消息返回TRUE,系统回（会）注销或关机。如果想退出程序，请使用WM_CLOSE消息！

关键在于怎么在Delphi下拦截WM_QUERYENDSESSION消息呢？Delphi也是很强悍的，当然不用直接去SetWindowLong了。

　　首先介绍一下Delphi中拦截消息的几种做法

第一种：自定义处理单条消息

unit Unit2;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;

type
  TForm2 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormCloseQuery(Sender: TObject; var CanClose: Boolean);
  private
    { Private declarations }
    //直接用 TWMQueryEndSession
    procedure EndMsg(var nMsg: TWMQueryEndSession); Message WM_QUERYENDSESSION;
    //也可以用这种
    //procedure EndMsg(var nMsg: TMessage); Message WM_QUERYENDSESSION;
  public
    { Public declarations }
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}

//收到WM_QUERYENDSESSION消息后就会触发这个过程
procedure TForm2.EndMsg(var nMsg: TWMQueryEndSession);
begin
  //0 可以取消关机操作
  nMsg.Result := 1;
  ShowMessage('注销、重启、关机');
end;

end.

第二种：利用Application.OnMessage处理消息

unit Unit2;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;

type
  TForm2 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }

  public
    { Public declarations }
    procedure OnMsg(var nMsg: tagMSG; var nHandled: Boolean);
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}

//消息处理过程
procedure TForm2.OnMsg(var nMsg: tagMSG; var nHandled: Boolean);
begin
  //处理……
  //这里会收到各种消息……经测试无法收到WM_QUERYENDSESSION消息
end;

procedure TForm2.FormCreate(Sender: TObject);
begin
  Application.OnMessage := OnMsg;
end;

end.

第三种：自己处理窗口函数，个人感觉这是最强大的，可以拦截一切发往窗口的消息！

unit Unit2;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;

type
  TForm2 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }

  public
    { Public declarations }
    procedure WndProc(var nMsg: TMessage); override;
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}

procedure TForm2.WndProc(var nMsg: TMessage);
begin

  //这里能收到发往窗口的所有消息

  inherited; // 注意这句不能少

  if nMsg.Msg = WM_QUERYENDSESSION then
  begin
    if nMsg.LParam = 0 then
      ShowMessage('关机或重启')
    else
      ShowMessage('注销');
  end;

end;

end.

经过再次测试，只有Application.OnMessage不能拦截WM_QUERYENDSESSION消息！还有，有时候Delphi的一些控件也会导致不能正确拦截。