POJ 2823

POJ 2823 Sliding Windows

题目大意：给出一个长度为n的数组（1<=n<=10^6）,然后

For I := 1 to n-k+1 do 问区间a[I,i+k-1]内的最大最小值。

解法：复杂度最高去到n^2，显然不能朴素询问，用单调队列去维护即可，用min举例，如果新+入的数比队尾大，则保留(以后可能会用到)，若小，则不断dec（mint），直到比队尾大为止（为什么？其实就是一个贪心，新数进入窗口，说明数在窗口期间都是有效的，前面几个比它大的已经不用保存了，是一种贪心的思想），我是用了一个time数组来处理一个数是否在窗口内，比较麻烦，不知道是否有更好的方法了。

{提出一个nlogn的算法，快排一下从第一个开始更新区间}

//poj p2823
//orz fjy, this story from the way to gdoi2011
const
        maxn=1000000;
var
        a, qmin, qmax: array[1..maxn]of longint;
        mint, maxt, minh, maxh, n, k, tot: longint;
        pr, time: array[1..2, 1..maxn]of longint;
procedure min(x, timing: longint);
begin
  if x>qmin[mint] then inc(mint)
   else
    begin
      inc(mint);
      while (mint>minh)and(x<=qmin[mint-1]) do dec(mint);
    end;
  qmin[mint] := x;
  time[1, mint] := timing;
end;

procedure max(x, timing: longint);
begin
  if x<qmax[maxt] then inc(maxt)
  else
    begin
      inc(maxt);
      while (maxt>maxh)and(x>=qmax[maxt-1]) do dec(maxt);
    end;
  qmax[maxt] := x;
  time[2, maxt] := timing;
end;

procedure init;
var
        i: longint;
begin
  fillchar(time ,sizeof(time), 0);
  minh := 1;
  mint := 1;
  maxh := 1;
  maxt := 1;

  readln(n, k);
  for i := 1 to n do read(a[i]); readln;
  qmin[1] := a[1];
  qmax[1] := a[1];
  for i := 2 to k do
    begin
      min(a[i], i);
      max(a[i], i);
    end;
  tot := 1;
  pr[1, 1] := qmin[minh];
  pr[2, 1] := qmax[maxh];
end;

procedure main;
var
        i, j: longint;
begin
  for i := k+1 to n do
    begin
      inc(tot);
      min(a[i], i);
      max(a[i], i);
      while (i-time[1, minh]>=k) do inc(minh);
      while (i-time[2, maxh]>=k) do inc(maxh);
      pr[1, tot] := qmin[minh];
      pr[2, tot] := qmax[maxh];
    end;
end;

procedure print;
var
        i, j: longint;
begin
  for j := 1 to 2 do
    begin
      for i := 1 to tot do
        begin
          if i<>1 then write(' ');
          write(pr[j, i]);
        end;
      writeln;
    end;
end;

begin
  {assign(input,'test.in'); reset(input);
  assign(output,'test.out'); rewrite(output); }
  init;
  main;
  print;
  //close(input);
end.