vijos 1030 重叠的方框

下图为5个放置在9x8 的点阵中的方框图:

若将他们按顺序叠放起来.则会有某些框的一部分盖住了另外一个框,遮住一些部分. 
下图是这5个框叠放起来的图形:

那么这些方框从下至上叠放的顺序是什么呢?
答案是: EDABC.
你的任务是对于一个给定的方框叠放以后的图形, 找出他们从下至上的叠放顺序.
下面是一些规则:
(1). 方框的边宽度为一个字符,边长不少于3个字符;
(2). 每个方框的4条边都有一部分可见, 一个角代表两条边;
(3). 方框用大写字母了表示, 没有两个方框用相同的字符来表示.

格式

输入格式

前两行每行一个数字，分别表示长、宽。

接下来为框叠起来的图。没有框的地方用'.'表示。

输出格式

输出全部可能情况。

按字典顺序排序。

解题思路

大概就是找到边框然后判断在其上面的框，建图，进行带有拓扑排序的DFS

var n,m,i,j,max:Longint;
    ch:char;
    f:array[0..1000,0..1000] of longint;
    dt:Array[1..26,1..26] of longint;
    u,d,l,r,c,w:array[1..26] of longint;
    pd:array[1..26] of boolean;
procedure dfs(i,k:longint);//带有拓扑排序的dfs
var j:longint;
begin

    w[k]:=i;
    if k=max then
    begin
        for j:=1 to max do write(char(w[j]+64));
        writeln;
        exit;
    end;
    for j:=1 to max do

      dec(c[j],dt[j,i]);

    for j:=1 to max do
        if (c[j]=0) and(not pd[j]) then
        begin
            pd[j]:=true;

            dfs(j,k+1);
            pd[j]:=false;
        end;
        for j:=1 to max do
        inc(c[j],dt[j,i]);

end;

procedure init;
var i,j:longint;
begin
    readln(n,m);//读数
    for i:=1 to n do
    begin
        for j:=1 to m do
        begin
            read(ch);
            if ch='.' then f[i,j]:=0;
            if ch in['A'..'Z'] then f[i,j]:=ord(ch)-64;
            if f[i,j]>max then max:=f[i,j];
        end;
        readln;
    end;
    filldword(u,length(u),1000);
    filldword(l,length(l),1000);
    for i:=1 to n do//寻找左右上下边界
        for j:=1 to m do
        if f[i,j]<>0 then
        begin
            if u[f[i,j]]>i then u[f[i,j]]:=i;
            if l[f[i,j]]>j then l[f[i,j]]:=j;
            if r[f[i,j]]<j then r[f[i,j]]:=j;
            if d[f[i,j]]<i then d[f[i,j]]:=i;
        end;

    {判断方框边界上是否有其他数，如果有，将f[i,j]赋值为1，表示i在j上面，建图}
    for i:=1 to max do
    begin
        for j:=u[i] to d[i] do
        begin
            if (f[j,l[i]]<>i)  then dt[f[j,l[i]],i]:=1;
            if (f[j,r[i]]<>i) then dt[f[j,r[i]],i]:=1;
        end;
        for j:=l[i] to r[i] do
        begin
            if (f[u[i],j]<>i) then dt[f[u[i],j],i]:=1;
            if (f[d[i],j]<>i) then dt[f[d[i],j],i]:=1;
        end;
    end;
end;
begin
    init;
    for i:=1 to max do//寻找各点出度
        for j:=1 to max do
        inc(c[i],dt[i,j]);
    for i:=1 to max do if c[i]=0 then//出度为0，表示在最下面
    begin
      pd[i]:=true;
      dfs(i,1);
      pd[i]:=false;
    end;
end.