第一个flash游戏配对游戏

看了《AS3.0游戏编程大学》用里面的素材模仿做了第一个flash游戏。。。

game

 

游戏影片剪辑代码，按照AS3.0 JIT编译的说明，把游戏代码放在构造函数里面貌似不是好的做法，效率低，因为JIT编译对构造函数里面的代码不进行动态编译。

package 
{
    import flash.display.MovieClip;
    import flash.events.MouseEvent;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.text.TextField;
    import flash.events.Event;
    import flash.utils.getTimer;
    import flash.display.IBitmapDrawable;
    import flash.media.SoundChannel;
    import flash.net.SharedObject;


    public class MyGame extends MovieClip
    {

        private const boardWidth:uint = 6;
        private const boardHeight:uint = 6;
        private const cardWidth:Number = 52;
        private const cardWHeight:Number = 52;
        private const offsetX:Number = 120;
        private const offsetY:Number = 45;
        private const pointForMatch:int = 100;
        private const pointForMiss:int = -5;


        private var cardArr:Array;
        private var firstCard:Card10;
        private var secondCard:Card10;
        private var cardNumbers:uint = 0;
        private var flipBackTimer:Timer;

        private var startTime:uint;
        private var gameTime:uint;
        private var timeText:TextField;
        private var score:int;
        private var scoreText:TextField;

        private var firstSound:FirstCardSound=new FirstCardSound();
        private var matchSound:MatchSound=new MatchSound();
        private var missSound:MissSound=new MissSound();



        public function MyGame():void
        {
            //var highScore:SharedObject = SharedObject.getLocal("userHighScore");
            //trace(highScore.data.HS);
            //highScore.data.HS = 0;
            //highScore.flush();
            //so.data.highScore = new Number(1234567890);
            //so.flush();

            startTime = getTimer();
            gameTime = 0;

            timeText=new TextField();
            timeText.x = 400;
            addChild(timeText);

            scoreText=new TextField();
            scoreText.x = 50;
            score = 0;
            addChild(scoreText);


            addEventListener(Event.ENTER_FRAME,showTimeAndScore);



            var Arr:Array=new Array();
            cardArr=new Array();
            for (var i:uint=0; i<boardWidth*boardHeight/2; i++)
            {
                Arr.push(i);
                Arr.push(i);
            }

            for (i=0; i<boardHeight; i++)
            {
                for (var j:uint=0; j<boardWidth; j++)
                {
                    var thiscard:Card10=new Card10();
                    //thiscard.stop();
                    cardArr.push(thiscard);
                    thiscard.x = i * cardWidth + offsetX;
                    thiscard.y = j * cardWHeight + offsetY;
                    var no:uint = Math.floor(Math.random() * Arr.length);
                    thiscard.cardFace = Arr[no];
                    Arr.splice(no,1);
                    thiscard.gotoAndStop(thiscard.cardFace+2);
                    //thiscard.gotoAndStop(1);
                    thiscard.addEventListener(MouseEvent.CLICK,cardClik);
                    addChild(thiscard);
                    cardNumbers++;
                }
            }

            flipBackTimer = new Timer(2000,1);
            flipBackTimer.addEventListener(TimerEvent.TIMER_COMPLETE,allFlipBack);
            flipBackTimer.start();

        }

        private function showTimeAndScore(event:Event)
        {
            gameTime = getTimer() - startTime;
            timeText.text = "time:" + clockTime(gameTime);
            scoreText.text = "score:" + String(score);

        }

        private function clockTime(time:uint):String
        {
            var seconds:int = Math.floor(time / 1000);
            var minutes:int = Math.floor(seconds / 60);
            seconds -=  minutes * 60;
            var timeString:String = minutes + ":" + String(seconds + 100).substr(1,2);
            return timeString;
        }

        private function allFlipBack(event:TimerEvent)
        {
            for (var i:uint=0; i<cardArr.length; i++)
            {
                //if(!this.getChildAt(i) is MovieClip)
                //trace("yes");
                //(Card10)(this.getChildAt(i)).startFlip(1);
                cardArr[i].startFlip(1);

            }

            //trace("t");
            flipBackTimer.removeEventListener(TimerEvent.TIMER_COMPLETE,allFlipBack);

        }

        private function cardClik(event:MouseEvent)
        {
            //var highScore:SharedObject = SharedObject.getLocal("userHighScore");
            //trace(so.data.highScore);
            //var file:FileReference=new FileReference();
            //file.save(clockTime(gameTime),"t.txt");
            //MovieClip(root).gotoAndStop("GameOver");
            var thiscard:Card10=(event.currentTarget as Card10);
            //trace(thiscard.cardFace);
            if (firstCard == null)
            {
                firstCard = thiscard;
                //thiscard.gotoAndStop(thiscard.cardFace+2);
                thiscard.startFlip(thiscard.cardFace+2);
                score +=  pointForMiss;
                PlaySound(firstSound);
            }
            else if (firstCard==thiscard)
            {
                thiscard.startFlip(1);
                firstCard = null;
                PlaySound(firstSound);


            }
            else if (secondCard==null)
            {
                secondCard = thiscard;
                //thiscard.gotoAndStop(thiscard.cardFace+2);
                thiscard.startFlip(thiscard.cardFace+2);
                if (firstCard.cardFace == secondCard.cardFace)
                {
                    PlaySound(matchSound);
                    removeChild(firstCard);
                    removeChild(secondCard);
                    firstCard = null;
                    secondCard = null;
                    cardNumbers -=  2;
                    if (cardNumbers == 0)
                    {
                        //trace(cardNumbers);

                        MovieClip(root).Time = clockTime(gameTime);
                        MovieClip(root).Score = score;

                        var highScore:SharedObject = SharedObject.getLocal("userHighScore");

                        if (score > highScore.data.HS)
                        {
                                highScore.data.HS=score;
                                highScore.flush();
                        }
                        MovieClip(root).HighScore=highScore.data.HS;
                        MovieClip(root).gotoAndStop("GameOver");
                    }
                    //trace(cardNumbers);
                    score +=  pointForMatch;


                }
                else
                {
                    PlaySound(missSound);
                    //flipBackTimer=new Timer(2000,1);
                    flipBackTimer.reset();
                    flipBackTimer.addEventListener(TimerEvent.TIMER_COMPLETE,FlipBack);
                    flipBackTimer.start();
                    score +=  pointForMiss;

                }

            }
            else
            {
                PlaySound(firstSound);
                //firstCard.gotoAndStop(1);
                //secondCard.gotoAndStop(1);
                firstCard.startFlip(1);
                secondCard.startFlip(1);
                firstCard = thiscard;
                //thiscard.gotoAndStop(thiscard.cardFace+2);
                thiscard.startFlip(thiscard.cardFace+2);
                secondCard = null;
                flipBackTimer.stop();
                score +=  pointForMiss;
            }

        }
        private function FlipBack(event:TimerEvent)
        {
            if (firstCard != null && secondCard != null)
            {

                firstCard.startFlip(1);
                secondCard.startFlip(1);
                firstCard = null;
                secondCard = null;

            }
            flipBackTimer.removeEventListener(TimerEvent.TIMER_COMPLETE,FlipBack);
        }

        private function PlaySound(soundObj:Object)
        {
            var channel:SoundChannel = soundObj.play();
        }


    }

}

卡片类代码：

package  
{
    import flash.events.Event;
    
    public class Card10 extends Card
    {

        private var cardface:uint;
        private var flipToFrame:uint;
        private var Step:uint;
        public function Card10():void
        {
            cardface=0;
        }
        
        public function get cardFace():uint
        {
            return cardface;
        }
        public function set cardFace(cf:uint):void
        {
            cardface=cf;
        }
        
        public function startFlip(toWhichFrame:uint)
        {
            flipToFrame=toWhichFrame;
            Step=10;
            this.addEventListener(Event.ENTER_FRAME,flip);
        }
        
        public function flip(event:Event)
        {
            Step--;
            if (Step > 5) 
            { // first half of flip
                this.scaleX = .20*(Step-6);
            } 
            else 
            { // second half of flip
                this.scaleX = .20*(5-Step);
            }
            
            if(Step==5)
            {
                gotoAndStop(flipToFrame);
            }
            
            if(Step==0)
            this.removeEventListener(Event.ENTER_FRAME,flip);
        }

    }
    
}

把flash嵌入html代码：

<title>DEMO</title>
<head>
<script type="text/javascript" src="https://files.cnblogs.com/wonderKK/swfobject.js"></script>
</head>
<body>
   <form id="Form1">
      <div id="flashcontent">
         <a href="http://www.adobe.com/go/getflashplayer">
            <img src="http://www.adobe.com/images/shared/download_buttons/get_flash_player.gif" alt="Get Adobe Flash player" border="0" /> 
         </a>      
      </div>
   </form>
   <script type="text/javascript">    
       var so = new SWFObject("https://files.cnblogs.com/wonderKK/game.swf", "mymovie", "800", "600", "7", "#FFFFFF");
       so.write("flashcontent");
   </script>
</body>