VB.NET中Module的概念

今天学习VB.NET，发现VB.NET里面有一个Module的东西，如下图(图-1)所示：

图-1

上网查了一下VB.NET里面的Module，才发现这是学习VB.NET遇到的第一个典型的问题就是：为什么VB.NET中会有一个Module的东西，而在C#等语言中是没有的呢？

首先，这是一个历史原因。早先的VB语言都有模块和类模块的概念。所谓模块一般就是存放公用的一些方法(Sub)或者函数(Function)，而类模块，相当于就是我们经常所说的类的概念。 

模块(Module)里面可以直接有方法，这些方法自动就是静态的（或者称为共享的——VB.NET中的关键字是Shared)，这些方法可以直接调用，所以Module是无法实例化，也没有必要实例化的。

模块无法继承，也无法实现接口。

模块里面可以有类，但其实这个类并不需要真的通过模块作为前缀来引用。所以模块有点虚的概念

模块可以被组织到命名空间中去，因为模块其实是个虚的，所以它的方法也可以直接外层的命名空间调用

Module代码范例：

'用命名空间封装Module
Namespace VBModuleTest
    ''' <summary>
    ''' 模块无法继承，无法实现接口
    ''' </summary>
    ''' <remarks></remarks>
    Module ModuleTest
        ''' <summary>
        ''' 模块里面的方法都是静态的，无需实例化，也无从实例化
        ''' </summary>
        ''' <remarks></remarks>
        Sub Main()
            'new一个Class1实例
            'Dim clazz As Class1 = New Class1这样也是对的
            Dim clazz As Class1 = New Class1()
            clazz.Name = "Class1类"
            Console.WriteLine(clazz.Name)
            Console.WriteLine(clazz.GetClassName())
            Console.ReadKey()
        End Sub
        ''' <summary>
        ''' 有返回值的方法，用Function来声明
        ''' </summary>
        ''' <returns></returns>
        ''' <remarks></remarks>
        Public Function Test1() As String
            Console.WriteLine("这个是Module里面的Test1方法")
            Return ""
        End Function
        ''' <summary>
        ''' 无返回值的方法，用Sub来声明
        ''' </summary>
        ''' <remarks></remarks>
        Public Sub Test2()
            Console.WriteLine("这个是Module里面的Test2方法")
        End Sub

        ''' <summary>
        ''' 类型可以放在模块里面，但主要的现实意义在于分类存放而已，放在模块里面并不影响该类型对外的引用。
        ''' 例如我们并不一定需要用VBModuleTest.ModuleTest.Class1，
        ''' 而是直接通过VBModuleTest.Class1就可以对其进行引用
        ''' </summary>
        ''' <remarks></remarks>
        Public Class Class1 : Implements IComparable
            ''' <summary>
            ''' 声明属性
            ''' </summary>
            ''' <remarks></remarks>
            Private _name As String
            Public Property Name() As String
                Get
                    Return _name
                End Get
                Set(ByVal value As String)
                    Me._name = value
                End Set
            End Property

            ''' <summary>
            ''' 声明方法
            ''' </summary>
            ''' <returns></returns>
            ''' <remarks></remarks>
            Public Function GetClassName() As String
                Test1()
                ModuleTest.Test2()
                Return Me.GetType().ToString()
            End Function

            ''' <summary>
            ''' 实现接口中的方法
            ''' </summary>
            ''' <param name="obj"></param>
            ''' <returns></returns>
            ''' <remarks></remarks>
            Public Function CompareTo(ByVal obj As Object) As Integer Implements System.IComparable.CompareTo
                Return 1
            End Function
        End Class
    End Module
End Namespace

这里的代码只是纯粹为演示目的而写的，没有任何具体意义 。